Armed-Assault.de Twitter
Antwort
 
Themen-Optionen Ansicht
Alt 01.07.2010, 21:50   #1 (permalink)
Newbie
 
Registriert seit: 21.04.2009
Beiträge: 24
Standard ARMA 2: OA - UAV & ULB mit Terminal Backpack nutzen

Hi.

Ich versuche gerade im Editor mittels eines UAV Terminal Backpacks die Drohne oder auch eine ULB zu steuern. Haut aber nicht hin.

Wenn ich einen leeren UAV Rucksack platziere, den das Modul und den Player damit sync klappt das nur, wenn ich mich direkt neben dem Rucksack befinde.

wenn ich den Rucksack aufsetze verschwindet im Actionmenü der Punkt UAV. Vermutlich weil dann die synchronization nicht mehr stimmt. Hat damit schon jemand experimentiert, der mir sagen könnte wie das funktioniert?

Wenn ich mir mit player addBackpack "US_UAV_Pack_EP1"; den Rucksack direkt aufsetze klappts auch nicht...
pestbeule ist offline   Mit Zitat antworten
Alt 01.07.2010, 22:57   #2 (permalink)
50 Beiträge100 Beiträge
 
Registriert seit: 12.08.2009
Ort: Schweiz
Beiträge: 191
Phoenixmaster13 eine Nachricht über Skype™ schicken
Standard

habe auch experimentiert damit. Ich glaube fast es ist nur möglich wenn du den Rucksack zu boden legst. Oder versuch doch mal den Rucksack einem deiner Kameraden zu geben und du dann hinter ihm stehst.
Phoenixmaster13 ist offline   Mit Zitat antworten
Alt 01.07.2010, 23:07   #3 (permalink)
500 Beiträge1000 Beiträge2.500 Beiträge
 
Benutzerbild von Cyborg11
 
Registriert seit: 26.03.2008
Beiträge: 2.822
Standard

Also für das ULB:
Platzier ganz normal das ULB Modul und einen AH6-X. Beides synchronisierst du.
Das Modul nennst du ULB_module_1.
Sooo ... jetzt kannst du den Rest auch über einen Trigger machen oder über ein Skript.

Machen wir mal die Triggervariante
Zitat:

Einstellungen: BLUFOR / Vorhanden / Mehrfach
Bedingung: (unitBackpack player) == "US_UAV_Pack_EP1"
Aktivierung: ULB_module_1 setVariable ["unitList", [player]]
Deaktivierung: ULB_module_1 setVariable ["unitList", []]

Die unitList müsstest du eventuell eben erweitern, wenn weitere Einheiten wie zum Beispiel ein AH64D auf das ULB Zugriff haben sollen.

Mehr zum ULB Modul => ULB - Bohemia Interactive Community


Das UAV Modul funktioniert im Prinzip genauso.
Platziere deine MQ9 Drohne und dein UAV Modul (Name: UAV_module_1) und synchronisiere diese.
Danach erstellst du wieder einen Trigger, der folgendermaßen aussieht.
Zitat:

Einstellungen: BLUFOR / Vorhanden / Mehrfach
Bedingung: (unitBackpack player) == "US_UAV_Pack_EP1"
Aktivierung: UAV_module_1 setVariable ["rules", [player]]
Deaktivierung: UAV_module_1 setVariable ["rules", []]

Mehr zum UAV Modul => UAV - Bohemia Interactive Community


Skriptvariante ist aber sowieso die schönste:
Dauert aber noch etwas! Ich poste das hier erstmal und werde dann das Skript in den nächsten paar Stunden hinzufügen

Aber weiß noch nicht wie es im MP ausschaut.
Cyborg11 ist offline   Mit Zitat antworten
Alt 02.07.2010, 10:55   #4 (permalink)
Newbie
 
Registriert seit: 21.04.2009
Beiträge: 24
Standard

Erst mal Danke euch beiden für die Hilfe.

Ich habe das gerade mal mit dem Auslöser probiert. Sieht gut aus. Funktioniert aber leider nicht. Bei der Bedingung gibt er mir eine Fehlermeldung aus. Liegt wohl an den Anführungszeichen um den Backpacknamen. Ich habe die mal weg gemacht und auch einfach auf this gemacht, dann müsste ja jeder darauf zugriff haben. Leider auch so kein Erfolg.
meinen Player habe ich auch noch mal mit dem Modul gesynct. Auch nix.
Kann das daran liegen, dass ich erst das Backpack entferne und dann das UAV Pack hinzufüge?

Ich habe das auch noch mal mit der UAV probiert. Geht leider auch nicht...

Ich habe auch schon probiert die Auslöserbefehle in die Init-Zeile des Boduls zu packen. Auch hier leider kein Erfolg.

Funktoniert das bei dir mit den Auslösern oder war das eine Art Trockenübung?

danke auf jeden Fall schon mal für die schnelle Hilfe.
pestbeule ist offline   Mit Zitat antworten
Alt 02.07.2010, 11:35   #5 (permalink)
500 Beiträge1000 Beiträge2.500 Beiträge
 
Benutzerbild von Cyborg11
 
Registriert seit: 26.03.2008
Beiträge: 2.822
Standard

Als ich die Lösung geschrieben habe, wusste ich noch nicht, dass man so den Backpack nicht überprüfen kann. Habe da aber ein andere Lösung

Mein Skript ist fertig. Nur funktioniert das mit dem UAV nicht, da man das UAV nur an einem Fahrzeug / leeren Objekt aktivieren kann. Ich schau einfach mal, ob ich es doch irgendwie hinbekomme. Wir werden sehen. Ich poste dann einfach das neue Skript, wenn ich Erfolg hatte

Aber hier die Skriptlösung für das ULB:
Code:
/*
===============================================================================================
TerminalBackpack - by Cyborg11
Version: 1.0
Date: 01.07.2010
Description:    A unit with a UAV Terminal Backpack has access to an ULB
                1. Synchronize the ULB to the ULB module
                2. Execute the script on the soldier that should have the action
                
Parameter: nul = [unit, ULB module] execVM "TerminalBackpack.sqf";
        _unit = object which should have access to UAV/ULB
        _ulbm = name of ULB module
        
Example:    nul = [this, ULBM1] execVM "TerminalBackpack.sqf";
===============================================================================================
*/

private ["_unit", "_ulbm", "_unitList", "_newUnitList"];

_unit = _this select 0;
_ulbm = _this select 1;
If (isNil "_ulbm") exitWith{
    hint "ERROR in script TerminalBackpack.sqf!!\n\nULB module is NIL, cancel script!!!!"; 
    diag_log text format ["**** ERROR in Script 'TerminalBackpack.sqf' in mission %1!!!", missionName];
    diag_log text format ["**** Module _ulbm is NIL!!!"];
};

// [98,97,99,107,112,97,99,107,95,117,115,95,97,117,118,46,112,51,100] - backpack_us_auv.p3d - Classname: US_UAV_Pack_EP1

While {alive _unit} do {
    _condition = toArray(str(unitBackpack _unit));
    
    If (117 IN _condition && 118 IN _condition && 46 IN _condition) then {
        If (!isNil "_ulbm") then {
            _unitList = _ulbm getVariable "unitList";
            _newUnitList = _unitList + [_unit];
            _ulbm setVariable ["unitList", _newUnitList, true];
        };
    } else {
        If (!isNil "_ulbm") then {
            _newUnitList = _newUnitList - [_unit];
            _ulbm setVariable ["unitList", _newUnitList, true];
        };
    };

    sleep 2;
};
Funktioniert. Hab ich gestern getestet
Cyborg11 ist offline   Mit Zitat antworten
Alt 02.07.2010, 11:53   #6 (permalink)
Newbie
 
Registriert seit: 21.04.2009
Beiträge: 24
Standard

Super. Danke dir für das Skript.

Bei mir klappt es leider nicht. Vielleicht mal wieder nen Denkaussetzer meinerseits

Bei meinem Player in der Init-Zeile:
removeBackpack player; player addBackpack "US_UAV_Pack_EP1"; nul = [this, ULBM1] execVM "TerminalBackpack.sqf";

Skript liegt im Missionsordner und wird auch aufgerufen, das ULB Modul heißt ULBM1 und der/die ULB ist mit dem Modul gesynct und hat den Namen ULB. Mit dem Player ist nichts gesynct. Das sollte doch alles sein. Fügt der automatisch die die Funktion ins Acrionmenü ein? Vielleicht ist es das ja....
pestbeule ist offline   Mit Zitat antworten
Alt 02.07.2010, 12:30   #7 (permalink)
500 Beiträge1000 Beiträge2.500 Beiträge
 
Benutzerbild von Cyborg11
 
Registriert seit: 26.03.2008
Beiträge: 2.822
Standard

Wenn du den AH6-X mit dem ULB Modul synchronisiert hast und das ULB Modul wirklich ULBM1 genannt und auch mit dem richtigen Namen aufgerufen hast, dann sollte es funktionieren.

Kann natürlich sein, dass ich gerade das Skript iwie zerschossen habe, da ich nämlich den UAV Teil aus dem Skript entfernt hatte und vllt. hab ich da noch ein paar ULB Zeilen erwischt.
Kannst du mal bitte in die arma2OA.rpt schauen, ob da irgendwas wegen meinem Skript steht?

Eigentlich solltest du eine Action bekommen mit ULB und dann Zugriff auf das ULB haben.


------------------------------------------------------------------


Hm ... hab das Skript gerade nochmal bei mir getestet.
Initzeile meines Spielers:
Code:
player addBackpack "US_UAV_Pack_EP1"; nul = [this, ULBM1] execVM  "TerminalBackpack.sqf";
Funktioniert ohne Probleme o.O
Ich hab die Action ULB gleich von Beginn an und kann das ULB steuern. Wenn ich den Rucksack ablege, ist die Action auch wieder weg.
Cyborg11 ist offline   Mit Zitat antworten
Alt 02.07.2010, 13:10   #8 (permalink)
Newbie
 
Registriert seit: 21.04.2009
Beiträge: 24
Standard

Mhh.. Also die rpt Datei sagt dies:

B 1-1-C:3: Getting out while IsMoveOutInProgress
B 1-1-C:2: Getting out while IsMoveOutInProgress
ULBg: Getting out while IsMoveOutInProgress
ULBg: Getting out while IsMoveOutInProgress

Mein Fehler... Ich hatte am anderen Ende der Karte ein 2. ULB mit Apache plaziert. Jetzt klappt es auch.

Jetzt muss ich nur noch schaffen, dass ich als player eine Rakete von einem Apache abschießen kann... Vielleicht reichts ja den Apache mit dem ULB zu syncen. Auch nicht schlecht wäre, wenn man am Laserziel eine Bombe einfliegen lassen könnte...
pestbeule ist offline   Mit Zitat antworten
Alt 02.07.2010, 13:25   #9 (permalink)
500 Beiträge1000 Beiträge2.500 Beiträge
 
Benutzerbild von Cyborg11
 
Registriert seit: 26.03.2008
Beiträge: 2.822
Standard

Als Spieler kannst du keine Rakete abfeuern. Da müsstest du mal versuchen dem Spieler die Hellfirewaffe + Hellfireraketen per addWeapon zu geben

Hier übrigens eine neue Version. Die funktioniert jetzt auf jeden Fall richtig und besser. UAV Code ist auch mit enthalten, ist aber nicht aktiviert. Muss da erst noch ein bisschen testen.
Dem Skript ist es jetzt auch egal, ob das ULB module schon Einheiten synchronisiert hat wie einen Apache oder keine Einheit.
Code:
/*
===============================================================================================
TerminalBackpack - by Cyborg11
Version: 1.1
Date: 01.07.2010
Description:    A unit with a UAV Terminal Backpack has access to an UAV and ULB
                1. Synchronize the ULB to the ULB module and the UAV to the UAV module
                2. Execute the script on the soldier that should have the action
                UAV does not work atm! It is nil by default.
                
Parameter: nul = [unit, ULB module, UAV module] execVM "TerminalBackpack.sqf";
        _unit = object which should have access to UAV/ULB
        _ulbm = name of ULB module - if you don't have a ULB module use nil
        _uavm = name of UAV module - if you don't have a UAV module use nil
        
Example:    nul = [this, ULBM1, nil] execVM "TerminalBackpack.sqf";
            nul = [this, nil, UAVM1] execVM "TerminalBackpack.sqf";
===============================================================================================
*/

private ["_unit", "_uavm", "_ulbm", "_terminal", "_terminalArray", "_unitList", "_newUnitList", "_rules", "_newRules"];

_unit = _this select 0;
_ulbm = _this select 1;
_uavm = nil;                // Funktioniert im Moment nicht
If (isNil "_ulbm" && isNil "_uavm") exitWith{
    hint "ERROR in script TerminalBackpack.sqf!!\n\nBoth modules are NIL, cancel script!!!!"; 
    diag_log text format ["**** ERROR in Script 'TerminalBackpack.sqf' in mission %1!!!", missionName];
    diag_log text format ["**** Both module values (_ulbm / _uavm) are NIL!!!"];
};

// [98,97,99,107,112,97,99,107,95,117,115,95,97,117,118,46,112,51,100] - backpack_us_auv.p3d - Classname: US_UAV_Pack_EP1

While {alive _unit} do {
    _condition = toArray(str(unitBackpack _unit));
    
    If (117 IN _condition && 118 IN _condition && 46 IN _condition) then {
        If (!isNil "_ulbm") then {
            _unitList = _ulbm getVariable "unitList";
            If (!(_unit IN _unitList)) then {
                _newUnitList = _unitList + [_unit];
                _ulbm setVariable ["unitList", _newUnitList, true];
            };
        };
        
        If (!isNil ("_uavm")) then {
            _rules = _uavm getVariable "rules";
            If (!(_unit IN _rules)) then {
                _newRules = _rules + [_unit];
                _uavm setVariable ["rules", _newRules, true];
            };
        };        
    } else {
        If (!isNil "_ulbm") then {
            _unitList = _ulbm getVariable "unitList";
            If (_unit IN _unitList) then {
                _newUnitList = _unitList - [_unit];
                _ulbm setVariable ["unitList", _newUnitList, true];
            };
        };
        
        If (!isNil ("_uavm")) then {
            _rules = _uavm getVariable "rules";
            If (_unit IN _rules) then {
                _newRules = _newRules - [_unit];
                _uavm setVariable ["rules", _newRules, true];
            };
        };
    };

    sleep 2;
};
Cyborg11 ist offline   Mit Zitat antworten
Alt 02.07.2010, 13:39   #10 (permalink)
Newbie
 
Registriert seit: 21.04.2009
Beiträge: 24
Standard

Perfekt.... Hehe. dem Spieler ne Hellfire zuordnen ;-)

Wenn man nen Apache hat und aus der ULB bei "Feuerbefehl" dem Apache per Skript sagt doFire und die Position des Laserstrahls ausliest könnte das funktionieren oder? Mit dem Laserstrahl lässt sich bestimmt aus der original sqf von BI nehmen.

Das wäre die perfekte Lösung sonst muss man ja immer zu nem Piloten wechseln, der dann in das ULB "springt". so Spielchen würd ich gerne bei meiner Mission vermeiden.

Dank deiner Hilfe kann ich das ULB schon mal als still stehenden Drohnenersatz nutzen, was ja auch schon einiges ist.
pestbeule ist offline   Mit Zitat antworten
Alt 02.07.2010, 13:58   #11 (permalink)
500 Beiträge1000 Beiträge2.500 Beiträge
 
Benutzerbild von Cyborg11
 
Registriert seit: 26.03.2008
Beiträge: 2.822
Standard

Zitat von pestbeule Beitrag anzeigen

Wenn man nen Apache hat und aus der ULB bei "Feuerbefehl" dem Apache per Skript sagt doFire und die Position des Laserstrahls ausliest könnte das funktionieren oder? Mit dem Laserstrahl lässt sich bestimmt aus der original sqf von BI nehmen.

Theoretisch ja. Das Abfeuern der Hellfire musst dann eben skripten, da es normalerweise so nicht vorgesehen ist.

Ach btw: ULB Modul funzt nicht im MP. Der 2. Spieler sitzt dann iwie im ULB drinnen, kann aber nichts machen außer die Kamera zu ändern. Kann auch nicht mehr aus dem ULB raus. Getestet auf nem gehosteten Server. Liegt aber am Modul, nicht an meinem Skript :o

Geändert von Cyborg11 (02.07.2010 um 14:00 Uhr).
Cyborg11 ist offline   Mit Zitat antworten
Alt 14.07.2010, 13:59   #12 (permalink)
500 Beiträge
 
Benutzerbild von Anemia
 
Registriert seit: 20.05.2009
Beiträge: 605
Standard

Hey Cyborg , habe dein Skript mal hier verbaut ....

Hoffe das ist ok so ?!

=NAG= - Thema anzeigen - [OA] Rucksäcke verwenden + UAV Backpack/Classnames
Anemia ist offline   Mit Zitat antworten
Alt 14.07.2010, 15:27   #13 (permalink)
500 Beiträge1000 Beiträge2.500 Beiträge
 
Benutzerbild von Cyborg11
 
Registriert seit: 26.03.2008
Beiträge: 2.822
Standard

Kein Problem

Übrigens: Modul ist schon MP fähig, aber es darf dann nur kein 2. Spieler benutzen.
Solange es nur ein Spieler nutzt und auch immer der gleiche, sollte es funzen.
Cyborg11 ist offline   Mit Zitat antworten
Alt 14.07.2010, 15:52   #14 (permalink)
500 Beiträge
 
Benutzerbild von Anemia
 
Registriert seit: 20.05.2009
Beiträge: 605
Standard

Zitat von Cyborg11 Beitrag anzeigen

Kein Problem

Übrigens: Modul ist schon MP fähig, aber es darf dann nur kein 2. Spieler benutzen.
Solange es nur ein Spieler nutzt und auch immer der gleiche, sollte es funzen.


Vielleicht sollte man das noch irgendwie festlegen im Script ?! oder halt in der erklärung.
Bzw. lässt sich den der Heli mit KI steuern ?!
Anemia ist offline   Mit Zitat antworten
Alt 14.07.2010, 16:24   #15 (permalink)
500 Beiträge1000 Beiträge2.500 Beiträge
 
Benutzerbild von Cyborg11
 
Registriert seit: 26.03.2008
Beiträge: 2.822
Standard

Der Heli lässt sich dann ganz normal steuern sowie auch im Tutorial gelernt.
Oder wie meinst das?
Einen KI Soldaten in den Heli setzen und ihn so steuern? Sollte natürlich auch funktionieren.
Cyborg11 ist offline   Mit Zitat antworten
Alt 15.07.2010, 16:24   #16 (permalink)
50 Beiträge100 Beiträge
 
Benutzerbild von todyoungblood
 
Registriert seit: 29.05.2009
Ort: Reutlingen
Alter: 43
Beiträge: 134
todyoungblood eine Nachricht über AIM schicken
Standard

Zitat:

Hier übrigens eine neue Version. Die funktioniert jetzt auf jeden Fall richtig und besser. UAV Code ist auch mit enthalten, ist aber nicht aktiviert. Muss da erst noch ein bisschen testen.

Hast Du schon ein Script mit dem auch UAV funktioniert?

Gruß Tod
__________________

Langsam ist präzise.....und präzise ist schnell....
http://www.astore.de
http://www.astore-shop.de
http://www.voodoo-puppe.net
todyoungblood ist offline   Mit Zitat antworten
Alt 15.07.2010, 16:36   #17 (permalink)
500 Beiträge1000 Beiträge2.500 Beiträge
 
Benutzerbild von Cyborg11
 
Registriert seit: 26.03.2008
Beiträge: 2.822
Standard

Zitat von todyoungblood Beitrag anzeigen

Hast Du schon ein Script mit dem auch UAV funktioniert?

Gruß Tod

Hab jetzt endlich rausgefunden, wie es funktioniert.

Anemia, bitte im Forum updaten!

Code:
/*
===============================================================================================
TerminalBackpack - by Cyborg11
Version: 1.2
Date: 15.07.2010
Description:    A unit with a UAV Terminal Backpack has access to an UAV and ULB
                1. Synchronize the ULB to the ULB module and the UAV to the UAV module
                2. Name the modules
                3. Execute the script on the soldier that should have the action
                
Parameter: nul = [unit, ULB module, UAV module] execVM "TerminalBackpack.sqf";
        _unit = object which should have access to UAV/ULB
        _ulbm = name of ULB module - if you don't have a ULB module use nil
        _uavm = name of UAV module - if you don't have a UAV module use nil
        
Example:    nul = [this, ULBM1, nil] execVM "TerminalBackpack.sqf";
            nul = [this, nil, UAVM1] execVM "TerminalBackpack.sqf";
            nul = [this, ULBM1, UAVM1] execVM "TerminalBackpack.sqf";
===============================================================================================
*/

private ["_unit", "_uavm", "_ulbm", "_terminal", "_terminalArray", "_unitList", "_newUnitList", "_rules", "_newRules"];

_unit = _this select 0;
_ulbm = _this select 1;
_uavm = _this select 2;
_oa = isClass (configFile >> "cfgPatches" >> "ca_E");
If (!_oa) exitWith{hint "OA is not installed on your system or is not running! Cancel Script!"};
If (isNil "_ulbm" && isNil "_uavm") exitWith{
    hint "ERROR in script TerminalBackpack.sqf!\n\nBoth modules are NIL, cancel script!"; 
    diag_log text format ["**** ERROR in Script 'TerminalBackpack.sqf' in mission '%1'!", missionName];
    diag_log text format ["**** Both module values (_ulbm / _uavm) are NIL!"];
};

// [98,97,99,107,112,97,99,107,95,117,115,95,97,117,118,46,112,51,100] - backpack_us_auv.p3d - Classname: US_UAV_Pack_EP1

While {alive _unit} do {
    _backpack = unitBackpack _unit;
    _condition = toArray(str(_backpack));

    If (115 IN _condition && 95 IN _condition && 97 IN _condition && 117 IN _condition && 118 IN _condition && 46 IN _condition    ) then {
        If (!isNil "_ulbm") then {
            _unitList = _ulbm getVariable "unitList";
            If (!(_unit IN _unitList)) then {
                _newUnitList = _unitList + [_unit];
                _ulbm setVariable ["unitList", _newUnitList, true];
            };
        };
        
        If (!isNil "_uavm") then {
            _rules = _uavm getVariable "rules";
            If (!(_unit IN _rules)) then {
                _newRules = _rules + [_unit];
                _uavm setVariable ["rules", _newRules, true];
                _uavm synchronizeObjectsAdd [_backpack, _unit];
            };
        };        
    } else {
        If (!isNil "_ulbm") then {
            _unitList = _ulbm getVariable "unitList";
            If (_unit IN _unitList) then {
                _newUnitList = _unitList - [_unit];
                _ulbm setVariable ["unitList", _newUnitList, true];
            };
        };
        
        If (!isNil "_uavm") then {
            _rules = _uavm getVariable "rules";
            If (_unit IN _rules) then {
                _newRules = _newRules - [_unit];
                _uavm setVariable ["rules", _newRules, true];
                _uavm synchronizeObjectsRemove [_backpack, _unit];
            };
        };
    };

    sleep 2;
};
Cyborg11 ist offline   Mit Zitat antworten
Alt 15.07.2010, 23:50   #18 (permalink)
50 Beiträge
 
Benutzerbild von miromanu
 
Registriert seit: 18.07.2009
Alter: 29
Beiträge: 90
Standard

irgendwie kriege ich das nicht gebacken. ich schreibe mal hier rein was ich mache und hoffe das ihr mir helfen könnt.
Also:
ich hab einen schützen mit dem uav backpack bestückt und in seine init zeile das reingeschrieben:
Code:
qwe addbackpack "US_UAV_Pack_EP1"; nul = [qwe, nil, UAVM1] execVM "TerminalBackpack.sqf";
(qwe ist sein name).

daraufhin habe ich ein UAV Manager modul auf die karte gesetzt und diesen UAVM1 benannt. dann eine fliegende MQ-9 und diese mit dem modul synchronisiert. jetzt habe ich den script von dieser seite kopiert und ihn als TerminalBackpack.sqf in den missions ordner gespeichert. bestimmt ist irgendwo ein fehler aber ich versuchs jetzt schon seit einer stunde und komme nicht drauf.
miromanu ist offline   Mit Zitat antworten
Alt 16.07.2010, 06:07   #19 (permalink)
500 Beiträge
 
Benutzerbild von Anemia
 
Registriert seit: 20.05.2009
Beiträge: 605
Standard

Zitat von Cyborg11 Beitrag anzeigen

Hab jetzt endlich rausgefunden, wie es funktioniert.

Anemia, bitte im Forum updaten!


Hab das skript im forum angepasst -> =NAG= - Thema anzeigen - [OA] Rucksäcke verwenden + UAV Backpack/Classnames


Aber was genau hast du geändert bzw. was funktioniert nun ?!

@miromanu

Versuch mal so

Code:
qwe addbackpack "US_UAV_Pack_EP1"; nul = [this, nil, UAVM1] execVM "TerminalBackpack.sqf";
Schonmal getestet ob den das ULB bei dir geht ?! bzw. ob das script aufegruffen wird. ?!

Geändert von Anemia (16.07.2010 um 06:13 Uhr).
Anemia ist offline   Mit Zitat antworten
Alt 16.07.2010, 08:36   #20 (permalink)
50 Beiträge
 
Benutzerbild von miromanu
 
Registriert seit: 18.07.2009
Alter: 29
Beiträge: 90
Standard

@Anemia funkrioniert leider auch so nicht. Wie kann ich denn testen ob das script aufgerufen wird?
miromanu ist offline   Mit Zitat antworten
Antwort


Aktive Benutzer in diesem Thema: 1 (Registrierte Benutzer: 0, Gäste: 1)
 
Themen-Optionen
Ansicht

Forumregeln
Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Ähnliche Themen
Thema Autor Forum Antworten Letzter Beitrag
ARMA 2 und ARMA 2.5 ( Opa ) 3 mal auf einem Computer installieren? det99 Technische Fragen & Probleme 5 29.06.2010 20:44
Deutsche Addons für ArmA II Marseille77 Mods & Addons 2 19.06.2010 08:00
Arma 1 Guide mit arma 2 kompatibel ? Bakker Editing & Scripting 5 18.06.2010 19:41
ofp, arma 1 oder doch arma 2? grievous Die Litfaßsäule 20 24.05.2010 09:16


Kontakt - HX3.de - Archiv - Nach oben

Angetrieben durch vBulletin, Entwicklung von Philipp Dörner & Tobias



SEO by vBSEO 3.2.0 ©2008, Crawlability, Inc.

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116