Armed-Assault.de Twitter
Antwort
 
Themen-Optionen Ansicht
Alt 04.12.2013, 15:42   #1 (permalink)
Newbie
 
Registriert seit: 03.11.2013
Beiträge: 23
Standard BIS_fnc_3DCredits "reparieren"

ihr kennt ja das Problem mit bis_fnc_3dCredits, dass der Text nicht mehr angezeigt wird.
Ich hab´s getestet und es scheint ja seitens BI noch nicht behoben zu sein.
Ich habe die 3dCredits bei mir wie folgt zum Laufen gebracht:

- script fnc_3dcredits.sqf kopieren und als eigene Funktion ("Meine3DFunktion") initialisieren.
- in der eigenen Funktion folgende Änderung machen:

Code:
scriptName "fn_3Dcredits.sqf";
/*
    Author: Karel Moricky

    Description:
    3D credits.

    Parameter(s):
    _this select 0: STRING - Text
    _this select 1: ARRAY - Position in 3D world

    Returns:
    True
*/
disableserialization;
private ["_text","_pos","_display","_control","_w","_h","_minsDis","_dis","_alpha","_pos2D"];

_text = _this select 0;
_pos = _this select 1;
_minDis = if (count _this > 2) then {_this select 2} else {20};
_fadeDis = if (count _this > 3) then {_this select 3} else {1.5};
if (isnil "BIS_fnc_3dCredits_n") then {BIS_fnc_3dCredits_n = 0;};

if (typename _pos == typename objnull) then {_pos = position _pos};
if (typename _pos == typename "") then {_pos = markerpos _pos};

(("BIS_fnc_3dCredits_" + str BIS_fnc_3dCredits_n) call bis_fnc_rscLayer) cutrsc ["rscDynamicText","plain"];
BIS_fnc_3dCredits_n = BIS_fnc_3dCredits_n + 1;

//#define DISPLAY (uinamespace getvariable "BIS_dynamicText")
//#define CONTROL (DISPLAY displayctrl 9999)

_display = uinamespace getvariable "BIS_dynamicText";
_control = _display displayctrl 9999;

#define DISPLAY    _display
#define CONTROL    _control

CONTROL ctrlsetfade 1;
CONTROL ctrlcommit 0;
CONTROL ctrlsetstructuredtext parsetext _text;
CONTROL ctrlcommit 0;

_w = safezoneW;//0.5;
_h = safezoneH;//0.3;

while {true} do {

    sleep 0.01; // <-- DIESER SLEEP MUSS REIN DANN FUNKTIONIERT ES
    _dis = player distance _pos;
    _alpha = abs ((_dis / _minDis) - _fadeDis);

    if (_alpha <= 1) then {
        _pos2D = worldtoscreen _pos;

        if (count _pos2D > 0) then {
            CONTROL ctrlsetposition [
                (_pos2D select 0) - _w/2,
                (_pos2D select 1) - _h/2,
                _w,
                _h
            ];
            //CONTROL ctrlsetbackgroundcolor [0,0,0,0.5];
            CONTROL ctrlsetstructuredtext parsetext _text;
            CONTROL ctrlsetfade (_alpha^3);
            CONTROL ctrlcommit 0.01;
        } else {
            CONTROL ctrlsetfade 1;
            CONTROL ctrlcommit 0.1;
        };
    } else {
        CONTROL ctrlsetfade 1;
        CONTROL ctrlcommit 0.1;
        sleep 0.1;
    };
    sleep 0.01;
};
SmokyJoey ist offline   Mit Zitat antworten
Antwort


Aktive Benutzer in diesem Thema: 1 (Registrierte Benutzer: 0, Gäste: 1)
 
Themen-Optionen
Ansicht

Forumregeln
Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus


Kontakt - HX3.de - Archiv - Nach oben

Angetrieben durch vBulletin, Entwicklung von Philipp Dörner & Tobias



SEO by vBSEO 3.2.0 ©2008, Crawlability, Inc.

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116