// Lokal weiße Lichtkugel erstellen        [Vienna 13.12.2011]
//
//Aufruf: [[Position], Helligkeit, Leuchtdauer] execVM "LichtPunkt.sqf"
//
//Aufruf in Initzeile: temp = [position this, 0.003, 10] execVM "LichtPunkt.sqf"

private ["_pos","_dauer","_hell","_light"];

_pos   = _this select 0;
_hell  = _this select 1;
_dauer = _this select 2;

//weiße Kugel erstellen
drop ["\ca\data\cl_water.p3d","","Billboard",1,_dauer,[_pos select 0,_pos select 1,(_pos select 2)+0.3],
      [0,0,0],1,1.275,1,0,[0.5],[[1,1,1,1],[1,1,1,1]],[0],0,0,"","",""];

//Kugel beleuchten
_light = "#lightpoint" createVehicleLocal [_pos select 0,_pos select 1,(_pos select 2)-1];
_light setLightAmbient    [0, 0, 0];
_light setLightColor      [1500, 1200, 1000];
_light setLightBrightness _hell;
_dauer = time + _dauer;

//Licht abschalten
waituntil {time > _dauer};
deletevehicle _light;

//Lokale Lichterkette erstellen          [Vienna 13.12.2011]
//
//Aufruf: [Anzahl, Abstand, Richtung, [1 Position], Helligkeit, Leuchtdauer] execVM "LichterKette.sqf"
//
//Aufrufbeispiel für Auslöser: temp = [40, 30, getDir player, position player, 0.01, 20] execVM "LichterKette.sqf";

private ["_anzl","_abst","_dir","_pos","_dauer","_hell","_licht","_kette"];

_anzl  = _this select 0;
_abst  = _this select 1;
_dir   = _this select 2;
_pos   = _this select 3;
_hell  = _this select 4;
_dauer = _this select 5;

_kette = []; //Array für Lichter

_temp = "" createVehicleLocal _pos;

for "_i" from 1 to _anzl do //Lichter-Kette erstellen
{
  //weiße Kugel erstellen
  drop ["\ca\data\cl_water.p3d","","Billboard",1,_dauer,[_pos select 0,_pos select 1,(_pos select 2)+0.3],
        [0,0,0],1,1.275,1,0,[0.5],[[1,1,1,1],[1,1,1,1]],[0],0,0,"","",""];
  //Kugel beleuchten
  _licht = "#lightpoint" createVehicleLocal [_pos select 0,_pos select 1,(_pos select 2)-1];
  _licht setLightAmbient    [0, 0, 0];
  _licht setLightColor      [1500, 1200, 1000];
  _licht setLightBrightness _hell;
  _kette = _kette + [_licht];
  _pos = [(_pos select 0)+(sin _dir*_abst),(_pos select 1)+(cos _dir*_abst),_pos select 2]
};

//Lichter abschalten
_dauer = time + _dauer;
waituntil {time > _dauer};
{deletevehicle _x} forEach _kette;