HX3 Foren

HX3 Foren (https://hx3.de/)
-   Editing & Scripting (https://hx3.de/editing-scripting-167/)
-   -   Eagle Wing - Effekte (https://hx3.de/editing-scripting-167/eagle-wing-effekte-18368/)

MarcusErgalla 27.12.2009 11:03

Eagle Wing - Effekte
 
Hier mal die Effekte aus Eagle Wing!
Der HUD-Effekt mit Trefferwirkung folg später!

- Erdbeben -



Code:

Switch (_This) do {
Case "BIS_Earthquake": {
        While {Alive Player} Do {
                Playsound "eq";
                _This = Vehicle Player;
                For "_i" from 0 to 140 do {
                        _vx = vectorup _this select 0;
                        _vy = vectorup _this select 1;
                        _vz = vectorup _this select 2;
                        _coef = 0.01 - ((Random 0.0004) * _i);
                        _This setvectorup [
                                _vx+(-_coef+random (2*_coef)),
                                _vy+(-_coef+random (2*_coef)),
                                _vz+(-_coef+random (2*_coef))
                        ];
                        sleep (0.01 + random 0.01);
                };
                sleep (60 + Random 180);
        };
};
Default {HintC "Error in Mainfunction";};
};

Zitat:

Syntax: "BIS_Earthquake" execVM "Main.sqf";
File: SQF-Function

- Wind und Staub -



Code:

Switch (_This) do {
Case "BIS_WindAndDust": {
        setwind [0.201112,0.204166,true];
        While {true} do {
        _ran = ceil random 5;
        playsound format ["wind_%1",_ran];
        _obj = vehicle player;
        _pos = position _obj;

        setwind [0.201112*2,0.204166*2,false];
        _velocity = [random 10,random 10,-1];
        _color = [1.0, 0.9, 0.8];
        _alpha = 0.02 + random 0.02;
        _ps = "#particlesource" createVehicleLocal _pos; 
        _ps setParticleParams [["\Ca\Data\ParticleEffects\Universal\universal.p3d", 16, 12, 8], "", "Billboard", 1, 3, [0, 0, -6], _velocity, 1, 1.275, 1, 0, [9], [_color + [0], _color + [_alpha], _color + [0]], [1000], 1, 0, "", "", _obj];
        _ps setParticleRandom [3, [30, 30, 0], [0, 0, 0], 1, 0, [0, 0, 0, 0.01], 0, 0];
        _ps setParticleCircle [0.1, [0, 0, 0]];
        _ps setDropInterval 0.01;

        sleep (random 1);
        deletevehicle _ps;
        _delay = 10 + random 20;
        sleep _delay;

        };
};
Default {HintC "Error in Mainfunction";};
};

Zitat:

Syntax: "BIS_WindAndDust" execVM "Main.sqf";
File: SQF-Function

- Atombombe -



Code:

Switch (_This) do {
Case "BIS_NuclearExplosion": {
setaperture 1.5;

_Cone = "#particlesource" createVehicleLocal getpos nukepos;
_Cone setParticleParams [["\Ca\Data\ParticleEffects\Universal\Universal", 16, 7, 48], "", "Billboard", 1, 10, [0, 0, 0],
                                [0, 0, 0], 0, 1.275, 1, 0, [40,80], [[0.25, 0.25, 0.25, 0], [0.25, 0.25, 0.25, 0.5],
                                [0.25, 0.25, 0.25, 0.5], [0.25, 0.25, 0.25, 0.05], [0.25, 0.25, 0.25, 0]], [0.25], 0.1, 1, "", "", nukepos];
_Cone setParticleRandom [2, [1, 1, 30], [1, 1, 30], 0, 0, [0, 0, 0, 0.1], 0, 0];
_Cone setParticleCircle [10, [-10, -10, 20]];
_Cone setDropInterval 0.005;

_top = "#particlesource" createVehicleLocal getpos nukepos;
_top setParticleParams [["\Ca\Data\ParticleEffects\Universal\Universal", 16, 3, 48, 0], "", "Billboard", 1, 20, [0, 0, 0],
                                [0, 0, 60], 0, 1.7, 1, 0, [60,80,100], [[1, 1, 1, -10],[1, 1, 1, -7],[1, 1, 1, -4],[1, 1, 1, -0.5],[1, 1, 1, 0]], [0.05], 1, 1, "", "", nukepos];
_top setParticleRandom [0, [75, 75, 15], [17, 17, 10], 0, 0, [0, 0, 0, 0], 0, 0, 360];
_top setDropInterval 0.002;

_top2 = "#particlesource" createVehicleLocal getpos nukepos;
_top2 setParticleParams [["\Ca\Data\ParticleEffects\Universal\Universal", 16, 3, 112, 0], "", "Billboard", 1, 20, [0, 0, 0],
                                [0, 0, 60], 0, 1.7, 1, 0, [60,80,100], [[1, 1, 1, 0.5],[1, 1, 1, 0]], [0.07], 1, 1, "", "", nukepos];
_top2 setParticleRandom [0, [75, 75, 15], [17, 17, 10], 0, 0, [0, 0, 0, 0], 0, 0, 360];
_top2 setDropInterval 0.002;

_smoke = "#particlesource" createVehicleLocal getpos nukepos;
_smoke setParticleParams [["\Ca\Data\ParticleEffects\Universal\Universal", 16, 7, 48, 1], "", "Billboard", 1, 25, [0, 0, 0],
                                [0, 0, 60], 0, 1.7, 1, 0, [40,15,120],
                                [[1, 1, 1, 0.4],[1, 1, 1, 0.7],[1, 1, 1, 0.7],[1, 1, 1, 0.7],[1, 1, 1, 0.7],[1, 1, 1, 0.7],[1, 1, 1, 0.7],[1, 1, 1, 0]]
                                , [0.5, 0.1], 1, 1, "", "", nukepos];
_smoke setParticleRandom [0, [10, 10, 15], [15, 15, 7], 0, 0, [0, 0, 0, 0], 0, 0, 360];
_smoke setDropInterval 0.002;

_Wave = "#particlesource" createVehicleLocal getpos nukepos;
_Wave setParticleParams [["\Ca\Data\ParticleEffects\Universal\Universal", 16, 7, 48], "", "Billboard", 1, 20/2, [0, 0, 0],
                                [0, 0, 0], 0, 1.5, 1, 0, [50, 100], [[0.1, 0.1, 0.1, 0.5],
                                [0.5, 0.5, 0.5, 0.5], [1, 1, 1, 0.3], [1, 1, 1, 0]], [1,0.5], 0.1, 1, "", "", nukepos];
_Wave setParticleRandom [2, [20, 20, 20], [5, 5, 0], 0, 0, [0, 0, 0, 0.1], 0, 0];
_Wave setParticleCircle [50, [-80, -80, 2.5]];
_Wave setDropInterval 0.0002;


_light = "#lightpoint" createVehicleLocal [((getpos nukepos select 0)),(getpos nukepos select 1),((getpos nukepos select 2)+500)];
_light setLightAmbient[1500, 1200, 1000];
_light setLightColor[1500, 1200, 1000];
_light setLightBrightness 100000.0/100000;

sleep 1.5*2;

_Wave setDropInterval 0.001;
deletevehicle _top;
deletevehicle _top2;


sleep 4.5;

_i = 0;
while {_i < 100} do
{
        _light setLightBrightness (100.0 - _i)/100;
        _i = _i + 1;
        sleep 0.1;
};
deleteVehicle _light;

sleep 2;
setaperture -1;

_Wave setDropInterval 0.001*10;
_Wave setParticleParams [["\Ca\Data\ParticleEffects\Universal\Universal", 16, 7, 48], "", "Billboard", 1, 20/2, [0, 0, 0],
                                [0, 0, 0], 0, 1.5, 1, 0, [50, 100], [[0.1, 0.1, 0.1, 0.5],
                                [0.5, 0.5, 0.5, 0.5], [1, 1, 1, 0.3], [1, 1, 1, 0]], [1,0.5], 0.1, 1, "", "", nukepos];
_Wave setParticleCircle [50, [-40, -40, 2.5]];
debuglog ["Log:::::::::::::::::::::::::::::"];

for "_i" from 0 to 15 do {
        _smoke setParticleParams [["\Ca\Data\ParticleEffects\Universal\Universal", 16, 7, 48, 1], "", "Billboard", 1, 25, [0, 0, 0],
                                        [0, 0, 60+_i], 0, 1.7, 1, 0, [40,15,120],
                                        [[1, 1, 1, 0.4],[1, 1, 1, 0.7],[1, 1, 1, 0.7],[1, 1, 1, 0.7],[1, 1, 1, 0.7],[1, 1, 1, 0.7],[1, 1, 1, 0.7],[1, 1, 1, 0]]
                                        , [0.5, 0.1], 1, 1, "", "", nukepos];
        sleep 5;
        if (player distance nukepos < 1100) exitwith {};
};

debuglog "Log::::::::::::::::::::NUKE START";
_timeNow = time;
waituntil {(time - _timeNow) > 160 || player distance nukepos < 1100};
//sleep 160;
debuglog "Log::::::::::::::::::::NUKE END";
60 setfog 0.63;

_smoke setParticleParams [["\Ca\Data\ParticleEffects\Universal\Universal", 16, 7, 48, 1], "", "Billboard", 1, 25, [0, 0, 0],
                                [0, 0, 30], 0, 1.7, 1, 0, [40,25+10,80],
                                [[1, 1, 1, 0.2],[1, 1, 1, 0.3],[1, 1, 1, 0.3],[1, 1, 1, 0.3],[1, 1, 1, 0.3],[1, 1, 1, 0.3],[1, 1, 1, 0.3],[1, 1, 1, 0]]
                                , [0.5, 0.1], 1, 1, "", "", nukepos];
_smoke setDropInterval 0.012;
_Cone setDropInterval 0.02;
_Wave setDropInterval 0.01;

sleep 15;
deleteVehicle _Wave;
deleteVehicle _cone;
deleteVehicle _smoke;
};
Default {HintC "Error in Mainfunction";};
};

Zitat:

Syntax: "BIS_NuclearExplosion" execVM "Main.sqf";
File: SQF-Function
Note: Object NukePos is needed!
Credits: BIS

Anemia 27.12.2009 14:46

danke .. sehr hilfreich :)

MarcusErgalla 27.12.2009 15:34

Bitte, ich hoffe es hilft und wurde ja auch schon öfters gefragt!
Werde schauen das ich noch Demomissionen erstelle, damit auch noch unerfahrene User damit zurecht kommen, aber erstmal selbst weiter basteln!

Cyborg11 27.12.2009 15:57

Danke schön :)

Aber ist das Absicht, dass du die 3 Effekte, die ja eigentlich in 3 Skripten stehen, in eine main.sqf Funktion verpackt hast? :naughty:

MarcusErgalla 27.12.2009 16:46

Öhh... Mist ertappt!
Ich verfende pro Mission immer eine Function, die heißt dann "Main.sqf", da steht alles drin und aus der Gewohnheit heraus, hab ich das oben dann so auch aufgebaut! :D

Cyborg11 27.12.2009 18:47

An sich gar keine so schlechte Idee. Dann kann man in eine effects.sqf Funktion alle Effekte reinhauen und per Aufruf (durch switch) wird dann bestimmt, welcher Effekt abgespielt wird.

Werd ich mir merken! Danke :zahn:

Hast du schon den HUD Effekt gefunden? Finde nichts :/

Desert 27.12.2009 18:51

Was ist Eagle War? Hab ich was verpasst? :komisch:

Cyborg11 27.12.2009 20:13

Zitat:

Zitat von Desert (Beitrag 286623)
Was ist Eagle War? Hab ich was verpasst? :komisch:

:zahn: Jetzt erst gemerkt, dass sich M-E verschrieben hat :ugly:

@M-E: Die Kampagne heißt Eagle Wing ^^


Habe mal die Effekte zusammen in ein Skript geschrieben:
Code:

/*
==============================================================
Effekte von Eagle Wing
---------------------------------------------------
| Aufruf über:
| nul = "BIS_Earthquake" execVM "effects.sqf";                        // Erdbeben
| nul = "BIS_WindAndDust" execVM "effects.sqf";                        // Wind und Staub
| nul = "BIS_NuclearExplosion" execVM "effects.sqf";                // Atombombe - Objekt nukepos erstellen
---------------------------------------------------
Credits: BIS
==============================================================
*/

Switch (_this) do {
        Case "BIS_Earthquake": {                                        // Erdbeben
                While {Alive Player} Do {
                        Playsound "eq";
                        _This = Vehicle Player;
                        For "_i" from 0 to 140 do {
                                _vx = vectorup _this select 0;
                                _vy = vectorup _this select 1;
                                _vz = vectorup _this select 2;
                                _coef = 0.01 - ((Random 0.0004) * _i);
                                _This setvectorup [
                                        _vx+(-_coef+random (2*_coef)),
                                        _vy+(-_coef+random (2*_coef)),
                                        _vz+(-_coef+random (2*_coef))
                                ];
                                sleep (0.01 + random 0.01);
                        };
                        sleep (60 + Random 180);
                };
        };
       
        Case "BIS_WindAndDust": {                                        // Wind und Staub
                setwind [0.201112,0.204166,true];
                While {true} do {
                        _ran = ceil random 5;
                        playsound format ["wind_%1",_ran];
                        _obj = vehicle player;
                        _pos = position _obj;

                        setwind [0.201112*2,0.204166*2,false];
                        _velocity = [random 10,random 10,-1];
                        _color = [1.0, 0.9, 0.8];
                        _alpha = 0.02 + random 0.02;
                        _ps = "#particlesource" createVehicleLocal _pos; 
                        _ps setParticleParams [["\Ca\Data\ParticleEffects\Universal\universal.p3d", 16, 12, 8], "", "Billboard", 1, 3, [0, 0, -6], _velocity, 1, 1.275, 1, 0, [9], [_color + [0], _color + [_alpha], _color + [0]], [1000], 1, 0, "", "", _obj];
                        _ps setParticleRandom [3, [30, 30, 0], [0, 0, 0], 1, 0, [0, 0, 0, 0.01], 0, 0];
                        _ps setParticleCircle [0.1, [0, 0, 0]];
                        _ps setDropInterval 0.01;

                        sleep (random 1);
                        deletevehicle _ps;
                        _delay = 10 + random 20;
                        sleep _delay;
                };
        };
       
        Case "BIS_NuclearExplosion": {                                // Atombombe - Objekt nukepos erstellen
                setaperture 1.5;

                _Cone = "#particlesource" createVehicleLocal getpos nukepos;
                _Cone setParticleParams [["\Ca\Data\ParticleEffects\Universal\Universal", 16, 7, 48], "", "Billboard", 1, 10, [0, 0, 0],
                                                [0, 0, 0], 0, 1.275, 1, 0, [40,80], [[0.25, 0.25, 0.25, 0], [0.25, 0.25, 0.25, 0.5],
                                                [0.25, 0.25, 0.25, 0.5], [0.25, 0.25, 0.25, 0.05], [0.25, 0.25, 0.25, 0]], [0.25], 0.1, 1, "", "", nukepos];
                _Cone setParticleRandom [2, [1, 1, 30], [1, 1, 30], 0, 0, [0, 0, 0, 0.1], 0, 0];
                _Cone setParticleCircle [10, [-10, -10, 20]];
                _Cone setDropInterval 0.005;

                _top = "#particlesource" createVehicleLocal getpos nukepos;
                _top setParticleParams [["\Ca\Data\ParticleEffects\Universal\Universal", 16, 3, 48, 0], "", "Billboard", 1, 20, [0, 0, 0],
                                                [0, 0, 60], 0, 1.7, 1, 0, [60,80,100], [[1, 1, 1, -10],[1, 1, 1, -7],[1, 1, 1, -4],[1, 1, 1, -0.5],[1, 1, 1, 0]], [0.05], 1, 1, "", "", nukepos];
                _top setParticleRandom [0, [75, 75, 15], [17, 17, 10], 0, 0, [0, 0, 0, 0], 0, 0, 360];
                _top setDropInterval 0.002;

                _top2 = "#particlesource" createVehicleLocal getpos nukepos;
                _top2 setParticleParams [["\Ca\Data\ParticleEffects\Universal\Universal", 16, 3, 112, 0], "", "Billboard", 1, 20, [0, 0, 0],
                                                [0, 0, 60], 0, 1.7, 1, 0, [60,80,100], [[1, 1, 1, 0.5],[1, 1, 1, 0]], [0.07], 1, 1, "", "", nukepos];
                _top2 setParticleRandom [0, [75, 75, 15], [17, 17, 10], 0, 0, [0, 0, 0, 0], 0, 0, 360];
                _top2 setDropInterval 0.002;

                _smoke = "#particlesource" createVehicleLocal getpos nukepos;
                _smoke setParticleParams [["\Ca\Data\ParticleEffects\Universal\Universal", 16, 7, 48, 1], "", "Billboard", 1, 25, [0, 0, 0],
                                                [0, 0, 60], 0, 1.7, 1, 0, [40,15,120],
                                                [[1, 1, 1, 0.4],[1, 1, 1, 0.7],[1, 1, 1, 0.7],[1, 1, 1, 0.7],[1, 1, 1, 0.7],[1, 1, 1, 0.7],[1, 1, 1, 0.7],[1, 1, 1, 0]]
                                                , [0.5, 0.1], 1, 1, "", "", nukepos];
                _smoke setParticleRandom [0, [10, 10, 15], [15, 15, 7], 0, 0, [0, 0, 0, 0], 0, 0, 360];
                _smoke setDropInterval 0.002;

                _Wave = "#particlesource" createVehicleLocal getpos nukepos;
                _Wave setParticleParams [["\Ca\Data\ParticleEffects\Universal\Universal", 16, 7, 48], "", "Billboard", 1, 20/2, [0, 0, 0],
                                                [0, 0, 0], 0, 1.5, 1, 0, [50, 100], [[0.1, 0.1, 0.1, 0.5],
                                                [0.5, 0.5, 0.5, 0.5], [1, 1, 1, 0.3], [1, 1, 1, 0]], [1,0.5], 0.1, 1, "", "", nukepos];
                _Wave setParticleRandom [2, [20, 20, 20], [5, 5, 0], 0, 0, [0, 0, 0, 0.1], 0, 0];
                _Wave setParticleCircle [50, [-80, -80, 2.5]];
                _Wave setDropInterval 0.0002;


                _light = "#lightpoint" createVehicleLocal [((getpos nukepos select 0)),(getpos nukepos select 1),((getpos nukepos select 2)+500)];
                _light setLightAmbient[1500, 1200, 1000];
                _light setLightColor[1500, 1200, 1000];
                _light setLightBrightness 100000.0/100000;

                sleep 1.5*2;

                _Wave setDropInterval 0.001;
                deletevehicle _top;
                deletevehicle _top2;


                sleep 4.5;

                _i = 0;
                while {_i < 100} do
                {
                        _light setLightBrightness (100.0 - _i)/100;
                        _i = _i + 1;
                        sleep 0.1;
                };
                deleteVehicle _light;

                sleep 2;
                setaperture -1;

                _Wave setDropInterval 0.001*10;
                _Wave setParticleParams [["\Ca\Data\ParticleEffects\Universal\Universal", 16, 7, 48], "", "Billboard", 1, 20/2, [0, 0, 0],
                                                [0, 0, 0], 0, 1.5, 1, 0, [50, 100], [[0.1, 0.1, 0.1, 0.5],
                                                [0.5, 0.5, 0.5, 0.5], [1, 1, 1, 0.3], [1, 1, 1, 0]], [1,0.5], 0.1, 1, "", "", nukepos];
                _Wave setParticleCircle [50, [-40, -40, 2.5]];
                debuglog ["Log:::::::::::::::::::::::::::::"];

                for "_i" from 0 to 15 do {
                        _smoke setParticleParams [["\Ca\Data\ParticleEffects\Universal\Universal", 16, 7, 48, 1], "", "Billboard", 1, 25, [0, 0, 0],
                                                        [0, 0, 60+_i], 0, 1.7, 1, 0, [40,15,120],
                                                        [[1, 1, 1, 0.4],[1, 1, 1, 0.7],[1, 1, 1, 0.7],[1, 1, 1, 0.7],[1, 1, 1, 0.7],[1, 1, 1, 0.7],[1, 1, 1, 0.7],[1, 1, 1, 0]]
                                                        , [0.5, 0.1], 1, 1, "", "", nukepos];
                        sleep 5;
                        if (player distance nukepos < 1100) exitwith {};
                };

                debuglog "Log::::::::::::::::::::NUKE START";
                _timeNow = time;
                waituntil {(time - _timeNow) > 160 || player distance nukepos < 1100};
                //sleep 160;
                debuglog "Log::::::::::::::::::::NUKE END";
                60 setfog 0.63;

                _smoke setParticleParams [["\Ca\Data\ParticleEffects\Universal\Universal", 16, 7, 48, 1], "", "Billboard", 1, 25, [0, 0, 0],
                                                [0, 0, 30], 0, 1.7, 1, 0, [40,25+10,80],
                                                [[1, 1, 1, 0.2],[1, 1, 1, 0.3],[1, 1, 1, 0.3],[1, 1, 1, 0.3],[1, 1, 1, 0.3],[1, 1, 1, 0.3],[1, 1, 1, 0.3],[1, 1, 1, 0]]
                                                , [0.5, 0.1], 1, 1, "", "", nukepos];
                _smoke setDropInterval 0.012;
                _Cone setDropInterval 0.02;
                _Wave setDropInterval 0.01;

                sleep 15;
                deleteVehicle _Wave;
                deleteVehicle _cone;
                deleteVehicle _smoke;
        };
       
        Default {HintC "Error in effectsfunction";};

};


comrade91 27.12.2009 20:27

Hmm irgendwie geht das bei mir nicht :(

Hab jetzt eine earthquake.sqf Datei erstellt und beim Auslöser (Bei der Aktivierung)
"BIS_Earthquake" execVM "Main.sqf"; reingeschrieben.
Danach kommt bei mir immer "Typ Script, erwartet nichts"
Woran liegt das^^

(Sorry bin neu bei der Sache mit den Scripts usw :zahn:)

Mfg.

Cyborg11 27.12.2009 20:30

Guck mal ein Post weiter oben. Bei dem gesamten Skript steht, wie die Effekte richtig aufgerufen werden :)

Code:

nul = "BIS_Earthquake" execVM "Main.sqf";

comrade91 27.12.2009 20:39

Achso :D

Danke dir ^^

comrade91 27.12.2009 21:09

schade, dass die Atombombe nichts macht :ugly:
Und leider ist der Effekt zu schnell vorbei ^^ In der Kampagne hielt es Minutenlang^^

MarcusErgalla 27.12.2009 21:25

Zitat:

Zitat von Cyborg11 (Beitrag 286622)
Hast du schon den HUD Effekt gefunden? Finde nichts :/

Gefunden und verbaut! :naughty:
Werde schauen das ich morgen noch die Demomissionen dazu fertige und das dann zum DL gegen Bares bereit stelle! :D

Cyborg11 27.12.2009 21:31

Zitat:

Zitat von M-E (Beitrag 286659)
Gefunden und verbaut! :naughty:
Werde schauen das ich morgen noch die Demomissionen dazu fertige und das dann zum DL gegen Bares bereit stelle! :D

Darfste gar nicht. Das sag ich BIS :confused:

Gib mal bitte Skript ^^ Beispielmission kannst dann immer noch uploaden. Ich brauch nur den Effekt, keine Mission. :zahn:

comrade91 28.12.2009 10:28

Need HUD Effekt :D:naughty:

burns 28.12.2009 22:21

Den mit den Bluteffekten, den Schlammspritzern, oder das Picture in Picture Ding?
Ich hoffe natürlich das der kleine M-E noch alle drei nachreicht. Sind wirklich tolle Spielereien!

Cyborg11 29.12.2009 12:56

Da M-E nichts mehr postet, habe ich mir mal schnell die Skripte zusammen gesucht :)


Picture-in-Picture:
Code:

scriptName "fn_pip.sqf";
/*
        File: pip.sqf
        Author: Karel Moricky

        Description:
        Picture In Picture

        Parameter(s):
                _this: Picture or Array of pictures

        Returns:
        Nothing
*/
private ["_input","_inputtype","_layer","_display","_pip","_file1","_file2","_layer1","_layer2"];
disableserialization;
_input = _this select 0;
_inputtype = typename _input;

//--- Single picture
if (_inputtype == typename "") then {
        if (_input != "") then {
                _layer = if (count _this > 1) then {_this select 1} else {100011};
                _display = uinamespace getvariable "str_pip";
                if (isnil "_display") then {
                        100011 cutrsc ["PIP","plain"];
                        _display = uinamespace getvariable "str_pip";               
                };
                if (isnull _display) then {
                        100011 cutrsc ["PIP","plain"];
                        _display = uinamespace getvariable "str_pip";
                };
                _pip = _display displayctrl _layer;
                _pip ctrlsettext _input;
                _pip ctrlcommit 0;
                rah1 setObjectTexture [1,_input];
                rah1 animate ["map_repos",0.6];
        } else {
                100011 cuttext ["","plain"];
                rah1 animate ["map_repos",1];
        };
};

//--- Multiple pictures
if (_inputtype == typename []) then {
        _count = (count _input - 1);

        for "_i" from 0 to _count do {
                _file = _input select _i;
                _layer = 100011 + _i;
                [_file,_layer] call bis_ew_fnc_pip;
        };
        sleep 1;
        _display = uinamespace getvariable "str_pip";
        _load = _display displayctrl 100099;
        _load ctrlsetfade 1;
        _load ctrlcommit 0;
        for "_i" from 0 to _count do {
                _layer = 100011 + _count - _i;
                _pip = _display displayctrl _layer;
                _pip ctrlsetfade 1;
                _pip ctrlcommit 0.2;
                sleep 1;
        };

        [""] call bis_ew_fnc_pip;
};


Und Screen Effekte:
Code:

scriptname "EW screen.sqf";
/*
        File: screen.sqf
        Author: Karel Moricky

        Description:
        Screen Effects

        Parameter(s):
        _this select 0: Intensity (0-1)
        _this select 1: (Optional) Dirt
*/
disableserialization;

_int = _this select 0;
_dirt = if (count _this > 1) then {_this select 1} else {false};

if (isnil {uinamespace getvariable "str_screen"}) then {uinamespace setvariable ["str_screen",displaynull]};
if (isnull (uinamespace getvariable "str_screen")) then {1918 cutrsc ["screen","plain"]};
_display = uinamespace getvariable "str_screen";

if (!_dirt) then {

        //--- Select free layer
        _control = controlnull;
        for "_i" from 1001 to 1006 do {
                _c = _display displayctrl _i;
                _f = ctrlfade _c;
                _p = ctrlposition _c;
                if ((_p select 3) == 0) then {_f = 1};
                if (_f == 1) exitwith {_control = _c};
        };
        if (isnull _control) exitwith {debuglog ["Log::::::FAIL"]};

        //--- Select position
        _w = safezoneW * _int;
        _h = _w / 0.75;
        _pos = [
                ((safezoneX - _w/2) + random (safezoneW)),
                ((safezoneY - _h/2) + random (safezoneH)),
                _w,
                _h
        ];

        //--- Fade out (0s)
        _control ctrlsetposition _pos;
        _control ctrlsetfade 1;
        _control ctrlcommit 0;

        //--- Fade in (0.1s)
        _control ctrlsetfade 0;
        _control ctrlcommit 0.1;
        waituntil {ctrlcommitted _control};

        sleep 3;

        //--- Fade out (random 5-15s)
        _control ctrlsetfade 1;
        _control ctrlcommit (5 + random 10);
        waituntil {ctrlcommitted _control};

        //--- Reset
        if (ctrlfade _control == 0) then {
                _control ctrlsetposition [0,0,0,0];
                _control ctrlcommit 0;
        };


} else {
        _control = _display displayctrl 1000;
        _pos = [safezoneX,safezoneY,safezoneW,safezoneH];

        //--- Fade out (0s)
        _control ctrlsetposition _pos;
        _control ctrlsetfade 1;
        _control ctrlcommit 0;

        //--- Fade in (0.2s)
        _control ctrlsetfade 0;
        _control ctrlcommit 0.2;
        waituntil {ctrlcommitted _control};

        sleep 3;

        //--- Fade out (random 5-10s)
        _control ctrlsetfade 1;
        _control ctrlcommit (5 + random 5);
        waituntil {ctrlcommitted _control};

};


comrade91 29.12.2009 13:38

Super, danke Cyborg. Nur ne kruze Frage: was soll man bei der Aktivierung für eine Befehl eingeben^^?:komisch::confused:
:D

Mfg.

IbastI 29.12.2009 14:08

bei picture in picture fällt mir doch glatt nochmal meine frage aus wunschaddonsthread ein...ist es nicht möglich darüber eine spezielle zieloptik zu generieren?
also das wenn man durch's snipergewehr guckt das zielen so aussieht wie bei "Red Orchestra"?
das wäre ein feines ding^^
muss allerdings gestehen dass ich die EW kampagne bis jetzt jungfräulich gelassen habe und deswegen am thema vorbeischreib :bahnhof:

Cyborg11 29.12.2009 20:54

Zitat:

Zitat von comrade91 (Beitrag 287027)
Super, danke Cyborg. Nur ne kruze Frage: was soll man bei der Aktivierung für eine Befehl eingeben^^?:komisch::confused:
:D

Mfg.

Das ist die Frage aller Fragen :zahn:
Auf jeden Fall muss man noch die Bilder usw. in der description.ext definieren :)

@IbastI: Theoretisch ja, aber es ist eigentlich nichts anderes als ein Dialog und ich weiß nicht ob man den Dialog dann so verändern kann, dass dieser das Zielfernrohr ausfüllt. Habe mich diesbezüglich zu wenig mit Dialogen beschäftigt. :zahn:

@M-E: Was ist denn nun mit der Beispielmission? :naughty:


Alle Zeitangaben in WEZ +1. Es ist jetzt 20:35 Uhr.

Angetrieben durch vBulletin, Entwicklung von Philipp Dörner & Tobias


SEO by vBSEO 3.2.0 ©2008, Crawlability, Inc.

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119