HX3 Foren

HX3 Foren (https://hx3.de/)
-   Multiplayer (https://hx3.de/multiplayer-164/)
-   -   Server Parameter...? (https://hx3.de/multiplayer-164/server-parameter-20342/)

MaSch0815 30.01.2011 23:55

Server Parameter...?
 
Ich habe mich mal mit den ganzen Server Parametern befasst.
Nun habe ich einige Probleme mit dem Parameter "-BEpath", "-mpStatistics" und "-ip=" usw..
So richtig schlau werde ich aber aus den Dokus dazu nicht, bzw. funktionieren sie einfach nicht.

Bei -BEpath kann man zwar den Pfad richtig angeben er schreibt aber doch in den angegebenen "-profiles" Pfad bzw. erstellt da sein Verzeichnis und erstellt die BEServer.dll neu. Damit ist die BEServer.cfg, welche in dem "-BEpath" definiert wurde, dann auch für den A...
Was mache ich falsch?

Bei "-mpStatistics" sollte er eigentlich eine mpStatistics.log, laut Doku, erstellen, ist aber nichts zu finden im Arma Root bzw. in den U-Verzeichnissen davon. Auch in den Standard User-Profiles C:\Dokumente... usw. ist nichts zu finden von ihr, sollte ja auch eigentlich nicht, da ja mit -profiles definiert. Warum geht das nicht?

Kann man in der "-ip" Definition auch einen DynDNS Dienst eintragen oder gehen dort nur die festen IP´s?

Hier mal noch der Inhalt der Batch, zur Verdeutlichung. Habe ich mir mal zusammengebaut um Ordnung ins System zu bekommen... ;)
Code:

@echo Off

REM ######## Variablen definieren - Anfang ##############
REM ######## Zeitstempel erzeugen - Anfang ##############
for /F "tokens=1" %%u in ('time /T') do set t=%%u
        if "%t:~1,1%"==":" set t=0%t%
        for /f "tokens=1" %%r in ('date /T') do set d=%%r_
        set A2SVR_TIMESTAMP=%d%%t::=.%
REM ######## Zeitstempel erzeugen - Ende ###############
set A2SVR_GAMETYPE=Domination_2_29A2_West_AI_OA.Takistan
set A2SVR_WORKPATH=C:\ARMA2SERVERROOT
set A2SVR_BEPATH=%A2SVR_WORKPATH%\server\BattlEye
set A2SVR_PROFILESPATH=%A2SVR_WORKPATH%\server\profiles
set A2SVR_CONFIGSPATH=%A2SVR_WORKPATH%\server\configs
set A2SVR_LOGSPATH=%A2SVR_WORKPATH%\server\logs
set A2SVR_LISTSPATH=%A2SVR_WORKPATH%\server\lists
set A2SVR_EXE=arma2oaserver.exe
set A2SVR_CONFIG=%A2SVR_CONFIGSPATH%\server_ao_domi2oa_229.cfg
set A2SVR_CFG=%A2SVR_CONFIGSPATH%\basic_ao.cfg
set A2SVR_IP=123.123.123.123
set A2SVR_PORT=2302
set A2SVR_NAME=default
set A2SVR_PROFILES=%A2SVR_PROFILESPATH%\standard
set A2SVR_PIDLOGPATH=%A2SVR_LOGSPATH%\pid_domi2oa_229.log
set A2SVR_RANKINGFILE=%A2SVR_LOGSPATH%\ranking_domi2oa_229.log
set A2SVR_NETLOG=-netlog
set A2SVR_MPSTATISTICS=-mpStatistics
set A2SVR_BANLIST=%A2SVR_LISTSPATH%\banlist.txt
set A2SVR_WHITELIST=%A2SVR_LISTSPATH%\whitelist.txt
set A2SVR_MEMBERSLIST=%A2SVR_LISTSPATH%\memberslist.txt
set A2SVR_FRIENDSLIST=%A2SVR_LISTSPATH%\friendslist.txt
REM ######## Variablen definieren - Ende ###############

REM ######### vorhandene Dateien sichern - Anfang ########
if exist %A2SVR_WORKPATH%\net.log (
        rename %A2SVR_WORKPATH%\net.log net_%A2SVR_TIMESTAMP%.log.old
        move /y net_%A2SVR_TIMESTAMP%.log.old %A2SVR_LOGSPATH%
)
REM ######## vorhandene Dateien sichern - Ende ##########

REM ###### BAN-Liste sichern und Vorlage laden - Anfang ######
if exist %A2SVR_WORKPATH%\ban.txt (
        rename %A2SVR_WORKPATH%\ban.txt banlist_%A2SVR_TIMESTAMP%.txt.old
        move /y banlist_%A2SVR_TIMESTAMP%.txt.old %A2SVR_LOGSPATH%
        copy /y %A2SVR_LISTSPATH%\ban.txt %A2SVR_WORKPATH%
) else (
        copy /y %A2SVR_LISTSPATH%\ban.txt %A2SVR_WORKPATH%
)
REM ###### BAN-Liste sichern und Vorlage laden - Ende ######

REM ########### Server Aufruf - Anfang ##############
start /D %A2SVR_WORKPATH% /B /HIGH %A2SVR_WORKPATH%\%A2SVR_EXE% -port=%A2SVR_PORT% -ip=%A2SVR_IP% -cfg=%A2SVR_CFG% -config=%A2SVR_CONFIG% -BEpath=%A2SVR_BEPATH% -name=%A2SVR_NAME% -profiles=%A2SVR_PROFILES% -pid=%A2SVR_PIDLOGPATH% -ranking=%A2SVR_RANKINGFILE% %A2SVR_NETLOG% %A2SVR_MPSTATISTICS%
REM ########### Server Aufruf - Ende ###############

exit


MaSch0815 06.02.2011 21:14

@ -BEpath
Der wird doch richtig geschrieben. Fehler=Code 99 (Fehler sitzt vor dem Gerät...)
Hatte ab und mal mit der alten LNK Datei gestartet und da fehlte natürlich die Angabe des Pfades. Also, reine Verwirrung...:ugly:

@ -mpStatistigs
Mal schnell die Erklärung aus der Batch kopiert. (schreibfaul...)
Zitat:

nicht nötig, wird sowieso geschrieben (Achtung! Die Datei wird nicht erstellt wenn in der geladenen server.cfg der Parameter "persistent = 1" gesetzt ist. Ist der Parameter nicht vorhanden oder auf "persistent = 0" gesetzt wird die Datei im Standard (C:\Dokumente und Einstellungen\usw...) oder im vordefinierten Profiles Pfad erstellt.)
Nach langer Suche die Kombination herausgefunden...
Macht für mich aber nicht so richtig Sinn. :stupid:

@ -ip
Da fehlt mir immer noch eine Erklärung zu...


Und mal noch die neue Batch mit einigen kleinen netten Sachen, die mir das starten, sichern und loggen des Servers etwas erleichtern soll. Wer mag, bitte...
Code:

@echo off
REM ######### Beschreibung der Batch - Anfang #############
REM getestet unter Windows Server 2003 R2
REM Ablauf der Batch Datei:
REM - Zeitstempel für Datei/Verzeichnisname erzeugen
REM - Auslesen des ARMA2 Verzeichnis Pfades aus der Registry
REM - Variablen für den Serverstart sammeln
REM - Überprüfung ob die Angegebenen Variablen stimmen
REM - verschieben/kopieren/packen der alten Server-Dateien (CFG,Logs, usw.) aus dem ARMA2 Root
REM - kopieren einer Vorlage der ban.txt in das ARMA2 Root
REM - Zusammenbauen der Server-Parameter aus den Variablen und Start des Servers
REM ######### Beschreibung der Batch - Ende ##############


REM ######## Zeitstempel erzeugen - Anfang ##############
REM hier wird ein Zeit-Format erzeugt welches später für die RAR bzw das Sicherungsverzeichnis benutzt wird. (zBsp.: 2011-01-01_01-01 / YYYY-MM-DD_HH-MM)
for /F "tokens=1" %%u in ('time /T') do set t=%%u
        if "%t:~1,1%"==":" set t=0%t%
        for /f "tokens=1" %%r in ('date /T') do set d=%%r
        set A2SVR_TIMESTAMP=%d:~6,4%-%d:~3,2%-%d:~0,2%_%t::=-%
REM ######## Zeitstempel erzeugen - Ende ###############
REM ####### ARMA2 Verzeichnis auslesen - Anfang ##########
REM Hier wird der Pfad für das ARMA2 Verzeichnis aus der Registry ausgelesen.
for /f "tokens=2*" %%a in ('reg query "HKEY_LOCAL_MACHINE\SOFTWARE\Bohemia Interactive Studio\ArmA 2 OA"^|findstr /c:"MAIN"') do set "REGQUERYMAIN=%%b"
        if ERRORLEVEL 1 cls&echo.&echo STOPP!!!&echo.&echo Der Pfad für das ARMA2 Verzeichnis konnte in der Registry&echo nicht erkannt werden.&echo.&echo.&echo Bitte den Pfad in der Variable "A2SVR_WORKPATH" selber setzen.&echo.&echo.&echo.&echo.&echo Programm wird beendet...&echo.&echo.&pause&exit
REM ####### ARMA2 Verzeichnis auslesen - Ende ############


REM ######## Variablen definieren - Anfang ##############
REM Erklärung zu den Variablen:
REM "set VARIABLE=" setzt die den Variablenname (nicht verändern)
REM hinter dem "=" Zeichen steht der Wert für die Variable welcher gesetzt werden soll
REM Der Bereich mit den doppelten "::" dient nur zur Erklärung
REM Sollten die zu setzenden Werte Leerzeichen enthalten ist der Wert in "" anzugeben zBsp: "meine schoene cfg datei.cfg"
REM Auf Umlaute nach Möglichkeit, sorry Moeglichkeit, verzichten, dadurch kommt es zu Fehlern im Batch Ablauf
REM Werte für die Umlaute, wenn man doch unbedingt Umlaute nehmen möchte (Wert zwischen den "" nehmen)        ä = "„"        Ä = "Ž"        ö = "”"        Ö = "™"        ü = ""        Ü = "š"        ß = "á"
REM ########################################
REM Ab hier sind die Variablen anzupassen...

set A2SVR_GAMETYPE=Domination_2_29A2_West_AI_OA.Takistan
REM in Planung (wird im Moment noch nicht weiter benötigt; Prozess/Server Erkennung evtl. auch durch PID.log möglich)

set A2SVR_WORKPATH=%REGQUERYMAIN%
REM Pfad wo sich das ARMA2 Verzeichnis befindet (manuell eintragen falls das Auslesen der Registry nicht funktioniert)

set A2SVR_EXE=arma2oaserver.exe
REM Dateiname der Serve EXE-Datei (Standard=arma2oaserver.exe)

set A2SVR_IP=123.123.123.123
REM Definiert die externe IP des Servers

set A2SVR_PORT=2302
REM Definiert den Port des Servers

set A2SVR_USERSNAME=default
REM Legt fest welches Users-Verzeichnis benutzt werden soll

set A2SVR_PROFILESNAME=standard
REM Legt fest welches Profiles-Verzeichnis benutzt werden soll

set A2SVR_CFG=basics.cfg
REM Name der config.cfg welche benutzt werden soll

set A2SVR_CONFIG=server.cfg
REM Name der server.cfg welche benutzt werden soll

set A2SVR_PIDLOGPATH=pid_domi2oa_229.log
REM Name für die PID-Log Datei

set A2SVR_RANKINGFILE=ranking_domi2oa_229.log
REM Name für die Ranking-Log Datei (Bei Servern ohne Ranking wird diese ignoriert)

set A2SVR_BEPATH=%A2SVR_WORKPATH%\server\BattlEye
REM Pfad wo sich das BattlEye Verzeichnis befindet (darin sollte die BEServer.dll und die BEServer.cfg befinden)

set A2SVR_PROFILESPATH=%A2SVR_WORKPATH%\server\profiles
REM Pfad für die Profil-Verzeichnisse

set A2SVR_CONFIGSPATH=%A2SVR_WORKPATH%\server\configs
REM Pfad für die Config-Dateien des Servers

set A2SVR_LOGSPATH=%A2SVR_WORKPATH%\server\logs
REM Pfad für die Log-Dateien die erstellt werden

set A2SVR_OLDLOGSPATH=%A2SVR_LOGSPATH%\old_logs
REM Pfad für die Sicherung der alten Log-Dateien

set A2SVR_LISTSPATH=%A2SVR_WORKPATH%\server\lists
REM Pfad für die banlist.txt, whitelist.txt usw.

set A2SVR_BANLIST=%A2SVR_LISTSPATH%\banlist.txt
REM in Planung (Pflege von ID, GUID, IP und Grund des BANs)

set A2SVR_WHITELIST=%A2SVR_LISTSPATH%\whitelist.txt
REM in Planung (löschen von bekannten IDs aus der ban.txt bei Fehlern durch BattlEye anhand der Vorlage)

set A2SVR_MEMBERSLIST=%A2SVR_LISTSPATH%\memberslist.txt
REM in Planung (löschen von bekannten IDs aus der ban.txt bei Fehlern durch BattlEye anhand der Vorlage)

set A2SVR_FRIENDSLIST=%A2SVR_LISTSPATH%\friendslist.txt
REM in Planung (löschen von bekannten IDs aus der ban.txt bei Fehlern durch BattlEye anhand der Vorlage)

set A2SVR_NETLOG=-netlog
REM Aktiviert den Netlog Parameter

set A2SVR_MPSTATISTICS=-mpStatistics
REM nicht nötig, wird sowieso geschrieben (Achtung! Die Datei wird nicht erstellt wenn in der geladenen server.cfg der Parameter "persistent = 1" gesetzt ist. Ist der Parameter nicht vorhanden oder auf "persistent = 0" gesetzt wird die Datei im Standard (C:\Dokumente und Einstellungen\usw...) oder im vordefinierten Profiles Pfad erstellt.)
REM ######## Variablen definieren - Ende ###############



REM Ab hier bitte keine Veränderungen vornehmen, da sich die Befehle nur auf die oben gesetzten Variablen beziehen

REM ###### Gültigkeit einiger Variablen abfragen - Anfang #####
REM Hier wird das Vorhandensein einiger Verzeichnisse bzw. Dateien noch einmal Gegengeprüft
if not exist %A2SVR_WORKPATH% (
        cls&echo.&echo STOPP!!!&echo.&echo ARMA2 Verzeichnis wurde nicht gefunden...&echo Bitte das richtige ARMA2 Verzeichnis in den Variablen definieren.&echo.&echo.&echo.&echo.&echo Programm wird beendet...&echo.&echo.&pause&exit
) else (
        if not exist %A2SVR_EXE% (
                cls&echo.&echo STOPP!!!&echo.&echo Die in den Variablen angegebene Datei "%A2SVR_EXE%" wurde nicht gefunden...&echo Bitte die richtige ARMA2-Server EXE in den Variablen definieren.&echo.&echo.&echo.&echo.&echo Programm wird beendet...&echo.&echo.&pause&exit
        ) else (
                if not exist %A2SVR_CONFIGSPATH%\%A2SVR_CFG% (
                        cls&echo.&echo STOPP!!!&echo.&echo Die in den Variablen angegebene Datei&echo "%A2SVR_CONFIGSPATH%\%A2SVR_CFG%" wurde nicht gefunden...&echo.&echo Bitte die richtige CFG-Datei in den Variablen definieren.&echo.&echo.&echo.&echo.&echo Programm wird beendet...&echo.&echo.&pause&exit
                ) else (
                        if not exist %A2SVR_CONFIGSPATH%\%A2SVR_CONFIG% (
                                cls&echo.&echo STOPP!!!&echo.&echo Die in den Variablen angegebene Datei&echo "%A2SVR_CONFIGSPATH%\%A2SVR_CONFIG%" wurde nicht gefunden...&echo.&echo Bitte die richtige CFG-Datei in den Variablen definieren.&echo.&echo.&echo.&echo.&echo Programm wird beendet...&echo.&echo.&pause&exit
                        ) else (
                                if not exist %A2SVR_BEPATH% (
                                        cls&echo.&echo STOPP!!!&echo.&echo Der in den Variablen angegebene Pfad&echo "%A2SVR_BEPATH%"&echo fr die BattlEye Dateien wurde nicht gefunden...&echo.&echo Bitte das richtige BattlEye Verzeichnis in den Variablen definieren.&echo.&echo.&echo.&echo.&echo Programm wird beendet...&echo.&echo.&pause&exit
                                ) else (
                                        if not exist %A2SVR_BEPATH%\BEServer.dll (
                                                cls&echo.&echo STOPP!!!&echo.&echo Die Datei "BEServer.dll" wurde nicht im Pfad&echo "%A2SVR_BEPATH%" gefunden...&echo.&echo Bitte die Datei "BEServer.dll" in das Verzeichnis&echo "%A2SVR_BEPATH%" kopieren.&echo.&echo.&echo.&echo.&echo Programm wird beendet...&echo.&echo.&pause&exit
                                        ) else (
                                                if not exist %A2SVR_BEPATH%\BEServer.cfg (
                                                        cls&echo.&echo STOPP!!!&echo.&echo Die Datei "BEServer.cfg" wurde nicht im Pfad&echo "%A2SVR_BEPATH%" gefunden...&echo.&echo Bitte die Datei "BEServer.cfg" im Verzeichnis&echo "%A2SVR_BEPATH%" erstellen.&echo.&echo.&echo.&echo.&echo Programm wird beendet...&echo.&echo.&echo oder...&echo.&echo.
                                                        choice /c jn /n /t 10 /d n /m "Ohne BEServer.cfg Fortfahren? Ja(J), Nein(N) (autom. "Nein" Abbruch in 10 sec.)"
                                                        if ERRORLEVEL 2 echo.&echo es wurde Nein gew„hlt&echo.&echo Programm wird beendet...&pause&exit
                                                        if ERRORLEVEL 1 goto RUNNOBECFG
                                                        if ERRORLEVEL 0 echo.&echo Programm wurde unterbrochen...&echo.&echo Programm wird beendet...&pause&exit
                                                )
                                        )
                                )
                        )
                )
        )
)
:RUNNOBECFG
REM ###### Gültigkeit einiger Variablen abfragen - Ende ######


REM ######### vorhandene Dateien sichern - Anfang ########
REM Überprüft ob Verzeichnis "old_logs" vorhanden ist, wenn nicht wird es erstellt
if not exist %A2SVR_OLDLOGSPATH% md %A2SVR_OLDLOGSPATH%
REM Überprüft ob das Verzeichnis mit dem aktuellem Zeitstempel schon vorhanden ist (schnelle Ausführungen des Server hintereinander), wenn nicht wird es erstellt
if not exist %A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP% md %A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP%
REM Verschieben der alten Server-Log Dateien in das Zeitstempel Verzeichnis
move /y %A2SVR_WORKPATH%\net.log %A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP%
move /y %A2SVR_WORKPATH%\ban.txt %A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP%
move /y %A2SVR_PROFILESPATH%\%A2SVR_PROFILESNAME%\*.rpt %A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP%
move /y %A2SVR_PROFILESPATH%\%A2SVR_PROFILESNAME%\*.log %A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP%
move /y %A2SVR_LOGSPATH%\*.log %A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP%
REM Kopieren von LOG, TXT, BattlEye Dateinen und der Startdateien (CMD) in das Zeitstempel Verzeichnis
copy /y %A2SVR_WORKPATH%\*.cmd %A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP%
copy /y %A2SVR_PROFILESPATH%\%A2SVR_PROFILESNAME%\users\%A2SVR_USERNAME%\*.* %A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP%
copy /y %A2SVR_BEPATH%\*.* %A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP%
copy /y %A2SVR_LISTSPATH%\ban.txt %A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP%\ban_vorlage.txt
copy /y %A2SVR_BANLIST% %A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP%
copy /y %A2SVR_WHITELIST% %A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP%
copy /y %A2SVR_MEMBERSLIST% %A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP%
copy /y %A2SVR_FRIENDSLIST% %A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP%
copy /y %A2SVR_CONFIGSPATH%\*.* %A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP%
REM Abfrage ob RAR-Packer im Root des ARMA2 Verzeichnisses liegt
if not exist %A2SVR_WORKPATH%\rar.exe (
        cls&echo.&echo STOPP!!!&echo.&echo Es konnte keine "rar.exe" zum komprimieren der Dateien&echo im ARMA2 Verzeichnis gefunden werden...&echo.&echo Bitte die "rar.exe" in das Verzeichnis "%A2SVR_WORKPATH%" kopieren.&echo.&echo.&echo Abgeschlossen:&echo - Verzeichnis "%A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP%" erstellt&echo - Dateien kopiert&echo.&echo.&echo.&echo.&echo Programm wird beendet...&echo.&echo.&pause&exit
) else (
        REM packen der gesammelten Dateien
        %A2SVR_WORKPATH%\rar.exe a -m5 -ep1 -y -inul %A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP%.rar %A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP%\*.*
        REM Abfrage ob RAR-Datei mit passendem Namen erstellt wurde, wenn ja Löschung des Verzeichnisses, wenn Nein bleibt er stehen und das Verzeichnis wird nicht gelöscht.
        if exist %A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP%.rar (
                RD %A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP% /s /q
        ) else (
                cls&echo.&echo STOPP!!!&echo.&echo Fehler beim packen des Verzeichnisses...&echo.&echo "%A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP%"&echo.&echo.&echo Abgeschlossen:&echo - Verzeichnis "%A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP%" erstellt&echo - Dateien kopiert&echo.&echo.&echo.&echo.&echo Programm wird beendet...&echo.&echo.&pause&exit
        )
)
REM ######## vorhandene Dateien sichern - Ende ##########


REM ###### BAN-Liste aus Vorlage laden - Anfang ######
REM Kopieren der ban.txt aus einer Vorlage (die aktuellen BANs sollten dann in der Vorlage gepflegt werden)
copy /y %A2SVR_LISTSPATH%\ban.txt %A2SVR_WORKPATH%
REM ###### BAN-Liste aus Vorlage laden - Ende ######


REM ########### Server Aufruf - Anfang ##############
REM Zusammenbau der Server Startparameter und Start des Servers
start /D %A2SVR_WORKPATH% /B /HIGH %A2SVR_WORKPATH%\%A2SVR_EXE% -port=%A2SVR_PORT% -ip=%A2SVR_IP% -config=%A2SVR_CONFIGSPATH%\%A2SVR_CONFIG% -cfg=%A2SVR_CONFIGSPATH%\%A2SVR_CFG% -config=%A2SVR_CONFIGSPATH%\%A2SVR_CONFIG% -BEpath=%A2SVR_BEPATH% -name=%A2SVR_USERSNAME% -profiles=%A2SVR_PROFILESPATH%\%A2SVR_PROFILESNAME% -pid=%A2SVR_LOGSPATH%\%A2SVR_PIDLOGPATH% -ranking=%A2SVR_LOGSPATH%\%A2SVR_RANKINGFILE% %A2SVR_NETLOG% %A2SVR_MPSTATISTICS%
REM ########### Server Aufruf - Ende ###############

:EXITAPP
exit


Panzerfaust 06.04.2011 13:52

ey cool Batch - Anfrage.
 
ey funktioniert das auch Batch - Anfrage !!!
;)

MaSch0815 06.04.2011 19:34

Zitat:

funktioniert das auch Batch - Anfrage !!!
???

Eigentlich schon. Auch unter SRV2008 getestet.
Wurde aber noch einmal angepasst. Poste ich dann noch mal, wenn Interesse bestehen sollte.

Panzerfaust 07.04.2011 05:48

aha...

Code:

REM ####### ARMA2 Verzeichnis auslesen - Anfang ##########
REM Hier wird der Pfad für das ARMA2 Verzeichnis aus der Registry ausgelesen.
for /f "tokens=2*" %%a in ('reg query "HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Bohemia Interactive Studio\ArmA 2 OA"^|findstr /"C:\Program Files\Bohemia Interactive\ArmA 2"') do set "REGQUERYMAIN=%%b"
        if ERRORLEVEL 1 cls&echo.&echo STOPP!!!&echo.&echo Der Pfad für das ARMA2 Verzeichnis konnte in der Registry&echo nicht erkannt werden.&echo.&echo.&echo Bitte den Pfad in der Variable "A2SVR_WORKPATH" selber setzen.&echo.&echo.&echo.&echo.&echo Programm wird beendet...&echo.&echo.&pause&exit
REM ####### ARMA2 Verzeichnis auslesen - Ende ############



http://www.mikrocontroller.net/forum kuckst du ...

komisch wo ist die rar Datei ... den er ausgelesen hat oder hätte

MaSch0815 07.04.2011 08:14

Zitat:

aha...
Ich schrieb ja wurde noch verändert, gerade der Teil mit der Registry haute auch nicht hin. Ich werde die neue mal hier einfügen, wenn ich es heute noch schaffe. ;)

Zitat:

http://www.mikrocontroller.net/forum[/url] kuckst du ...
wat soll ich da? Nen Schaltkreis mit in die Batch einbauen?:ugly:

Zitat:

komisch wo ist die rar Datei ... den er ausgelesen hat oder hätte
Er liest nicht aus einer RAR, er schreibt eine. Und zwar diverse Dateien die sonst beim nächsten Serverstart gelöscht werden würden und weitere, siehe dazu weiter oben.
Code:

if not exist %A2SVR_WORKPATH%\rar.exe (
        cls&echo.&echo STOPP!!!&echo.&echo Es konnte keine "rar.exe" zum komprimieren der Dateien&echo im ARMA2 Verzeichnis gefunden werden...&echo.&echo Bitte die "rar.exe" in das Verzeichnis "%A2SVR_WORKPATH%" kopieren.&echo.&echo.&echo Abgeschlossen:&echo - Verzeichnis "%A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP%" erstellt&echo - Dateien kopiert&echo.&echo.&echo.&echo.&echo Programm wird beendet...&echo.&echo.&pause&exit
) else (
        REM packen der gesammelten Dateien
        %A2SVR_WORKPATH%\rar.exe a -m5 -ep1 -y -inul %A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP%.rar %A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP%\*.*
        REM Abfrage ob RAR-Datei mit passendem Namen erstellt wurde, wenn ja Löschung des Verzeichnisses, wenn Nein bleibt er stehen und das Verzeichnis wird nicht gelöscht.
        if exist %A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP%.rar (
                RD %A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP% /s /q
        ) else (
                cls&echo.&echo STOPP!!!&echo.&echo Fehler beim packen des Verzeichnisses...&echo.&echo "%A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP%"&echo.&echo.&echo Abgeschlossen:&echo - Verzeichnis "%A2SVR_OLDLOGSPATH%\%A2SVR_TIMESTAMP%" erstellt&echo - Dateien kopiert&echo.&echo.&echo.&echo.&echo Programm wird beendet...&echo.&echo.&pause&exit
        )
)



Alle Zeitangaben in WEZ +1. Es ist jetzt 16:45 Uhr.

Angetrieben durch vBulletin, Entwicklung von Philipp Dörner & Tobias


SEO by vBSEO 3.2.0 ©2008, Crawlability, Inc.

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119