//////////////////////////////////////////////////////////////////
// Function file for Armed Assault
// Created by: UAV_Für_MP_V1.02! Ghost [AUT] 
//////////////////////////////////////////////////////////////////

private ["_UAV_Terminal","_UAV_player","_UAV_manager","_UAV_gruppe","_UAV_drohne","_UAV_timeout"];

_UAV_Terminal = _this select 0; //Drohnen-Terminal
_UAV_player   = _this select 1; //Spieler für die Drohnen-Kontrolle
_UAV_manager  = Manager;        //Globaler Name des Drohnen-Managers

UAV = true;                     //Globale Variable, sperrt weiteren Zugriff auf die Aktion des Terminals
publicVariable "UAV";

//Drohne erstellen
_UAV_drohne = createVehicle ["MQ9PredatorB_US_EP1", _UAV_Terminal, [], 200, "FLY"];
_UAV_gruppe = createGroup West;
"US_Soldier_Pilot_EP1" createUnit [getMarkerpos "UAV_Spawn", _UAV_gruppe, "this moveindriver _UAV_drohne", 1,"FROM"]; //Dummy-Pilot  für Drohne
"US_Soldier_Pilot_EP1" createUnit [getMarkerpos "UAV_Spawn", _UAV_gruppe, "this moveingunner _UAV_drohne", 1,"FROM"]; //Dumme-Gunner für Drohne
_UAV_drohne flyInHeight 350; //Drohnen Flughöhe

//Manager Skript für Client laden (wenn Spieler nicht Host)   
If (!isServer) then {[_UAV_manager] execVM "ca\modules_e\uav\data\scripts\uav.sqf"};
sleep 2;

//Synchronisation mit dem Drohnen-Manager	
_UAV_manager synchronizeObjectsAdd [_UAV_player,_UAV_Terminal,_UAV_drohne];

TitleText[localize "STR_UAV_1","plain down"];

_UAV_timeout = time + 300; //Zeit in Sekunden bis zur Zerstörung der Drohne

//Warten auf Ereignis (ohne sleep 2; spinnt das Programm)
waitUntil {sleep 2; !alive _UAV_drohne OR !alive _UAV_player OR _UAV_timeout < time};

//Synchronisation beenden
_UAV_manager synchronizeObjectsRemove [_UAV_player,_UAV_Terminal,_UAV_drohne];

//Dummys löschen
{deleteVehicle _x} forEach units _UAV_gruppe;

TitleText[localize "STR_UAV_2","plain down"];

sleep 20;

UAV = false;  // Zugriff auf die Drohnen-Aktion wieder freigeben
publicVariable "UAV";

sleep 40;
//Drohne löschen (erst in Summe nach 60 Sekunden)
deleteVehicle _UAV_drohne;