/* Skript läuft Lokal bei Playern 

Verhindert unbefugte Spieler als Driver in lenkbaren Objekten.
Versetzt die Spieler ersatzweise auf einen sonstigen freien Platz. 

Parameter: [[Vehicle,[Unit,Unit,...]],[Vehicle,[Unit,Unit,...]],...] execVM "Driver_Verbot.sqf";
      Vehicle = Klasse der verbotenen Objekte
      Unit  = Klasse eines befugten Drivers

Beispiel-Aufruf des Skripts für Helikopter und Panzer:

[
 ["Helicopter",["USMC_Soldier_Officer", "USMC_Soldier_Pilot"]],
 ["Tank",   ["USMC_Soldier_Officer", "USMC_Soldier_Crew" ]]
] execVM "Driver_Verbot.sqf";

*/ 

if (! local player) exitWith {}; // Nur für Spieler aktivieren

private ["_vehicleType","_driverTypen","_vhID","_vhDriver"];

while {true} do //Dauerschleife bis Spielende 
 {
 //Warten bis Spieler in ein Objekt einsteigt
 waituntil {player != vehicle player};
 _vhID = vehicle player; //ID des bestiegenen Objektes
 //Ist ein anderer Driver im Vehicle?
 if (NOT isNull driver _vhID and driver _vhID != player)
  then {_vhDriver = driver _vhID} else {_vhDriver = objNull};
 while {player != vehicle player} do
  {
  if (player == driver _vhID) then //ist player Driver des Objekts?
   {
    {  
     _vehicleType = _x select 0;
     _driverTypen = _x select 1;
     //Spieler keiner der erlaubten Driver-Typen?
     if ({_x == typeOf player} count _driverTypen == 0) then
     {
     //Spieler Driver in einem nicht erlaubten Objekt?
     if (_vhID isKindOf _vehicleType) then
      {
      moveOut player;
      //Falls anderer Driver im Vehicle war, dann wieder als Driver einsetzen
      if (NOT isNull _vhDriver) then {moveOut _vhDriver;_vhDriver moveInDriver _vhID};
      //Spieler raus aus dem Objekt und umsetzen wenn möglich
      player moveInCargo _vhID;
      if (player == vehicle player) then {player moveInCommander _vhID};
      if (player == vehicle player) then {player moveInGunner _vhID}
      }
     }
    } forEach _this //Durchläuft alle Vehicle-Typen mit den zugehörigen Driver-Typen
   };
   sleep 1
  }
 }

[
 ["Helicopter",["USMC_Soldier_Officer", "USMC_Soldier_Pilot"]],
 ["Tank",      ["USMC_Soldier_Officer", "USMC_Soldier_Crew" ]],
 ["Plane",     ["USMC_Soldier_Pilot"]]
] execVM "Driver_Verbot.sqf";