17.02.2011, 15:43
|
#1 (permalink) |
 Registriert seit: 29.10.2008
Ort: austria
Alter: 41
Beiträge: 7
 |
Weapon Save Config
Hallo Leute
Ich habe eine frage zum Weapon save! wenn man stirbt und wieder aufwacht das man die selbe ausrüstung hat wie vorher könnt ihr mir evtl sagen wie das script aussieht bzw die config wie die geschrieben gehört. danke
__________________
1-2 und im Chor ich lieb das Marinechor  Besucht uns doch einfach mal am Austrian Arma" Server 
Geändert von Arni83 (17.02.2011 um 17:18 Uhr). |
|
|
17.02.2011, 17:59
|
#2 (permalink) |
  
Registriert seit: 16.09.2008
Ort: Berlin
Alter: 38
Beiträge: 1.737
 |
Code:
if (!(local player)) exitWith {};
while {true} do {
waitUntil {!alive player};
_weapons = weapons player;
_magazines = magazines player;
waitUntil {alive player};
_p = player;
removeAllItems _p;
removeAllWeapons _p;
{_p addMagazine _x;} forEach _magazines;
{_p addWeapon _x;} forEach _weapons;
_primw = primaryWeapon _p;
if (_primw != "") then {
_p selectWeapon _primw;
// Fix for weapons with grenade launcher
_muzzles = getArray(configFile>>"cfgWeapons" >> _primw >> "muzzles");
_p selectWeapon (_muzzles select 0);
};
};
if (true) exitWith {};
__________________
Niemand hat die Absicht eine Tüte zu bauen!  ___<<<A3 Wounding System>>>___ |
|
|
|
17.02.2011, 18:01
|
#3 (permalink) |
|
Registriert seit: 29.10.2008
Ort: austria
Alter: 41
Beiträge: 7
|
Danke für die antwort für das muss ich eine eigene sqf datei machen oder muss ich das in der init sqf hinterlegen?
__________________
1-2 und im Chor ich lieb das Marinechor Besucht uns doch einfach mal am Austrian Arma" Server
|
|
|
|
18.02.2011, 15:47
|
#6 (permalink) |
  
Registriert seit: 10.01.2010
Alter: 75
Beiträge: 175
|
Hallo Xeno! Hättest du noch was passendes bei der Hand wenn ich noch zusätzlich einen Rucksack hätte? Sprich das nach dem Tod im Rucksack auch noch alles drin ist was man sich vorher ausgesucht hat? Mfg.Mike Geändert von Xeno (03.01.2014 um 10:08 Uhr). |
|
|
|
18.02.2011, 18:30
|
#7 (permalink) |
Registriert seit: 04.06.2008
Beiträge: 197
|
Hi,
eine Lösung mit Rucksack könnte in die Richtung gehen: Code:
if (!isDedicated) then {
[] spawn {
// JIP player ist null
if (isNull player) then {waitUntil {!isNull player}};
// zur Sicherheit wenn das Script mehrmals ausgeführt werden sollte...
if (!isNil {player getVariable "x_weaponmagadd"}) exitWith {};
player setVariable ["x_weaponmagadd", true];
player addEventhandler["killed", {
player setVariable ["x_weapons", weapons player];
player setVariable ["x_magazines", magazines player];
if (!isNull unitBackpack player) then {
player setVariable ["x_packType", (typeOf unitBackpack player)];
player setVariable ["x_packMags", (getMagazineCargo unitBackpack player)];
player setVariable ["x_packWeps", (getWeaponCargo unitBackpack player)];
};
}];
player addEventhandler ["respawn", {
private "_p";
_p = player;
removeAllItems _p;
removeAllWeapons _p;
{_p addMagazine _x} forEach (player getVariable "x_magazines");
{_p addWeapon _x} forEach (player getVariable "x_weapons");
_primw = primaryWeapon _p;
if (_primw != "") then {
_p selectWeapon _primw;
// Fix for weapons with grenade launcher
_muzzles = getArray(configFile>>"cfgWeapons" >> _primw >> "muzzles");
_p selectWeapon (_muzzles select 0);
};
if (!isNil {player getVariable "x_packType"}) then {
private ["_packMags", "_packWeps"];
_packMags = [];
_packWeps = [];
_packMags = (player getVariable "x_packMags");
_packWeps = (player getVariable "x_packWeps");
_p addBackpack (player getVariable "x_packType");
clearMagazineCargo (unitBackpack _p);
clearWeaponCargo (unitBackpack _p);
for "_i" from 0 to count (_packMags select 0) - 1 do {
(unitBackpack _p) addMagazineCargo [(_packMags select 0) select _i, (_packMags select 1) select _i];
};
for "_i" from 0 to count (_packWeps select 0) - 1 do {
(unitBackpack _p) addWeaponCargo [(_packWeps select 0) select _i, (_packWeps select 1) select _i];
};
};
}];
};
};
Und nicht dass ihr denkt ich versteh das alles zu 100% was da steht! Bin nur gut im Abschreiben und Rumprobieren 
|
|
|
| Aktive Benutzer in diesem Thema: 1 (Registrierte Benutzer: 0, Gäste: 1) | |
| Themen-Optionen | |
| Ansicht | |
|
|
Ähnliche Themen
|
||||
| Thema | Autor | Forum | Antworten | Letzter Beitrag |
| J.S.R.S - Jarhead's Sounds-Redeployment Systems | Termi | Mods & Addons | 508 | 08.01.2013 15:19 |
| Hilfe bei config Motor Sound | stiefel1976 | Editing & Scripting | 4 | 30.01.2011 19:16 |
| Weapon Respawn Script | Anemia | Editing & Scripting | 5 | 12.07.2010 11:36 |
| addon config | TeeTime | Editing & Scripting | 1 | 06.07.2010 01:43 |
| brauche hilfe bei meiner ersten Config | GER_CJ-187 | Mods & Addons | 21 | 01.07.2010 12:42 |
Linear-Darstellung
