Armed-Assault.de Twitter
Antwort
 
Themen-Optionen Ansicht
Alt 18.02.2013, 20:35   #1 (permalink)
Newbie
 
Benutzerbild von TheRhisd
 
Registriert seit: 12.09.2012
Beiträge: 33
Standard Seite nicht erkannt?

Guten Tag zusammen.
Ich habe neulich eine PvP Mission erstellt, habe nun aber das Problem, das Einheiten nicht mehr richtig erkannt werden, sobald sie ein bestimtes Script benutzt haben o.O
Das besagte Script ist ein selbst geschriebenen FallschirmTelportationsAbsprung Script, das Einheiten schnell über die Map bringt (recht nützlich).
Wenn man also auf diesem Weg reist, kann man keine Basis mehr erobern (darum geht es in der Mission...).
Hab nichts zu diesem Thema gefunden und frag deshalb hier mal nach:
Kennt das jemand? Weiß jemand ne Lösung?

Falls das Hilft ist hier das Skript:
Code:
/*
====================
FallschirmSprung Script v0.1
by Rhisd
====================
*/
_caller = _this select 1;
_height = _this select 3;

if !(local Player) exitWith {};
if (jumpactive) exitWith {_caller groupChat "Script in use... Try later."};
jumpactive = true;

titleText ["Durch Klick auf die Karte den Absprungort waehlen!", "plain down"];
onMapSingleClick "'jumppoint' setMarkerPos _pos; 'jumppoint' SetMarkerType 'Destroy'; jumpactive = false";

while {jumpactive} do {sleep 0.2};
_chute = "ParachuteWest" createVehicle getMarkerPos "jumppoint";
_chute setPos [(getpos _chute select 0), (getpos _chute select 1), _height];
sleep 0.5;
_caller moveInDriver _chute;
titleText ["", "plain down"];
onMapSingleClick "";
"jumppoint" setMarkerPos [0,0];
"jumppoint" setMarkerType "Empty";

while {(getPos _caller select 2) > 2 } do {sleep 1};
sleep 10;
deleteVehicle _chute;
EDIT: Die Einheit wird nach dem Benutzen des Scriptes nicht mehr als OPFOR Einheit von einem Trigger erkannt.

Geändert von TheRhisd (18.02.2013 um 20:46 Uhr).
TheRhisd ist offline   Mit Zitat antworten
Alt 18.02.2013, 20:49   #2 (permalink)
Imperator fori nocturni - This sucks more than anything that has ever sucked before 10 Jahre hx3
20.000 Beiträge
 
Benutzerbild von burns
 
Registriert seit: 13.04.2003
Ort: Monerica
Alter: 35
Beiträge: 32.223
Standard

Tja, wie wärs mit ParachuteEast?

k.A. obs hilft, aber klingt Arma-logisch
__________________

burns ist offline   Mit Zitat antworten
Alt 18.02.2013, 20:56   #3 (permalink)
Newbie
 
Benutzerbild von TheRhisd
 
Registriert seit: 12.09.2012
Beiträge: 33
Standard

Hatte ich auch gedacht und getestet aber mit ParachuteEast klappt es auch nicht :/
TheRhisd ist offline   Mit Zitat antworten
Alt 18.02.2013, 22:30   #4 (permalink)
SQF Zauberer 10 Jahre hx3
500 Beiträge1000 Beiträge
 
Benutzerbild von Vienna
 
Registriert seit: 12.07.2004
Ort: Wien
Beiträge: 1.917
Standard

Füge folgenden Code anstelle von _chute = "ParachuteWest" createVehicle getMarkerPos "jumppoint"; ein.

Code:
_chute = format ["%1",side _caller];
_chute = switch (_chute) do
 {
  case "WEST": {"ParachuteWest"};
  case "EAST": {"ParachuteEast"};
  case "GUER": {"ParachuteG"};
  default      {"ParachuteC"}
 };
_chute = _chute createVehicle getMarkerPos "jumppoint";
Die Seite des Callers wird auf Text umgewandelt, weil case GUER nicht erkennt.

Edit:

Lösche auch die folgenden Zeilen am Ende des Skripts. Das Löschen sollte automatisch erfolgen.
while {(getPos _caller select 2) > 2 } do {sleep 1};
sleep 10;
deleteVehicle _chute;

Es gibt auch noch eine Seite "ENEMY". z.B. nach Teamkills. Keine Ahnung wie darauf das Skript reagiert.

Geändert von Vienna (18.02.2013 um 22:55 Uhr).
Vienna ist offline   Mit Zitat antworten
Alt 19.02.2013, 14:46   #5 (permalink)
Newbie
 
Benutzerbild von TheRhisd
 
Registriert seit: 12.09.2012
Beiträge: 33
Standard

Vielen Dank Vienna, du hast mal wieder meine Mission geretten
Der von dir beschriebene Weg klappt wunderbar
Warum auch immer man für jede Seite einen eigenen Fallschirm braucht versteh ich zwar nicht aber ist eigentlich ja auch egal o.O

Danke
TheRhisd ist offline   Mit Zitat antworten
Alt 19.02.2013, 15:35   #6 (permalink)
5000 Beiträge
 
Benutzerbild von Xeno
 
Registriert seit: 03.01.2008
Alter: 77
Beiträge: 6.547
Standard

*deleted*

Xeno

Geändert von Xeno (08.12.2013 um 17:19 Uhr).
Xeno ist offline   Mit Zitat antworten
Alt 19.02.2013, 17:02   #7 (permalink)
SQF Zauberer 10 Jahre hx3
500 Beiträge1000 Beiträge
 
Benutzerbild von Vienna
 
Registriert seit: 12.07.2004
Ort: Wien
Beiträge: 1.917
Standard

Schon erstaunlich, dass es diese alten "Verwirrungen" noch immer gibt. Bei Zivilisten ist es genauso.

Code:
Laut Wiki
Syntax      : Side = side unitName
Parameters  : unitName: Object or Group
Return Value: Side

side Unit bei West       Return: WEST | Intern: WEST
side Unit bei Ost        Return: EAST | Intern: EAST
side Unit bei Widerstand Return: GUER | Intern: RESISTANCE
side Unit bei Zivilist   Return: CIV  | Intern: CIVILIAN
Vienna ist offline   Mit Zitat antworten
Alt 20.02.2013, 14:15   #8 (permalink)
SQF Zauberer 10 Jahre hx3
500 Beiträge1000 Beiträge
 
Benutzerbild von Vienna
 
Registriert seit: 12.07.2004
Ort: Wien
Beiträge: 1.917
Standard

Ein Absprung-Skript unter Berücksichtigung von Xenos Hinweisen. Es kommt jetzt zu keinen Problemen mehr wenn der Spieler auf "Feind" oder "Gefangen" gestellt ist.

Skript FallschirmAbsprung.sqf
Code:
//Fallschirmabsprung des Spielers über Kartenklick
// Parameter: Absprunghöhe in Meter 
//Aufruf z.B. über Auslöser: temp = 100 execVM "FallschirmAbsprung.sqf";

AbsprungHoehe = _this;

//"Kartenklick" für den Fallschirmabsprung erstellen
onMapSingleClick
  " 
    player moveInDriver
      ( 
        (
          ['ParachuteWest','ParachuteEast','ParachuteG','ParachuteC'] 
          select ([west,east,resistance,civilian] find (side group player))
        )
        createVehicle [0,0]
      );
    vehicle player setPos [_pos select 0, _pos select 1, AbsprungHoehe];
    openMap [false, false]
  ";

TitleText ["\nMit Klick auf die Karte Absprungstelle festlegen.\n Abbrechen [M] oder [ESC]","plain down",6];
openMap   [true, false]; //Karte anzeigen
waitUntil {!visibleMap}; //warten bis Karte geschlossen
TitleText ["","plain"];  //Titel-Text löschen
onMapSingleClick "";     //"Kartenklick" entfernen
Vienna ist offline   Mit Zitat antworten
Antwort


Aktive Benutzer in diesem Thema: 1 (Registrierte Benutzer: 0, Gäste: 1)
 
Themen-Optionen
Ansicht

Forumregeln
Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Ähnliche Themen
Thema Autor Forum Antworten Letzter Beitrag
Eigene Seite erschießt mich kurz vor Missionsende Cyclone83 Editing & Scripting 7 07.05.2012 12:14
Harddisk wird nicht mehr erkannt HenkerundKoch36 Software & Hardware 13 10.02.2011 20:38
Speicher wird nicht erkannt MarcusErgalla Software & Hardware 10 08.12.2010 22:28
Ofpnam Seite stiefel1976 Hilfe 5 24.09.2010 16:03


Kontakt - HX3.de - Archiv - Nach oben

Angetrieben durch vBulletin, Entwicklung von Philipp Dörner & Tobias



SEO by vBSEO 3.2.0 ©2008, Crawlability, Inc.

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116