HX3 Foren

HX3 Foren (https://hx3.de/)
-   Editing & Scripting (https://hx3.de/editing-scripting-187/)
-   -   Waypoint im Script hinzufügen??? (https://hx3.de/editing-scripting-187/waypoint-script-hinzufuegen-25620/)

Joa666 02.03.2017 18:03

Waypoint im Script hinzufügen???
 
Servus zusammen,

ich versuche per Script ein Fahrzeug mit Fahrer zu spawnen und diesem dann einen oder mehrere Wegpunkte zuzuweisen.

Nach längerem Hin und Her krieg ich zumindest das Fahrzeug gespawnt ... mit Besatzung ... aber die Wegpunktzuweisung wird ignoriert. Vielleicht kann mir einer auf die Sprünge helfen was ich falsch mache.

Hier mein Script:

----------------------------------------------------------------

if(!isServer)exitWith{};

G001 = createGroup east;

_veh = createVehicle ["CUP_O_BMP_HQ_RU",getMarkerPos "X1",[],0,"NONE"];
[
_veh,
[
["CUP_O_RU_Soldier_VDV_EMR","driver"]
]
] call BIS_fnc_initVehicleCrew;


WP001 = G001 addWaypoint [getMarkerPos "X1a", 0];
WP001 setWaypointType "MOVE";
WP001 setWaypointSpeed "LIMITED";
WP001 setWaypointBehaviour "SAFE";

---------------------------------------------------------------

Danke schonmal für eure Hilfe

Grüße

Joa

Pfandgiraffe 03.03.2017 10:43

Das liegt daran, dass die Gruppe welcher du da den Wegpunkt zuweisen möchtest nichts mit der Gruppe zu tun hat welche am Ende in deinem BMP sitzt.

Versuch's mal mit folgender Variante. Hier wird die Gruppe ermittelt, welche durch die Funktion gespawnt wird. Alternativ versuche mal bitte die zweite Variante die ich gepostet habe. Die erste Variante mit der Funktion ist eigentlich mega aufgebläht bzgl. performance. Es gibt immerhin auch die Engine Lösung von BI mit "createCrew". Es kann jedoch sein, dass mit der zweiten Variante eine falsche Crew gespawnt wird. Das häjngt davon ab wie gut die CUP Config ist.

1. Variante:
Code:

if (!isServer) exitWith {};

_veh = createVehicle ["CUP_O_BMP_HQ_RU", getMarkerPos "X1", [], 0, "NONE"];

_crew = [
        _veh,
        [["CUP_O_RU_Soldier_VDV_EMR","driver"]]
] call BIS_fnc_initVehicleCrew;

_grp_tank_crew = grpNull;
_grp_tank_crew = if (!isNull (commander _veh)) then {
        group (commander _veh)
} else {
        group (_crew select 0)
};

if (isNull _grp_tank_crew) exitWith {diag_log format ["no crew was generated for given vehicle: %1", _veh]};


WP001 = _grp_tank_crew addWaypoint [getMarkerPos "X1a", 0];
WP001 setWaypointType "MOVE";
WP001 setWaypointSpeed "LIMITED";
WP001 setWaypointBehaviour "SAFE";


2. Variante:
Code:

if (!isServer) exitWith {};

_veh = createVehicle ["CUP_O_BMP_HQ_RU", getMarkerPos "X1", [], 0, "NONE"];
_crew = createVehicleCrew _veh;

_grp_tank_crew = grpNull;
_grp_tank_crew = if (!isNull (commander _veh)) then {
        group (commander _veh)
} else {
        Group (_crew select 0)
};

if (isNull _grp_tank_crew) exitWith {diag_log format ["no crew was generated for given vehicle: %1", _veh]};


WP001 = _grp_tank_crew addWaypoint [getMarkerPos "X1a", 0];
WP001 setWaypointType "MOVE";
WP001 setWaypointSpeed "LIMITED";
WP001 setWaypointBehaviour "SAFE";


p.s.: die 2. Variante spawnt eine komplette Crew und nicht nur den Fahrer!


Grüße

Joa666 03.03.2017 11:01

danke für die schnelle hilfe ... die erste variante funzt einwandfrei ... werd mal die performance im auge behalten ... bei der zweiten passiert das gleiche wie bei meinem fehlerhaften script ... aber das liegt wohl an den cup fahrzeugen ... werd es mal mit vanilla fzg versuchen.

tausend Dank


Grüße

Joa

Pfandgiraffe 03.03.2017 18:50

Zitat:

kannst du mir sagen warum deine Lösung im Editor einwandfrei läuft und aufm Server nicht?

Grüße

Joa
Ich beantworte keine Fragen über PM...

Das kommt drauf an wie du die ganze Sache startest?


Grüße


Alle Zeitangaben in WEZ +1. Es ist jetzt 08:08 Uhr.

Angetrieben durch vBulletin, Entwicklung von Philipp Dörner & Tobias


SEO by vBSEO 3.2.0 ©2008, Crawlability, Inc.

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119