Armed-Assault.de Twitter
 
 
Themen-Optionen Ansicht
Alt 19.02.2011, 11:53   #1 (permalink)
50 Beiträge100 Beiträge
 
Benutzerbild von Tomahawk
 
Registriert seit: 05.10.2008
Beiträge: 128
Standard Aufklärungsflugzeug

Hi all,
Meine erste Frage zu Thema Aufklärungsflugzeug.
Ist das möglich, das durch irgendeine Flugzeug alle feindliche einheiten in einem radius von 300 km sichtbar werden?
Der Flieger fliegt ganz hoch also unsichtbar für feind, dafür soll er die Feindliche Einheiten auf Karte stetig sichtbar machen.
Also keine UAV.

2. Mit welche code kann man KI befehligen, das er z.B in eine der seine Wegpunkte ca. 5 min stehen bleibt, dann kann er weiter laufen.

Danke im vorraus
Tomahawk ist offline  
Alt 19.02.2011, 12:13   #2 (permalink)
500 Beiträge1000 Beiträge
 
Registriert seit: 05.01.2008
Alter: 32
Beiträge: 1.703
Standard

Die KI Frage ist einfach. Du gibts kannst bei dem Wegpunkt einen Countdown/Zeitüberschreitung von 300 Sekunden angeben. (Über dem Feld von Aktivierung glaub ich)
JoeJoe87577 ist offline  
Alt 19.02.2011, 12:19   #3 (permalink)
50 Beiträge100 Beiträge
 
Benutzerbild von Tomahawk
 
Registriert seit: 05.10.2008
Beiträge: 128
Standard

oh Danke.
Die Frage 2 ist beantwortet.

Nun Die erste Frage ?!
Tomahawk ist offline  
Alt 19.02.2011, 12:27   #4 (permalink)
500 Beiträge
 
Benutzerbild von Anemia
 
Registriert seit: 20.05.2009
Beiträge: 605
Standard

schonmal probiert ein Flugzeug einfach auf die höhe zu schicken und geschaut was dann passiert ?!
Anemia ist offline  
Alt 19.02.2011, 12:42   #5 (permalink)
50 Beiträge100 Beiträge
 
Benutzerbild von Tomahawk
 
Registriert seit: 05.10.2008
Beiträge: 128
Standard

Ja das habe ich schon probiert, das geht aber leider nicht.
Tomahawk ist offline  
Alt 19.02.2011, 16:34   #6 (permalink)
SQF Zauberer 10 Jahre hx3
500 Beiträge1000 Beiträge
 
Benutzerbild von Vienna
 
Registriert seit: 12.07.2004
Ort: Wien
Beiträge: 1.917
Standard

300km Reichweite halte ich für übertrieben!

Das Skript zeigt Luft-, Tank, Kfz.- und wahlweise auch Personen-Objekte auf der Karte an. Du kannst es in dein Aufklärungsflugzeug einbinden.

Ob Personen anzuzeigen sind, ist im letzten Parameter mit true/false einstellbar.

Im Anhang ist auch ein Beispiel.

RadarAll.sqf
Code:
// Lokales Radar zeigt Flugobjekte, Tanks, Fahrzeuge und wahlweise Personen   [Vienna, 19.02.2011]
// Der Radarbereich wird durch einen blinkenden Ring angezeigt.
//
// Unbekannte Objekte sind blau, freundliche grün, feindliche rot.
//   Bei Flugobjekten wird auch die Höhe angezeigt.
//
// Aufruf: [Radarobjekt, Radarradius, true/false Personen anzeigen] execVM "RadarAll.sqf"
// Beispiel für Auslöser: temp = [player,2000,true] execVM "RadarAll.sqf"

private ["_radar","_radius","_r","_b","_marker","_m","_c","_t","_k","_h","_s"];

_radar      = _this select 0;
_radius     = _this select 1;

_b = ["Air","Tank","Car"];
//Personen anzeigen?
if (_this select 2) then {_b = _b + ["Man"]};

while {alive _radar} do
  {
    //Map offen?
    if (visibleMap) then 
      {
        //Durchlauf aller Flugobjekte im Radarbereich 
        _marker = [];
        {
          if (alive _x) then
            {
              //Marker Erstellen
              _m = createMarkerLocal [str _x, position _x];
              _h = ""; //für Höhe von Flugobjekten.
              //Markertype und Größe festlegen
              _s = [0.9,0.9]; //Markergröße
              if (_x isKindOf "Air") then      //Flug-Objekt
                {
                  _k = "Air";
                  _h = " 0m hoch";
                  if(position _x select 2 > 1)then{_h=" "+str(floor(position _x select 2))+"m hoch"}
                }
              else
                {
                  if (_x isKindOf "Tank") then //Tank-Objekt 
                    {_k="Tank"}
                  else
                    {                          
                      if (_x isKindOf "Car") then //Car-Objekt
                        {_k="Car";_s = [0.8,0.5]}
                      else
                        {_k="Vehicle";_s = [2,2]} //Men-Objekt
                    }
                };
              //Markerfarbe für Type: blau=unbekannt, grün=freundlich, rot=feindlich
              if(player countUnknown[_x]==1)then{_t="?";_c="ColorBlue"}
              else{_t=typeOf _x;if(player countFriendly[_x]==1)then{_c="ColorGreen"}
                                else{_c="ColorRed"}};
              _m setMarkerTypeLocal  _k;
              _m setMarkerTextLocal  (if(_x isKindOf "Man")then{""}else{str _t + _h});
              _m setMarkerColorLocal _c;
              _m setMarkerSizeLocal  _s;
              _marker = _marker + [_m]
            }
        } forEach nearestObjects [_radar,_b,_radius];
        sleep 2.8;
        //Marker für Radarreichweite erstellen
        _r = createMarkerLocal ["FlugobjektRadar4711", position _radar];
        _r setMarkerShapeLocal "ELLIPSE";
        _r setMarkerBrushLocal "BORDER";
        _r setMarkerSizeLocal [_radius,_radius];
        _r setMarkerColorLocal "ColorOrange";
        sleep 0.3;
        //Reichweitenmarker löschen
        deleteMarkerLocal _r; 
        //alle Flugobjektmarker löschen
        {deleteMarkerLocal _x} foreach _marker 
      }
    else
      {
        sleep 2
      }
   }
Angehängte Dateien
Dateityp: zip RadarAllgemein-utes.zip (4,5 KB, 61x aufgerufen)
Vienna ist offline  
Alt 19.02.2011, 19:52   #7 (permalink)
50 Beiträge100 Beiträge
 
Benutzerbild von Tomahawk
 
Registriert seit: 05.10.2008
Beiträge: 128
Standard

Danke Vienna
Tomahawk ist offline  
 


Aktive Benutzer in diesem Thema: 1 (Registrierte Benutzer: 0, Gäste: 1)
 
Themen-Optionen
Ansicht

Forumregeln
Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus


Kontakt - HX3.de - Archiv - Nach oben

Angetrieben durch vBulletin, Entwicklung von Philipp Dörner & Tobias



SEO by vBSEO 3.2.0 ©2008, Crawlability, Inc.

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119