HX3 Foren - Munition für NLAW bzw. Panzerfaust 3, DM51 und GPS

HX3 Foren (https://hx3.de/)

- Editing & Scripting (https://hx3.de/editing-scripting-187/)

- - Munition für NLAW bzw. Panzerfaust 3, DM51 und GPS (https://hx3.de/editing-scripting-187/munition-fuer-nlaw-bzw-panzerfaust-3-dm51-gps-23362/)

Munition für NLAW bzw. Panzerfaust 3, DM51 und GPS

Moin nochmal,

ich bin jetzt beim Punkt "bewaffnen" angelangt und habe folgende Probleme dabei.

Ich benutze den BWmod und will einige Truppmitglieder mit der Panzerfaust 3 plus Munition ausrüsten. Ich füge also die Panzerfaust mit "this addWeapon "BWA3_Pzf3";" hinzu. Das klappt wunderbar, jedoch wird mir die Munition nicht angezeigt, die ich mit "this addMagazine "BWA3_Pzf3_IT";" hinzufüge. Da steht dann 0.

Erst habe ich an einen Bug beim BWmod gedacht und einfach das mitgelieferte NLAW genommen, aber auch da kann ich keine Munition hinzufügen mit this addMagazine "NLAW_AT_F"; this addWeapon "launch_NLAW_F";

Ich hab dazu noch ein Backpack mit auf den Weg gegeben, scheint aber auch nicht zu helfen.

Darüberhinaus entfernt er mir mit this removeItem "ItemGPS"; auch nicht das GPS, was einfach weiterhin fröhlich im Inventar bleibt.

Ich füge ausserdem noch DM51 Granaten hinzu, die ich zwar im Inventar habe, aber nicht werfen kann. Andere Standardgranaten aus Arma 3 gehen problemlos.

Andere Waffen (Assault Rifles), Magazine, Firs Aid Kits usw. funktionieren einwandfrei.

Viele Grüße

Commander | Kai

Wenn es mit den Standardwaffen und Munition klappt, dann könnte es am BWmod liegen. Man sollte als Anfänger vorerst nur mit dem originalen Spiel Erfahrungen sammeln. Die Bugs vom Original reichen vollkommen aus, um die Nerven zu strapazieren!

Zu beachten wäre, das bei Bewaffnung immer die Munition vor den Waffen einzufügen und bei mehreren Waffen die primäre Waffe festzulegen ist.

Habe erst die Munition hinzugefügt, dann die Waffen.

Mit der Standard NLAW hat das auch nicht geklappt.

Ich werde nachher mal probieren das ohne den BWmod zu machen. Schade, zu BW Einheiten habe ich einfach mehr bezug als zu Blufor NATO Einheiten :D

Aber grundsätzlich gibt es nicht mehr dabei zu beachten als das was ich gemacht habe?

Es ist wichtig die primäre Waffe zu selektieren. Dabei ist zu beachten ob diese Waffe einen Granatwerfer hat.

Hier findest du eine entsprechende Routine zu den "muzzles": http://hx3.de/editing-scripting-167/...30/#post320707

Mit der Annahme, dass sie bei Arma3 auch noch so funktioniert.

Danke für die Hilfe. Ich glaube, dass es einfacher ist, wenn ich ne Waffenkiste am Anfang der Mission hinstelle, wo die Spieler sich aufmunitionieren können mit der Panzerfaust und den Granaten. Eins nach dem anderen. Bin ja schon froh das ich soweit bin, dass die Mission (Hubschraubertaxi, Funksprüche abspielen, zuweisen von Aufgaben usw. usw.) im Grunde genommen so funktioniert wie ich mir das vorstelle.

Muss noch etwas basteln, dann werd ich Mission hier auch hochladen.

Vielen Dank für Deine Hilfe, die ist _sehr_ willkommen!!!

Commander / Kai

Ich meine im BIF BWMod Thread gelesen zu haben, dass man die Handgranaten der BWMod nicht per Befehl zuweisen kann bzw. diese dann nicht funktionieren.

Wenn du das mit Munitionskisten löst, dann ist es von Vorteil die Kisten mit den gewünschten Waffen und Munition zu bestücken. Folgend ein Skript mit dem du Munikisten nach eigenen Wünschen "umrüsten" kannst.

Sieh dir beim Beispiel im Code an, wie Waffen und Munition anzuführen sind. So kann jede Kiste mit anderen Waffen gefüllt werden.

In die Variablen Waffen, Magazine und Granten setzt du immer die von dir gewünschte Befüllung vor dem Aufruf des Skripts ein. Beachte auch den jeweiligen Namen der Munikiste.

Aufrufen kannst du das in der Init.sqf oder auch in einem Auslöser.

Skript: WaffenKiste.sqf (auch als Anhang vorhanden)

Code:

/*

Skript WaffenKiste.sqf (Multiplayer ab Arma2 OA)



Aufruf: [NameMunikiste, Array-Waffen, Array-Magazine, Array-Granaten] execVM "WaffenKiste.sqf";



Beispiel für Munikiste mit Namen Kiste1:



Waffen   = ["M9","Colt1911"];

Magazine = ["15Rnd_9x19_M9","7Rnd_45ACP_1911"];

Granaten = ["HandGrenade","PipeBomb"];

temp = [Kiste1, Waffen, Magazine, Granaten] execVM "WaffenKiste.sqf";

*/



if (!isserver) exitwith {}; //Skript nur für den Server



//Lokale Variable

private ["_kiste","_waffen","_munition","_granaten","_jeWaffe","_jeMunition","_jeGranaten"];



//Parameter übernehmen

_kiste    = _this select 0;  //Munikiste 

_waffen   = _this select 1;  //Waffenliste

_munition = _this select 2;  //Munitionsliste

_granaten = _this select 3;  //Granatenliste



//Stück jeder Art in der Kiste

_jeWaffe    =  5;            //Anzahl jeder Waffenart

_jeMunition = 10 * _jeWaffe; //Anzahl jeder Munitionsart

_jeGranaten =  4 * _jeWaffe; //Anzahl jeder Granatenart



sleep 1; //allgemeine Initialisierung abwarten

  

//Waffenkiste leeren

clearWeaponCargoGlobal   _kiste;

clearMagazineCargoGlobal _kiste;

 

// Kiste mit Waffen bestücken

for "_i" from 0 to count _waffen - 1 do

 {

  _kiste addWeaponCargoGlobal [_waffen select _i, _jeWaffe]

 };

// Kiste mit Magazinen bestücken

for "_i" from 0 to count _munition - 1 do

 {

  _kiste addMagazineCargoGlobal [_munition select _i, _jeMunition]

 };

// Kiste mit Granaten bestücken

for "_i" from 0 to count _granaten - 1 do

 {

  _kiste addMagazineCargoGlobal [_granaten select _i, _jeGranaten]

 };