PDA

Archiv verlassen und diese Seite im Standarddesign anzeigen : Fahrzeuge Respawn lassen


Schradder
06.03.2009, 22:10
Hi
Wie kann ich zerstörte Fahrzeuge respawn lassen.?
Muss ich was in der Description.ext eingeben?

Virility92
06.03.2009, 23:16
hast du schon den editing guide von mr-murray runtergeladen? da stehts drin, und noch vieles mehr!

Garstiger Hobbit
07.03.2009, 15:16
Wenn du ein Fahrzeug respawnen lassen wills dann musst du auf alle fälle folgendes beachten.

Startpositin des Fahrzeugs
Startdir des Fahrzeugs
Typ des Fahrzeugs

Folgndes ist noch beim Fahrzeugrespawn zu beachten es darf nur auf dem Server laufen.
Ich würde empfehlen es in Sqf syntax zu schreiben geht am einfachsten.

Mr-Murray
10.03.2009, 16:09
Lade dir mal meinen Vehiclerespawn runter, falls dir Standard zu langweilig ist.

DOWNLOAD (http://www.djkane.de/armafiles/vehicle-respawn_mr-murray_1.0.rar)

Christian.1987
20.05.2009, 15:08
Ich will jetzt kein neuen Thema deswegen aufmachen.

So ich hab die Fahrzeug Respawn Beispielmission von Mr-Murry mall ausprob.

In der Mission ist es so das das Fahrzeug immer an der selben stelle wider spawn´t wo es Zerstört wurde. :zahn:

Ich will aber das das Fahrzeug immer an dem selben Platz Spawn´t, soll heißen da wo ich das Fahrzeug im Editor Plaziert hab soll es nach zertörung wider Verfügbar sein (also zb. in der Basis).

Wer kann mir da weiter helfen. Plase ;)

DirtyHarryTPC
20.05.2009, 16:13
einfach den Guide ziehen :rolleyes: da steht doch alles drin !

Christian.1987
20.05.2009, 18:47
Der Clue ist ja das genau die Beispiel Mission so aufgebaut ist wie im Guide Steht. Hilft mir also nett weiter.

Das neue Fahrzeug erscheint immer wider da wo es Zerstört wurde.

Ich habs auch schon mit Ganz normallen Vehicle Respawn Marker also (Respawn_Vehicle_West) ausprob. da ich aber mehrere Fahrzeuge habe geht das auch irgendwie nett.

Xeno
20.05.2009, 19:01
Zwei Varianten...

Erste, respawn wenn Fahrzeug leer und bewegt worden ist:


// by Xeno
private ["_vehicle", "_delay", "_startpos", "_startdir", "_type", "_moved"];
if (!isServer) exitWith{};

_vehicle = _this select 0;
_delay = _this select 1;
_startpos = getpos _vehicle;
_startdir = getdir _vehicle;
_type = typeof _vehicle;

while {true} do {
sleep 2 + random 2;
if (({alive _x} count (crew _vehicle)) == 0) then {
_moved = (if (_vehicle distance _startpos > 5) then {true} else {false});
if (_moved || !(alive _vehicle)) then {
sleep _delay;
if (alive _vehicle && ({alive _x} count (crew _vehicle)) > 0) exitWith {};
deletevehicle _vehicle;
sleep 0.5;
_vehicle = _type createvehicle _startpos;
_vehicle setpos _startpos;
_vehicle setdir _startdir;
};
};
};
Zweite Variante, Respawn nur, wenn Fahrzeug zerstört ist:


// by Xeno
private ["_vehicle", "_delay", "_startpos", "_startdir", "_type"];
if (!isServer) exitWith{};

_vehicle = _this select 0;
_delay = _this select 1;
_startpos = getpos _vehicle;
_startdir = getdir _vehicle;
_type = typeof _vehicle;

while {true} do {
sleep 2 + random 2;
if (({alive _x} count (crew _vehicle)) == 0) then {
if (!(alive _vehicle)) then {
sleep _delay;
deletevehicle _vehicle;
sleep 0.5;
_vehicle = _type createvehicle _startpos;
_vehicle setpos _startpos;
_vehicle setdir _startdir;
};
};
};
In die init Zeile folgendes rein:

handle = [this, 120] execVM "wie_du_das_script_genannt_hast.sqf"

Die Respawnzeit 120 kannst Du ersetzen wie Du möchstest.

Nicht getestet, nur schnell aus den Fingern zusammengeschrieben.

Xeno

Vienna
20.05.2009, 19:07
Das neue Fahrzeug erscheint immer wider da wo es Zerstört wurde.
Steht bei dir in der Description.ext auch die richtige Respawnart? ---> respawnVehicle=3;

Christian.1987
20.05.2009, 19:52
Vienna, du bist einfach der Beste hat 1a Funktioniert.

Vielen Vielen Dank, Vienna :daumen: :daumen: :daumen: ;)

DirtyHarryTPC
20.05.2009, 19:57
steht aber dabei welche zahlen du ändern musst damit es so oder so geht.
Augen aufmachen ;)

Xeno
20.05.2009, 21:28
Hab ja nun schon ein paar hundert ArmA MP Missionen gesehen und exakt nur eine, die respawnVehicle benutzt hat.

Und bei dieser ist es in kurzer Zeit wieder rausgeflogen, weil es Probleme verursacht hat (afair).

Nur so als Tip :)

Xeno

Christian.1987
20.05.2009, 21:33
Also bei mir geht er ohne Prob.

Ich hab die Zeit noch auf 20 sec. gesetzt, also nach Zerstörung des Fahrzeuges wider in der Base steht :D. (Geht, Wunderbar :daumen:)


Der Script ist von dir Xeno :D :daumen:

// by Xeno

Christian.1987
13.06.2009, 13:29
Ähmm mir ist aufgefallen das der Script nicht mit Flugzeugen geht. :zahn:

Woran kann das Ligen ?

Ich wollte das der AH1 wider in der Basis Steht wen er Zerstört wird. Gett aber nett. :(