Einzelnen Beitrag anzeigen
Alt 02.03.2016, 20:39   #10 (permalink)
Drunken Officer
500 Beiträge1000 Beiträge
 
Benutzerbild von Drunken Officer
 
Registriert seit: 15.05.2011
Beiträge: 1.109
Standard

Ich habe es z.B. so gemacht. Folgender gedachter Verlauf:
- Team startet in Basis und der Heli (Transe) steht dort bereits.
- Team wird ausgeflogen zu Punkt A
- Team raus, Heli zurück
- Team ist fertig, alle tot, halb Altis in Flammen
- Heli kommt -> alle rein
- Heli fliegt zurück zur Basis
- Bier trinken

Dazu laße ich in der InitServer.sqf u.a. folgenden Aufruf machen:
Code:
_varload = execVM "Variablen\variablen.sqf";
waituntil { sleep 1; scriptdone _varload};
In der Variablen.sqf steht dann folgendes drin:
Code:
DOF_fnc_trnChopper = 
    {
        private ["_lfz", "_gruppe", "_LZ", "_LP", "_wph", "_wpe", "_dof_repair_parts"];
        _lfz = _this select 0;
        _gruppe = _this select 1;
        _LZ = _this select 2;
        _LP = _this select 3;
        _art = _this select 4;
        
        switch (_art) do 
        
        {
            case "rein": 
                            {
                                    //waituntil {sleep 2;{_x in transportheli} count units _gruppe == count units _gruppe };
                                    _wph = (group _lfz) addwaypoint [getMarkerPos _LZ, 0];
                                    _wph setWaypointtype "MOVE";
                                    _wph setWaypointSpeed "NORMAL";
                                    _wph setWaypointBehaviour "SAFE";
                                    _wph setWaypointStatements ["true", "(vehicle this) LAND 'GET OUT';"]; 
                                    waitUntil {sleep 1; _lfz distance getWPPos [(group _lfz), 1] < 1000};    
                                    _wph setWaypointSpeed "LIMITED";
                                    waituntil {sleep 2; {_x in _lfz} count units _gruppe == 0 };
                            };
            case "raus":
                            {
                                    _wph = (group _lfz) addwaypoint [getMarkerPos _LZ, 0];
                                    _wph setWaypointtype "MOVE";
                                    _wph setWaypointSpeed "NORMAL";
                                    _wph setWaypointBehaviour "SAFE";
                                    _wph setWaypointStatements ["true", "(vehicle this) LAND 'GET IN';"]; 
                                    waituntil {sleep 2; {_x in _lfz} count units _gruppe == count units _gruppe };
                            };
        };
                _wpe = (group _lfz) addwaypoint [(getpos _LP), 0];
                _wpe setWaypointStatements ["true", "(vehicle this) LAND 'LAND';"]; 
                waitUntil {sleep 5; isTouchingGround _lfz};
                _lfz action ["engineOff", _lfz];
                _dof_repair_parts = (configfile >> "CfgVehicles" >> typeof _lfz >> "HitPoints") call BIS_fnc_getCfgSubClasses; 
                _lfz setDammage 0; 
                {_lfz setHit [_x, 0] } forEach _dof_repair_parts;
                _lfz setfuel 1;
                _lfz setVehicleAmmo 1;
                            
        
                            
    };
Jetz will ich erreichen, dass der Heli meine Leute zum Einsatzort fliegt.
[Transe, (group p1), "mkr_LZ_rein", helipad1, "rein"] spawn DOF_fnc_trnChopper;

Wenn das ganze über nen Trigger läuft, dann
if (isServer) then { .... };

Jetz will ich erreichen, dass der Heli meine Leute aus dem Einsatzort fliegt.
[Transe, (group p1), "mkr_LZ_raus", helipad1, "raus"] spawn DOF_fnc_trnChopper;
__________________
Bewegende Momente bei ArmA 3

Geändert von Drunken Officer (02.03.2016 um 20:42 Uhr).
Drunken Officer ist offline