⚡ Neueste Beiträge

Module über Script spawnen

23.12.2015, 23:56 #1 (Permalink)
TimmK
Newbie
Registriert seit: 08.11.2015
Beiträge: 18
Module über Script spawnen

Moin,
kann mir jemand sagen ob und wie ich Module (Zeus Game Master) über ein Script spawnen kann?
24.12.2015, 10:59 #2 (Permalink)
Moerderhoschi
Armed-Assault.de Team10 Jahre hx3
500 Beiträge1000 Beiträge2.500 Beiträge
Avatar von Moerderhoschi
Registriert seit: 02.07.2006
Ort: Kabul
Alter: 41
Beiträge: 2.666
Das erstellen vom curatorModule ueber ein Script geht mit den Befehl

Code:
"ModuleCurator_F" createUnit [_pos, _grp];


Davor muss aber eine Gruppe der Seite sidelogic erstellt werden, in welcher das Module dann Mitglied ist.

Code:
_side_logic = createCenter sidelogic;
_grp = createGroup _side_logic;


Ich weiß nicht wie es um deine Scriptingkenntnis steht, falls da eher weniger vorhanden ist empfehle ich Dir den folgenden Thread zu lesen, 99% davon gilt auf fuer ArmA III: Missionserstellung Tipps&Tricks

Sobald Du das getan hast, verstehst Du auch folgendes Script besser, was ich als Beispiel gebastelt habe:

Code:
// made by Moerderhoschi

// check if script only executed on server
if (!isServer) exitwith {};

// defining zeus game master
zeusGameMaster = nameOfPlayerWhoWillBeZeus;
publicvariable "zeusGameMaster";
sleep 0.1;

// wait until zeusGameMaster is defined
waitUntil {sleep 0.5; !isNil "zeusGameMaster"};

// create logic that zeus module can be created
_side_logic = createCenter sidelogic;
_group_logic = createGroup _side_logic;
sleep 0.1;

// create zeus module
"ModuleCurator_F" createUnit [[0,0,0], _group_logic,"zeusGameMasterModule = this"];

// set module to be able to do stuff near players
zeusGameMasterModule allowCuratorLogicIgnoreAreas true;
sleep 0.1;

// assign zeusGameMaster to module
zeusGameMaster assignCurator zeusGameMasterModule;
sleep 0.1;

// add allMissionObjects to be editable to the module
zeusGameMasterModule addCuratorEditableObjects [ (allMissionObjects "") , true];


Auch empfehlenswert der Editing Guide von Psychobastard fuer A3: Psycho's A3 Editing Guide
__________________


08.05.2017, 19:01 #3 (Permalink)
[GNC]JamesRyan
50 Beiträge
Avatar von [GNC]JamesRyan
Registriert seit: 04.11.2009
Ort: Ober-Ramstadt
Alter: 37
Beiträge: 79
Brauchte ebenfalls diese Funktionalität, also danke an Moerderhoschi für die Lösung! Allerdings ist das Skript sehr aufgebläht und wenn es eh auf dem Server läuft, sind die publicVariable Befehle auch unnötig (außer für JIP eventuell). Da ich das ganze für Admins brauche, die sich bei einem Disconnect auch neu einloggen können, sieht meine Lösung so aus:

Code:
// arguments
params ["_curator"];

// check if player is not already curator
if (_curator in (allCurators apply {getAssignedCuratorUnit _x})) exitWith{};

// create logic that zeus module can be created
private _side_logic = createCenter sidelogic;
private _group_logic = createGroup _side_logic;
sleep 0.1;

// create zeus module
private _curatorObj = _group_logic createUnit ["ModuleCurator_F", [0,0,0], [],0, "NONE"];

// set module to be able to do stuff near players
_curatorObj allowCuratorLogicIgnoreAreas true;

// assign zeusGameMaster to module
_curator assignCurator _curatorObj;

// add allMissionObjects to be editable to the module
_curatorObj addCuratorEditableObjects [ (allMissionObjects "") , true];
__________________
~[3.JgKp]James~
Kompaniechef | Autor SQF-Handbuch | 3.Jägerkompanie
HX3 Foren · Startseite · Archiv · Impressum · Datenschutz