Armed-Assault.de Twitter
 
 
Themen-Optionen Ansicht
Alt 29.12.2009, 16:16   #1 (permalink)
50 Beiträge
 
Benutzerbild von comrade91
 
Registriert seit: 23.12.2009
Beiträge: 60
comrade91 eine Nachricht über ICQ schicken
Standard Schnee

Hi

kennt vielleicht jemand von euch einen Schneescript^^? Etwas Winter fehlt bei ArmA^^

Mfg.
comrade91 ist offline  
Alt 29.12.2009, 16:22   #2 (permalink)
50 Beiträge100 Beiträge
 
Registriert seit: 08.06.2009
Ort: Düsseldorf
Beiträge: 159
Standard

Wenn du eine Schneebedeckte Insel willst, musst du dir eine downloaden!
__________________
Im Ingenieur steckt Genie, vergiss das nicht.
Skywalker077 ist offline  
Alt 29.12.2009, 16:29   #3 (permalink)
50 Beiträge
 
Benutzerbild von comrade91
 
Registriert seit: 23.12.2009
Beiträge: 60
comrade91 eine Nachricht über ICQ schicken
Standard

Nene ich möchte, dass der Schnee vom Himmel fällt^^ Und ja noch eine passende Insel dazu und es kann abgehen

Mfg
comrade91 ist offline  
Alt 30.12.2009, 08:07   #4 (permalink)
10 Jahre hx3
5000 Beiträge10.000 Beiträge15.000 Beiträge
 
Benutzerbild von burns
 
Registriert seit: 13.04.2003
Ort: Monerica
Alter: 41
Beiträge: 32.968
Standard

Vorgestern in einer CTF Mission gesehen, ist allerdings noch .sqs
Code:
; Snowing script v1.0 by Kegetys <Kegetys@raketti.net>
; http://www.ofp.kege.cjb.net
;
; For Winter Nogojev
;
;he snow script was written by Kegetys, and produces a snow effect.  Usage:
;[density] exec "snow.sqs"
;...where density is the density of snow you want (I use 25 for light snow).
;
;
; where density is the density of the snowing. If density is not specified a default of 5 is used.
; Note that the maximum working density is relative to the FPS.
;

_velocity = [0,0,-0.61]

_density = 5

? count _this > 0 : _density = _this select 0

keepsnowing = true

#Begin

~0.001
_spawnDist = 35
_spawnHeight = 15



_foo = 0

#luup
_posDrop = [(getpos player select 0)-_spawnDist+(random (_spawnDist*2)), (getpos player select 1)-_spawnDist+(random (_spawnDist*2)),  (getpos player select 2)+_spawnHeight]
_posDrop = [(_posDrop select 0)+((velocity vehicle player select 0)*5),(_posDrop select 1)+((velocity vehicle player select 1)*5),_posDrop select 2]
drop ["\ca\data\cl_water", "",            "Billboard", 1,           7,       _posDrop, _velocity,     1,                0.000001,  0.000, 1.4,     [0.06,0.06], [[1,1,1,0], [1,1,1,1], [1,1,1,1], [1,1,1,1]], [0,1,0,1,0,1],  0.2,                   1.2,                      "",      "",            ""]
_foo = _foo + 1
? _foo < _density : goto "luup"

? keepsnowing: goto "Begin"
__________________

burns ist offline  
Alt 30.12.2009, 08:29   #5 (permalink)
10 Jahre hx3
5000 Beiträge10.000 Beiträge15.000 Beiträge
 
Registriert seit: 01.12.2004
Beiträge: 17.666
Standard

Oh mein Gott, .sqs, das gibts noch?
Und das Skript ist noch für Nogojev für OFP, nur eben angepasst... oh meint Gott...
__________________
...
MarcusErgalla ist offline  
Alt 30.12.2009, 10:36   #6 (permalink)
10 Jahre hx3
50 Beiträge100 Beiträge250 Beiträge
 
Benutzerbild von Saint
 
Registriert seit: 04.01.2008
Alter: 50
Beiträge: 314
Standard

vielleicht ein feature von GL4 ?
__________________
"Um nirgends eine gähnende Leere zu lassen, wollen wir uns vorstellen, daß aller Orten und zu jeder Zeit etwas Wahrnehmbares vorhanden ist. Um nicht Materie oder Elektrizität zu sagen, will ich für dieses Etwas das Wort Substanz brauchen."

Hermann Minkowski
Saint ist offline  
Alt 30.12.2009, 15:15   #7 (permalink)
50 Beiträge100 Beiträge250 Beiträge
 
Registriert seit: 14.06.2009
Beiträge: 456
Standard

Ich hatte mal irgendeine Dynamic Weather Mod (oder so ähnlich) auf Armaholic heruntergeladen, war ein Modul was man nur platzieren muss, und es gab Dinge wie Fog, Regen, Sturm, Schnee und so weiter. Echt genial!

Guck dir das mal an

Edit: Hier: http://www.armaholic.com/page.php?id=7659
__________________
sommergemuese ist offline  
Alt 30.12.2009, 17:27   #8 (permalink)
50 Beiträge
 
Benutzerbild von comrade91
 
Registriert seit: 23.12.2009
Beiträge: 60
comrade91 eine Nachricht über ICQ schicken
Standard

o danke das sieht ja mal geil aus

Mfg.
comrade91 ist offline  
Alt 31.01.2010, 22:42   #9 (permalink)
Newbie
 
Registriert seit: 21.12.2009
Beiträge: 9
Standard

Zitat von comrade91 Beitrag anzeigen

Hi

kennt vielleicht jemand von euch einen Schneescript^^? Etwas Winter fehlt bei ArmA^^

Mfg.


du meinst doch sicher ARMA 2

dieses arma 2 tz tz tz

suche auch eines nur nicht für den 2ten teil...
med1c+ ist offline  
Alt 01.02.2010, 14:07   #10 (permalink)
500 Beiträge
 
Benutzerbild von DirtyHarryTPC
 
Registriert seit: 18.07.2008
Alter: 44
Beiträge: 560
DirtyHarryTPC eine Nachricht über ICQ schicken
Standard

Zitat von med1c+ Beitrag anzeigen

du meinst doch sicher ARMA 2

dieses arma 2 tz tz tz

suche auch eines nur nicht für den 2ten teil...


sollte auch im ersten gehen.
DirtyHarryTPC ist offline  
Alt 19.02.2010, 15:18   #11 (permalink)
500 Beiträge1000 Beiträge2.500 Beiträge
 
Benutzerbild von Cyborg11
 
Registriert seit: 26.03.2008
Beiträge: 2.822
Standard

Hier noch ein Skript im .sqf Format
Code:
/*
  Author:
   rübe (inspired by I3_DelayingTheBear.Chernarus)
  
  Description:
   weather script: winter
   color filter, light snow particles and ground fog around the player (or given obj)
   
  Parameters:
   _this select 0: particle source center (object; optional, default = player)
   
*/
private ["_obj", "_pos", "_snow", "_fog"];

"colorCorrections" ppEffectAdjust [1, 1, 0, [0.01, 0.02, 0.04, 0.01], [0.87, 1.08, 1.196, 0.3], [0.399, 0.287, 0.014, 0.0]]; 
"colorCorrections" ppEffectCommit 0; 
"colorCorrections" ppEffectEnable TRUE;

setWind [2.342, 3.108, true];

_obj = player;
if ((count _this) > 0) then
{
   _obj = _this select 0;
};
_pos = position (vehicle _obj);

// snow
_snow = "#particlesource" createVehicleLocal _pos; 
_snow setParticleParams [
                                          // GLOBAL PARAMETERS 
   ["\Ca\Data\cl_water.p3d",              // ShapeName
    1,                                    // - Anim Divisor (1 for a 1x1, 8 for a 8x8, etc) 
    1,                                    // - Anim Starting Row
    1],                                   // - Number of Frames to Play (speed controlled by animation phase below)
   "",                                    // AnimationName (obsolete)
   "Billboard",                           // Type ("Billboard" or "SpaceObject")
   1,                                     // TimerPeriod: The period of calling the "OnTimer" event (in sec).
   7,                                     // LifeTime: Life time of the particle (in sec).
   
                                          // PHYSICAL PARAMETERS
   [0, 0, 20.0],                          // Position: Either 3D coordinate (x, y, z) or name of the selection (Object property!)
   [0, 0, -0.35],                         // MoveVelocity: 3D vector (x, y, z) which describes the velocity vector of the particle direction and speed in m/s.
   1.0,                                  // RotationVelocity: Float number which determines number of rotations in one second.
   0.000001,                                  // Weight: Weight of the particle (kg).
   0.0,                                  // Volume: Volume of the particle (m^3).
   0.4,                                  // Rubbing: Float number without dimension which determines the impact of the density of the environment on this particle. 0 - no impact (vacuum). --> wind/air fraction!
   
                                          // RENDER PARAMETERS (array -> development in time) 
   [0.17,0.05],                           // Size: Size of the particle in time to render (m).
   [[1.0,1.0,1.0,1.0],                    // Colour of the particle in time to render (RGBA).
    [0.94,0.94,0.96,1.0], 
    [1.0,1.0,1.0,1.0]], 
   [0, 1],                                // AnimationPhase: Phase of the animation in time. (play speed of the selected frames for the Number of Frames to Play; higher == faster)
   0,                                     // RandomDirectionPeriod: Period of change of the velocity vector (s).
   0.01,                                  // RandomdirectionIntensity: Each MoveVelocity component will be changed with random value from interval <0, RandomDirectionIntensity>.
   "",                                    // OnTimer: Name of the script to run every period determined by TimerPeriod property. (this == position)
   "",                                    // BeforeDestroy: Name of the script to run right before destroying the particle. (this == position)
   _obj                                   // object: Object to bind this particle to.
];
_snow setParticleRandom [
   2,                                     // lifeTime      
   [35, 35, 10],                          // position
   [0.0, 0.0, -0.1],                    // moveVelocity
   0.001,                                  // rotationVelocity
   0.05,                                  // size
   [0.01, 0.01, 0.01, 0.02],              // color
   0.002,                                  // randomDirectionPeriod
   360                                    // angle
];
_snow setParticleCircle [
   0,                                     // radius 
   [0.0, 0.0, -0.1]                     // velocity
];
_snow setDropInterval 0.01;


// ground fog
_fog = "#particlesource" createVehicleLocal _pos; 
_fog setParticleParams [
   ["\Ca\Data\ParticleEffects\Universal\universal.p3d" , 16, 12, 13, 0], "", "Billboard", 1, 10, 
   [0, 0, -6], [0, 0, 0], 1, 1.275, 1, 0, 
   [7,6], [[1, 1, 1, 0], [1, 1, 1, 0.04], [1, 1, 1, 0]], [1000], 1, 0, "", "", _obj
];
_fog setParticleRandom [3, [55, 55, 0.2], [0, 0, -0.1], 2, 0.45, [0, 0, 0, 0.1], 0, 0];
_fog setParticleCircle [0.1, [0, 0, -0.12]];
_fog setDropInterval 0.01;


while {true} do 
{
   _pos = position (vehicle _obj);
   _snow setpos _pos;
   _fog setpos _pos;
   sleep 1;
};
Bohemia Interactive Forums - View Single Post - Snow?
Cyborg11 ist offline  
Alt 22.02.2010, 10:02   #12 (permalink)
Newbie
 
Registriert seit: 18.01.2010
Ort: Köln (NRW)
Beiträge: 4
Standard

Hallo zusammen!

Kann mir eventuell jemand sagen welchen Parameter man in diesem Snowscript ändern muss um ein bischen dichteren Schneefall zu bekommen?
Ich hab schon ein wenig damit rumgespielt aber noch kein zufriedenstellendes Ergebnis bekommen.

schönen Gruß

Hawk

http://www.germany-fun.net
Hawk ist offline  
Alt 22.02.2010, 14:43   #13 (permalink)
500 Beiträge1000 Beiträge2.500 Beiträge
 
Benutzerbild von Cyborg11
 
Registriert seit: 26.03.2008
Beiträge: 2.822
Standard

Meinst du das Schnee Skript, das ich gepostet habe?

Versuche mal in folgender Zeile die Zeit zu verändern:
Code:
_snow setDropInterval 0.01;
Cyborg11 ist offline  
Alt 22.02.2010, 16:50   #14 (permalink)
Newbie
 
Registriert seit: 18.01.2010
Ort: Köln (NRW)
Beiträge: 4
Standard

Vielen Dank,

genau das wars!

Mit
Code:
_snow setDropInterval 0.001;
sieht es schon fast nach Schneesturm aus.


schönen Gruß
Hawk
Hawk ist offline  
Alt 24.07.2010, 01:39   #15 (permalink)
Newbie
 
Benutzerbild von SniperWolf
 
Registriert seit: 07.07.2010
Ort: Deutschland
Beiträge: 37
Standard

gibt es auch eine Möglichkeit das Schnee-Script im Multiplayer zu benutzen, so dass es jeder Spieler sieht? Im Editor geht es, im Multiplayer schneit es aber leider nicht :-(
SniperWolf ist offline  
Alt 24.07.2010, 02:28   #16 (permalink)
500 Beiträge1000 Beiträge2.500 Beiträge
 
Benutzerbild von Cyborg11
 
Registriert seit: 26.03.2008
Beiträge: 2.822
Standard

Wenn du OA hast, brauchst du es sowieso nicht.
Platzier einfach das Umgebung - Effekte Modul und es schneit, wenn du die Wintermonate eingestellt hast.
=> Environment - Effects - Bohemia Interactive Community
Cyborg11 ist offline  
Alt 24.07.2010, 11:10   #17 (permalink)
50 Beiträge100 Beiträge
 
Benutzerbild von Doorgunner
 
Registriert seit: 15.02.2010
Ort: Niedersachsen/Kreis NI
Alter: 45
Beiträge: 209
Standard

Zitat von Cyborg11 Beitrag anzeigen

Wenn du OA hast, brauchst du es sowieso nicht.
Platzier einfach das Umgebung - Effekte Modul und es schneit, wenn du die Wintermonate eingestellt hast.
=> Environment - Effects - Bohemia Interactive Community

Nö, schneit aber nicht! Eigentlich passiert überhaupt nix, egal welchen Monat ich eingestellt hab.
Doorgunner ist offline  
Alt 24.07.2010, 11:19   #18 (permalink)
500 Beiträge1000 Beiträge
 
Benutzerbild von Pfandgiraffe
 
Registriert seit: 16.09.2008
Ort: Berlin
Alter: 38
Beiträge: 1.737
Pfandgiraffe eine Nachricht über ICQ schicken Pfandgiraffe eine Nachricht über Skype™ schicken
Standard

damit das schnee für jeden spieler im mp sichtbar wird muss es auch jeder client ausführen. in deinem fall wird es wohl nur der server ausführen.
__________________
Niemand hat die Absicht eine Tüte zu bauen!
​​​​​​​
___<<<A3 Wounding System>>>___
Pfandgiraffe ist offline  
Alt 24.07.2010, 13:40   #19 (permalink)
Newbie
 
Benutzerbild von SniperWolf
 
Registriert seit: 07.07.2010
Ort: Deutschland
Beiträge: 37
Standard

Zitat:

Nö, schneit aber nicht! Eigentlich passiert überhaupt nix, egal welchen Monat ich eingestellt hab.

Funktioniert sehr wohl... Einfach das Modul platzieren, Dezember einstellen und dann noch den Spieler mit dem Modul synchronisieren. Das hab ich jedenfalls gemacht. Es schneit tatsächlich...

Aber ich muss sagen das mir das Script besser gefällt, da es zusätzlich noch einen Farbfilter aktiviert und noch Nebel auf dem Boden erzeuugt. In Verbindung mit einem schönen Umgebungsschneesturm und dunklen Winterhimmel erlebt man Arma 2 in einer ganz neuen Atmosphäre.

Hab es jetzt auch zum laufen bekommen im Multiplayer. Muss nur noch schauen ob das von der Performance her hin haut, denn es wird ja bei jedem Spieler ausgeführt und dann sehen alle anderen das bei jedem Spieler ja auch und man hat einen wirklichen Schneesturm im Spiel. Hat noch jemand eine Idee wie man es auf jedem einzelnen Client ausführen kann, ohne das es die anderen Spieler sehen?

Im Moment steht bei jedem Spieler in der Initzeile "nul = [] execVM "schnee.sqf";". Gibt es auch einen anderen Weg?
SniperWolf ist offline  
Alt 24.07.2010, 14:10   #20 (permalink)
500 Beiträge1000 Beiträge2.500 Beiträge
 
Benutzerbild von Cyborg11
 
Registriert seit: 26.03.2008
Beiträge: 2.822
Standard

Schreib es nicht in die Initzeile, sondern schreib den Aufruf in die init.sqf.

Wenn du noch den Farbfilter haben möchtest, dann platzier doch noch das Umgebung - Farbe Module. Oder wie es eben heißt
Es schneit übrigens erst, wenn es bewölkt (> 0.35) ist Steht aber auch so im Wiki.
Cyborg11 ist offline  
 


Aktive Benutzer in diesem Thema: 1 (Registrierte Benutzer: 0, Gäste: 1)
 
Themen-Optionen
Ansicht

Forumregeln
Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Ähnliche Themen
Thema Autor Forum Antworten Letzter Beitrag
Schnee Skript 1337Jin Editing 8 12.09.2004 15:32


Kontakt - HX3.de - Archiv - Nach oben

Angetrieben durch vBulletin, Entwicklung von Philipp Dörner & Tobias



SEO by vBSEO 3.2.0 ©2008, Crawlability, Inc.

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119