Armed-Assault.de Twitter
 
 
Themen-Optionen Ansicht
Alt 17.10.2010, 17:46   #1 (permalink)
Newbie
 
Registriert seit: 29.05.2009
Ort: Berlin
Beiträge: 12
Standard Anwesenheit (Bedingung)

Hi habe da mal eine frage will ne Mission basteln mit mehreren aufgaben und dazu will ich das feindliche einheiten spawnen wenn ein bestimmtes Ziel erfolgt ist um das erst mal zu testen habe ich 2 feindliche Einheiten auf die Karte gesetzt und die 1 test1 genannt und Einheit 2 soll erst sichtbar sein wenn einheit 1 tot ist dazu habe ich bei einheit 2 bei Anwesenheit (Bedingung) not alive test1 eingetragen hat aber leider nicht geklappt einheit 2 spawnt nicht obwohl einheit1 tot ist wo liegt der Fehler
BIB-ODIN ist offline  
Alt 17.10.2010, 18:10   #2 (permalink)
10 Jahre hx3
500 Beiträge1000 Beiträge
 
Benutzerbild von TeRp
 
Registriert seit: 02.04.2003
Ort: San Francisco
Beiträge: 1.919
Standard

Hab mir mal die Mühe gemacht und die fehlenden Satzzeichen in Reihenfolge aufgeschrieben:
, . . , . , . . ?

Ist zum Einsetzen an den richtigen Stellen, dann lässt sich der Text auch lesen und verstehen.
Ich hoffe, dass ich hab keins übersehen habe.
__________________

TeRp ist offline  
Alt 17.10.2010, 18:46   #3 (permalink)
50 Beiträge100 Beiträge250 Beiträge
 
Registriert seit: 24.12.2008
Beiträge: 424
Standard

Abgesehen von Satzzeichen sollte man auch mal die Suche bemühen.

In diesem Konkreten Fall hätte man einfach mal 10 Themen weiter unten nachsehen sollen.

Da findet man das hier "Anwesenheit (Bedingung):" im Fenster "Einheit bearbeiten"

In diesem Thema solltest du dem 3.Beitrag besondere Aufmerksamkeit schenken.
__________________
Frankyman ist offline  
Alt 17.10.2010, 19:11   #4 (permalink)
Newbie
 
Registriert seit: 29.05.2009
Ort: Berlin
Beiträge: 12
Standard

Zitat von Frankyman Beitrag anzeigen

Abgesehen von Satzzeichen sollte man auch mal die Suche bemühen.

In diesem Konkreten Fall hätte man einfach mal 10 Themen weiter unten nachsehen sollen.

Da findet man das hier "Anwesenheit (Bedingung):" im Fenster "Einheit bearbeiten"

In diesem Thema solltest du dem 3.Beitrag besondere Aufmerksamkeit schenken.

den 3. Beitrag habe ich besondere Aufmerksamkeit geschenkt aber es wurde auch in diesem Thema keine brauchsame Lösung gefunden es muß ja irgendwie funktionieren denn wenn man eine EVO oder Dom spielt kommen ja auch erst die Feinde wenn eine bestimmte City dran ist.
BIB-ODIN ist offline  
Alt 17.10.2010, 19:12   #5 (permalink)
SQF Zauberer 10 Jahre hx3
500 Beiträge1000 Beiträge
 
Benutzerbild von Vienna
 
Registriert seit: 12.07.2004
Ort: Wien
Beiträge: 1.917
Standard

Das musst du mit Wegpunkten verwirklichen! Einheiten müssen ja zum Einsatzort geführt werden. In den Wegpunkten ist es möglich, Einheiten nach bestimmten Ereignissen in Marsch zu setzen.

Der Transport bleibt dir überlassen. z.B. mit Hubschraubern und Absprung, oder mit Fahrzeugen. Geht natürlich auch zu Fuß, wenn die Einheiten nicht zu weit entfernt sind.

Es ist auch möglich Einheiten mit setPos zu "beamen", oder direkt über Skripte vor Ort zu erstellen.
Vienna ist offline  
Alt 17.10.2010, 19:30   #6 (permalink)
Newbie
 
Registriert seit: 29.05.2009
Ort: Berlin
Beiträge: 12
Standard

Erst mal danke das hier jemand mal antwortet und nicht Deutschlehrer spielt,aber wie meinst du das hier (Es ist auch möglich Einheiten mit setPos zu "beamen" wie muß dann sowas aussehen ? oder hat jemand vieleicht schon ein Skript geschrieben was man benutzen könnte?
BIB-ODIN ist offline  
Alt 17.10.2010, 19:44   #7 (permalink)
10 Jahre hx3
500 Beiträge1000 Beiträge
 
Benutzerbild von Buliwyf
 
Registriert seit: 11.03.2005
Ort: HH
Alter: 52
Beiträge: 1.930
Standard

Zitat von BIB-ODIN Beitrag anzeigen

Erst mal danke das hier jemand mal antwortet und nicht Deutschlehrer spielt

Solche Kunden wie Du sind mir hier am Liebsten! Zu faul oder nicht intelligent genug eine Suchfunktion zu nutzen und dann noch bei so einem lieblos hingeknallten Text, den man als Normalsterblicher schon zweimal lesen muss damit man überhaupt erahnen kann worum es geht, davon ausgehen, dass sich jemand findet, der einem schööööööön was vorkaut, was man brauchen kann....

Nee is klar...
__________________
Buliwyf ist offline  
Alt 17.10.2010, 20:44   #8 (permalink)
Newbie
 
Registriert seit: 29.05.2009
Ort: Berlin
Beiträge: 12
Standard

Zitat von Buliwyf Beitrag anzeigen

Solche Kunden wie Du sind mir hier am Liebsten! Zu faul oder nicht intelligent genug eine Suchfunktion zu nutzen und dann noch bei so einem lieblos hingeknallten Text, den man als Normalsterblicher schon zweimal lesen muss damit man überhaupt erahnen kann worum es geht, davon ausgehen, dass sich jemand findet, der einem schööööööön was vorkaut, was man brauchen kann....

Nee is klar...

Mein Gott bist du arrogant und wenn du richtig lesen könntest würdest du wissen das ich gesucht habe aber das halt auch dort keine Lösung gefunden wurde und meine Frage war halt ob nicht jemand schon ein Script geschrieben hat was man benutzen kann aber wenn du so schlau bist wie du tust kannst du mir sicher weiterhelfen.
BIB-ODIN ist offline  
Alt 17.10.2010, 20:48   #9 (permalink)
10 Jahre hx3
500 Beiträge1000 Beiträge
 
Benutzerbild von Buliwyf
 
Registriert seit: 11.03.2005
Ort: HH
Alter: 52
Beiträge: 1.930
Standard

*gähn*

createUnit

__________________
Buliwyf ist offline  
Alt 17.10.2010, 23:51   #10 (permalink)
SQF Zauberer 10 Jahre hx3
500 Beiträge1000 Beiträge
 
Benutzerbild von Vienna
 
Registriert seit: 12.07.2004
Ort: Wien
Beiträge: 1.917
Standard

Kopiere diese Zeile in die Initialisierungszeile des Anführers einer Gruppe:

Start1=false; TempNul = group this spawn {while{true} do {waitUntil{Start1}; {_x setPos position player} forEach units _this; Start1=false}}

Immer wenn du die Variable Start1=true setzt, werden alle Soldaten der Gruppe zum Spieler "gebeamt".

Im Anhang ein Beispiel, in dem mit Funk die Variable gesetzt wird.
Angehängte Dateien
Dateityp: zip Unterstuetzung_zum_Spieler-utes.zip (1,3 KB, 58x aufgerufen)
Vienna ist offline  
Alt 18.10.2010, 20:50   #11 (permalink)
500 Beiträge1000 Beiträge
 
Benutzerbild von Pfandgiraffe
 
Registriert seit: 16.09.2008
Ort: Berlin
Alter: 38
Beiträge: 1.737
Pfandgiraffe eine Nachricht über ICQ schicken Pfandgiraffe eine Nachricht über Skype™ schicken
Standard

hier dein script, vorbild a'la evo - das was du wolltest:


erst das hier:
Code:
// resupplys towns with reinforcments


//added with 1.09:
_private = ["_actualtown"];
_actualtown = 0;
_actualtown = BIS_EVO_MissionProgress;


for [{_loop=0}, {_loop<1}, {_loop=_loop}] do
{
_spawn = [0,0,0];
_spawns = [];
_radio = objNull;
_alist = objNull;
_tag = "";
_type = "";
_Allspawns = [["lopatinoref","lopatinorefa","lopatinorefb"],["staryref","staryrefa","staryrefb"],["zelenogorskref","zelenogorskrefa","zelenogorskrefb"],["chernogorskref","chernogorskrefa","chernogorskrefb"],["elektrozavodskref","elektrozavodskrefa","elektrozavodskrefb"],["mstaref","mstarefa","mstarefb"],["khelmref","khelmrefa","khelmrefb"],["krasnostavref","krasnostavrefa","krasnostavrefb"]];
_wtime = 30;

_newtown = BIS_EVO_MissionProgress;
if (_actualtown != _newtown) exitWith {};        //beendet reinforce wenn neue stadt gestartet


    _radio = BIS_EVO_radios select BIS_EVO_MissionProgress;
    _alist = BIS_EVO_DetectWest;
    _curtownInf = (BIS_EVO_Infantry select BIS_EVO_MissionProgress) select 0;
    _basetownInf = (BIS_EVO_Infantry select BIS_EVO_MissionProgress) select 1;
    _curtownMec = (BIS_EVO_Mechanized select BIS_EVO_MissionProgress) select 0;
    _basetownMec = (BIS_EVO_Mechanized select BIS_EVO_MissionProgress) select 1;

    //hintSilent format["CI:%1 BI:%2 CM:%3 BM:%4 ",_curtownInf,_basetownInf,_curtownMec,_basetownMec];  //debug, psycho
    
BIS_EVO_mKamazOpen =

{
        _guard = grpNull;
        _unit = objNull;
        _pos2 = objNull;
        _max = objnull;
        _allunits = ["TK_Commander_EP1","TK_Soldier_MG_EP1","TK_Soldier_EP1","TK_Soldier_GL_EP1","TK_Soldier_AT_EP1","TK_Soldier_Sniper_EP1"];
        _max = count _allunits;

        _guard = createGroup (east);

        _spawns = _Allspawns select BIS_EVO_MissionProgress;
        _pos2 = GetMarkerPos (_spawns select (round random 2));
        _ural = createVehicle ["V3S_TK_EP1", _pos2, _spawns, 0, "NONE"];[_ural] call EVO_Lock;_ural addEventHandler ["killed", {handle = [_this select 0] execVM "data\scripts\bury.sqf"}];
        Sleep 0.2;
        _unit = _guard createUnit [(_allunits select round random (_max - 1)), _pos2, [], 0, "NONE"];_unit setSkill 2+(random 3);[_unit] join _guard;_unit assignAsDriver _ural;_unit moveInDriver _ural;
        Sleep 0.2;
        _unit = _guard createUnit [(_allunits select round random (_max - 1)), _pos2, [], 0, "NONE"];_unit setSkill 2+(random 3);[_unit] join _guard;_unit assignAsCargo _ural;_unit moveInCargo _ural;
        Sleep 0.2;
        _unit = _guard createUnit [(_allunits select round random (_max - 1)), _pos2, [], 0, "NONE"];_unit setSkill 2+(random 3);[_unit] join _guard;_unit assignAsCargo _ural;_unit moveInCargo _ural;
        Sleep 0.2;
        _unit = _guard createUnit [(_allunits select round random (_max - 1)), _pos2, [], 0, "NONE"];_unit setSkill 2+(random 3);[_unit] join _guard;_unit assignAsCargo _ural;_unit moveInCargo _ural;
        Sleep 0.2;
        _unit = _guard createUnit [(_allunits select round random (_max - 1)), _pos2, [], 0, "NONE"];_unit setSkill 2+(random 3);[_unit] join _guard;_unit assignAsCargo _ural;_unit moveInCargo _ural;
        Sleep 0.2;
        _unit = _guard createUnit [(_allunits select round random (_max - 1)), _pos2, [], 0, "NONE"];_unit setSkill 2+(random 3);[_unit] join _guard;_unit assignAsCargo _ural;_unit moveInCargo _ural;
        Sleep 0.2;

        [position _alist,_guard,_radio,_alist] call BIS_EVO_Erefway;
        [_guard, 1] setWaypointType "GETOUT";
        {_x addEventHandler ["killed", {handle = [_this select 0,"INF"] execVM "data\scripts\mobjbury.sqf"}]} forEach (units _guard);    
        _recy = [objnull,_guard] execVM "data\scripts\grecycle.sqf";
        _guard setFormation "COLUMN";            
};

BIS_EVO_MI17support =

{
        _pos = objNull;
        _unit = objNull;
        _vec = objNull;
        _heli = objnull;
        _max = objnull;
        _allunits2 = ["TK_Soldier_SL_EP1","TK_Soldier_HAT_EP1","TK_Soldier_GL_EP1","TK_Soldier_AR_AP1","TK_Soldier_Spotter_EP1","TK_Soldier_SniperH_EP1"];
        _max = count _allunits2;

        _pos = position _radio;
        _posback = getmarkerpos "EnemyAir03";

        _pilot = createGroup (east);

        "TK_Soldier_Pilot_EP1" createUnit [getmarkerpos "centerp", _pilot];Sleep BIS_EVO_GlobalSleep;
        "TK_Soldier_Pilot_EP1" createUnit [getmarkerpos "centerp", _pilot];Sleep BIS_EVO_GlobalSleep;
        _pos1 = [(_pos select 0)-1000 -(random 2000),(_pos select 1)+2000 -(random 3000),(200 + random 100)];
        _pos2 = [(_pos select 0)+1000 +(random 2000),(_pos select 1)+2000 -(random 3000),(200 + random 100)];
        if(floor (random 2) == 1) then 
        {
            _heli = createVehicle ["Mi17_TK_EP1",_pos1, [], 500, "FLY"];Sleep BIS_EVO_GlobalSleep
        }else
        {
            _heli = createVehicle ["Mi17_TK_EP1",_pos2, [], 500, "FLY"];Sleep BIS_EVO_GlobalSleep
        };
        _heli setpos [getpos _heli select 0, getpos _heli select 1, 200];
        _heli setdir (random 359);
        _heli engineon true;
        (units _pilot select 0) assignAsDriver _heli;
        (units _pilot select 1) assignAsGunner _heli;
        (units _pilot select 0) moveInDriver _heli;
        (units _pilot select 1) moveInGunner _heli;
        _sumark = [_heli] execVM "data\scripts\sumarker.sqf";
        _wp = _pilot addWaypoint [_pos, 10];
        _wp2 = _pilot addWaypoint [_posback, 10];
        {_x setBehaviour "careless"} forEach (units _pilot);

        (driver _heli) commandMove _pos;
        (driver _heli) doMove _pos;
        _heli flyInHeight 150;

        waitUntil {(_heli distance _pos) < (random 200) or not (canmove _heli)};

        if (canmove _heli) then 
        {
            _para = createGroup (east);
            _count = 6;
            _i = 0;
            while {_i <= _count} do                //create falschirmspringer
            {
                _pos = position _heli;
                _unit = _para createUnit [_allunits2 select (round random (_max-1)), [0,0,0], [], 300, "NONE"];
                _unit setSkill 2+(random 3);
                _unit addEventHandler ["killed", {handle = [_this select 0,"INF"] execVM "data\scripts\mobjbury.sqf"}];
                [_unit] join _para;
                _vec = createVehicle ["ParachuteEast", _pos, [], 20, 'NONE'];
                _vec setpos [_pos select 0,_pos select 1,(_pos select 2)- 12];
                _unit MoveInDriver _vec;
                sleep 0.7;
                _i = _i + 1;
            };

            {_x setBehaviour "combat"} forEach (units _para);
            [position _alist,_para,_radio,_alist] call BIS_EVO_Erefway;

            sleep 90;
            {deleteVehicle _x} forEach ([_heli] + crew _heli);
            if (!isNull _unit) then {deleteVehicle _unit};
            deleteGroup _pilot;
        }
        else        //edit psycho   --  curtowninf löschen die nie kreiert wurde
        {
        (BIS_EVO_Infantry select BIS_EVO_MissionProgress) set [0, _curtownInf-6];
        };
};



    if(_curtownMec <= (_basetownMec) and alive _radio) then
    {
        _unit = objNull;
        _guard = grpNull;
        _pos = objNull;
        _vec = objNull;
        _maxo = 0;
        _spawns = _Allspawns select BIS_EVO_MissionProgress;
        _pos = GetMarkerPos (_spawns select (round random 2));
        _tag = "MEC";
        _allvec = ["BMP2_TK_EP1","M113_TK_EP1","BTR60_TK_EP1","BRDM2_TK_EP1","BRDM2_ATGM_TK_EP1","T72_TK_EP1","T55_TK_GUE_EP1","BTR40_MG_TK_GUE_EP1","LandRover_MG_TK_EP1","UAZ_AGS30_TK_EP1"];
        _maxo = (count _allvec)-1;    
        _rds = [];
        _rds = (_pos nearRoads 10);
        waitUntil{count _rds > 0};
        _cardir = (getdir (_rds select 0));
        _degrees = [_pos,position _alist] call BIS_EVO_GetRelDir;
        _dirdif = (_cardir-_degrees);
        if((_dirdif > 89) or (_dirdif < -89)) then{_cardir=_cardir-180};    
        _pos = position (_rds select 0);
        _array = [_allvec select (round random _maxo),_pos,(east),0,_cardir,20] call BIS_EVO_CreateVehicle;
        _guard = _array select 0;
        _vec = _array select 1;
        
        (BIS_EVO_Mechanized select BIS_EVO_MissionProgress) set [0, _curtownMec+(count units _guard)];
        [position _alist,_guard,_radio,_alist] call BIS_EVO_Erefway;
        [_guard, 1] setWaypointCombatMode "RED";        
        {_x addEventHandler ["killed", {handle = [_this select 0,"MEC"] execVM "data\scripts\mobjbury.sqf"}]} forEach (units _guard);
        _guard setFormation "COLUMN";        
    };

    sleep 3;
    /*
    _realcurtownInf = "man" countType (list BIS_EVO_DetectEast);
    _curtownInf = _realcurtownInf;
    hint format ["realcurt: %1", _realcurtownInf];
    */
    
    

    if(_curtownInf <= (_basetownInf) and alive _radio) then 
    {


            _tag = "INF";    
        
            sleep 0.2;
        
            [] call BIS_EVO_mKamazOpen;
        
            [] call BIS_EVO_MI17support;
        
            (BIS_EVO_Infantry select BIS_EVO_MissionProgress) set [0, _curtownInf+12];
    
    };

sleep _wtime;    
};
dann brauchst du das:
Code:
// Deletes dead Enemy
_unit = _this select 0;
_tag = _this select 1;

switch (_tag) do //who died where?
{
    case "INF":
    {
        _curtownInf = (BIS_EVO_Infantry select BIS_EVO_MissionProgress) select 0;
        (BIS_EVO_Infantry select BIS_EVO_MissionProgress) set [0, _curtownInf-1];
    };    
     case "MEC":
    {
        _curtownMec = (BIS_EVO_Mechanized select BIS_EVO_MissionProgress) select 0;
        (BIS_EVO_Mechanized select BIS_EVO_MissionProgress) set [0, _curtownMec-1];
    };
     default
    {
    };    
};
if (not (_unit isKindOf "Man")) then
{
    {_x setpos position _unit} forEach crew _unit;
    sleep 300.0;
    deletevehicle _unit;
};
if (_unit isKindOf "Man") then
{
    if(not ((vehicle _unit) isKindOf "Man")) then {_unit setpos (position vehicle _unit)} ;
    sleep 310.0;
    hideBody _unit;
    sleep 4;
    deleteVehicle _unit;
};

und einen initialisator...
Code:
// City Setup
_radio = objNull;                                                    //edit psycho
_radio = BIS_EVO_radios select BIS_EVO_MissionProgress;                //edit psycho
_mkr = (BIS_EVO_MissionTowns select BIS_EVO_MissionProgress);
_pos = getMarkerPos _mkr;
BIS_EVO_DetectEast = createTrigger ["EmptyDetector", _pos];
BIS_EVO_DetectEast setTriggerActivation ["EAST", "PRESENT", true];
BIS_EVO_DetectEast setTriggerArea [500, 500, 0, true];
BIS_EVO_DetectEast setTriggerTimeout [2, 2, 2, true ];

BIS_EVO_DetectWest = createTrigger ["EmptyDetector", _pos];
BIS_EVO_DetectWest setTriggerActivation ["WEST", "PRESENT", true];
BIS_EVO_DetectWest setTriggerArea [600, 600, 0, true];
BIS_EVO_DetectWest setTriggerTimeout [2, 2, 2, true ];
_count = (count BIS_EVO_MissionTowns);


Sleep 2.0;
while {BIS_EVO_MissionProgress < _count} do
{
     _mkr = (BIS_EVO_MissionTowns select BIS_EVO_MissionProgress);
     _pos = getMarkerPos _mkr;
    
    BIS_EVO_DetectEast setpos _pos;
    BIS_EVO_DetectWest setpos _pos;
    Sleep 2.0;
    _radio = BIS_EVO_radios select BIS_EVO_MissionProgress;
    CityClear=false;
    [_mkr,BIS_EVO_DetectEast,BIS_EVO_DetectWest,BIS_EVO_MissionProgress] call BIS_EVO_Erec;
    
    Sleep 10.0;
    for [{_loop=0}, {_loop<1}, {_loop=_loop}] do
    {
        if ("Man" countType list BIS_EVO_DetectEast <= 4) then
        {
            if ("Tank" countType list BIS_EVO_DetectEast  == 0) then
            {
                if("Car" countType list BIS_EVO_DetectEast == 0) then
                {
                    if(not (alive _radio)) then    //edit psycho, because reinforce stop to work if town clear before radiotower destroyed
                    {
                        if ("Land" countType list BIS_EVO_DetectWest > 0) then{_loop=1};
                        CityClear=true;
                    };    
                };
            };
        };
        Sleep 4;
    };
    {_handle = [_x] execVM "data\scripts\submit.sqf"} forEach list BIS_EVO_DetectEast;
    {_x addscore 10} forEach list BIS_EVO_DetectWest;
    BIS_EVO_MissionProgress = BIS_EVO_MissionProgress+1;
    publicVariable "BIS_EVO_MissionProgress";
    //player globalchat format ["debug info: BIS_EVO_MissionProgress: %1",BIS_EVO_MissionProgress];
};

noch was vergessen...?
Code:
diag_log format ["########################## %1 ################################", missionName];
enableSaving [false, false];

//_psy = [] execVM "showclass.sqf";
//_psy = [player] execVM "cb_mapswitch.sqf";

spawntype = param1;
EVOhour = paramsArray select 2;
grasslevel = paramsArray select 3;
if (grasslevel == 0) then {setTerrainGrid 50};
if (grasslevel == 1) then {setTerrainGrid 25};
if (grasslevel == 2) then {setTerrainGrid 1};
viewparam =  paramsArray select 4;
basebeam = paramsArray select 5;
lkwbeam = paramsArray select 6;
farpbeam = paramsArray select 7;
ranklock = paramsArray select 8;
diffparam = paramsArray select 9;
loadoutparam = paramsArray select 10;
townparam = paramsArray select 11;
performanceparam = paramsArray select 12;
EVO_weathersystem = paramsArray select 13;
EVO_contermeassures = paramsArray select 14;


// Respawn settings
publicVariable "spawntype"; 
if (spawntype == 0 or spawntype == 1) then {server execVM "revive_init.sqf"};
if (spawntype == 2) then {"Respawn_west" setMarkerPos [(getMarkerPos "base" select 0),(getMarkerPos "base" select 1)]};

//debug=true

if (performanceparam == 1) then {enableEnvironment true};
if (performanceparam == 2) then {enableEnvironment false};


[] execVM "Briefing.sqf";

// Score required to attain each rank.
BIS_EVO_rank1 = 10;
BIS_EVO_rank2 = 20;
BIS_EVO_rank3 = 40;
BIS_EVO_rank4 = 80;
BIS_EVO_rank5 = 125;
BIS_EVO_rank6 = 200;

BIS_EVO_GlobalSleep = 0.1; // Global sleep is used after spawning a unit.


if (townparam == 1) then { BIS_EVO_MissionProgress = 0;};
if (townparam == 2) then { BIS_EVO_MissionProgress = 1;};
if (townparam == 3) then { BIS_EVO_MissionProgress = 2;};
if (townparam == 4) then { BIS_EVO_MissionProgress = 3;};
if (townparam == 5) then { BIS_EVO_MissionProgress = 4;};
if (townparam == 6) then { BIS_EVO_MissionProgress = 5;};
if (townparam == 7) then { BIS_EVO_MissionProgress = 6;};
if (townparam == 8) then { BIS_EVO_MissionProgress = 7;};


// Sub mission conditions
BIS_EVO_Onmission=false; 
BIS_EVO_sobj1=false;
BIS_EVO_radios = [parso1,somso1,cayso1,dolso1,ortso1,corso1,obrso1,bagso1]; // Each radio in each town
BIS_EVO_MissionTowns = ["mobj1","mobj2","mobj3","mobj4","mobj5","mobj6","mobj7","mobj8"];// Each mission objectives town marker.



// Set difficulty
// Easy
if (diffparam == 60) then 
{
    BIS_EVO_Infantry = [[3,6],[4,8],[5,10],[6,12],[7,14],[8,16],[9,18],[10,20]];//[Actual number of groups,Base number of groups]
    BIS_EVO_Mechanized = [[3,4],[4,5],[5,6],[6,7],[7,7],[7,8],[8,9],[8,10]];//[Actual number of groups,Base number of groups]
};
// Normal
if (diffparam == 30) then 
{
    BIS_EVO_Infantry = [[6,12],[8,16],[10,20],[12,24],[14,28],[16,32],[18,36],[20,40]];//[Actual number of groups,Base number of groups]//Razor
    BIS_EVO_Mechanized = [[4,5],[5,6],[6,8],[8,10],[10,12],[12,14],[15,16],[16,18]];//[Actual number of groups,Base number of groups]//Razor
};
// Hard
if (diffparam == 10) then 
{
    BIS_EVO_Infantry = [[10,20],[15,30],[20,40],[25,50],[30,60],[35,70],[40,80],[45,90]];//[Actual number of groups,Base number of groups];//[Actual number of groups,Base number of groups]
    BIS_EVO_Mechanized = [[8,10],[10,12],[12,14],[14,16],[16,18],[18,20],[20,22],[22,24]];//[Actual number of groups,Base number of groups]
};
// Extreme
if (diffparam == 5) then 
{
    BIS_EVO_Infantry = [[20,40],[25,50],[30,60],[35,70],[40,80],[45,90],[50,100],[55,110]];//[Actual number of groups,Base number of groups];//[Actual number of groups,Base number of groups]
    BIS_EVO_Mechanized = [[10,20],[12,24],[14,28],[16,32],[18,36],[20,40],[22,44],[24,48]];//[Actual number of groups,Base number of groups]
};

// The actual amount of infantry and mechanized enemy groups in a city.|When this number falls lower the the base amount, reinforcements are sent.
// The base amount of infantry and mechanized enemy groups in a city|If all of a group die the number is decremented.
BIS_EVO_CivCount = 0; // Number of civilians spawned

BIS_EVO_vdist=viewparam;                          // clients saved view distance
BIS_EVO_avdist=viewparam+1000;                   // clients saved air vehicle view distance
BIS_EVO_gdate = [2007,7,4,EVOhour,59];        // Current date and time
BIS_EVO_Playerlist = [];               // List of player names.
BIS_EVO_Playercount = 0;               // Amount of players in the game
BIS_EVO_lives=500;                   // Amount of deaths allowed in a game before it ends when paarm is active
BIS_EVO_PlayerSkill = 0.0;
BIS_EVO_allvar_packed = "";           // String transmitted to JIP clients containing all vars.
BIS_EVO_end=false;                    // Used to trigger the end of the game
BIS_EVO_sop=objNull;                // Sub objective player
BIS_EVO_sot=objNull;                // Sub objective target (radio or officer)
BIS_EVO_sor=0;                          // Sub objective reward

BIS_EVO_sup=objNull;               // Player calling support
CB_sup=objNull;                           // by psycho
BIS_EVO_sut="";                           // Type of support called
BIS_EVO_sur="";

BIS_EVO_fattack=false;                // detects if the player was attacked by the enemy for medic rewards.
BIS_EVO_mpoint=objNull;               // Player eligible for a medic reward.
BIS_EVO_epoint=objNull;               // Player eligible for a repair reward.
BIS_EVO_dunit="none";                // Name of disconnection player.
BIS_EVO_runit=objNull;                // Player who requires an AI recruit
BIS_EVO_rtype="none";               // Type of AI to be delivered
BIS_EVO_tunit=objNull;                // Target player for a join group request 
BIS_EVO_junit = objNull;               // Player who wishes to join the group
BIS_EVO_jgroup=grpNull;                // group junit wants to join

BIS_EVO_lunit = objNull;                // Laser target near the bomb site for shared point laser designation
BIS_EVO_lpoint = 1;                     // Points the designator will receive.

BIS_EVO_punit=objNull;               // Player requesting submission.
BIS_EVO_prew=0;                      // reward score for mission.
BIS_EVO_aunit=objNull;                // Player who will be promoted
BIS_EVO_arank="NULL";                // New rank the player will get

BIS_EVO_EngZone = objNull;           //Engineer zone
BIS_EVO_elock = 0;                          // Remembers if the engineer has his truck locked
BIS_EVO_ltrk = objNull;                 // The truck that is locked
BIS_EVO_mtar=objNull;                // the target that the missile is attacking in AA warning
BIS_EVO_fmission=false;               // Limits support to one request at a time.
BIS_EVO_latk=objNull;                // Person attacking a radio tower
10 setRadioMsg "NULL";


BIS_EVO_Objective0 = taskNull; // Idol objective
BIS_EVO_Objective1 = taskNull; //City 1 to
BIS_EVO_Objective2 = taskNull;
BIS_EVO_Objective3 = taskNull;
BIS_EVO_Objective4 = taskNull;
BIS_EVO_Objective5 = taskNull;
BIS_EVO_Objective6 = taskNull;
BIS_EVO_Objective7 = taskNull;
BIS_EVO_Objective8 = taskNull; //City 8
BIS_EVO_Objective9 = taskNull; // 

// Common function to lock vehicles.
//BIS_EVO_Lock =
//{
//    _vec = _this select 0;
//    if(Param1 == 7) then {_vec lock true} else {_vec lock false};
//};

// Detects empty enemy vehicles and deletes them.
BIS_EVO_IdelSVEC = 
{    
    _svec = _this select 0;
    for [{_loop=0}, {_loop<1}, {_loop=_loop}] do
    {
        if(not alive _svec or count units _svec == 0) then {_loop=1};
        Sleep 4.0;
    };
    sleep 2.0;
    if(not alive _svec) exitWith {};
    sleep 300;
    if(count units _svec == 0) then 
    {
        {_x setpos position _svec} forEach crew _svec;
        sleep 1.0;
        deletevehicle _svec
    };
};

BIS_EVO_aaweapons = ["M_Sidewinder_AA","M_R73_AA","M_Strela_AA","M_Stinger_AA"]; // All ammo that will set off a missile warning
BIS_EVO_pallammo = ["30Rnd_556x45_Stanag","30Rnd_556x45_Stanag","30Rnd_556x45_Stanag","30Rnd_556x45_Stanag","30Rnd_556x45_Stanag","Laserbatteries","MAAWS_HEAT","MAAWS_HEAT","MAAWS_HEAT","17Rnd_9x19_glock17","17Rnd_9x19_glock17","17Rnd_9x19_glock17","17Rnd_9x19_glock17"];// The players default load out
BIS_EVO_pweapons = ["SCAR_L_STD_HOLO","MAAWS","glock17_EP1","Binocular_Vector","Laserdesignator"]; // The players default load out
BIS_EVO_PlayerModel = "US_Soldier_EP1"; // The players default Model
"0" objstatus "Active";
"1" objstatus "Active";
"2" objstatus "Active";
"3" objstatus "Active";
"4" objstatus "Active";
"5" objstatus "Active";
"6" objstatus "Active";
"7" objstatus "Active";
"8" objstatus "Active";

setDate BIS_EVO_gdate;
_base = [] execVM "data\scripts\BIS_EVO_GetRelDir.sqf";
_spawnv = [] execVM "data\scripts\BIS_EVO_CreateVehicle.sqf";
if (isServer) then 
{
    {_x addEventHandler ["hit", {if((_this select 1) != BIS_EVO_latk) then {(_this select 0) setdamage 0}}]} forEach BIS_EVO_radios;
    onplayerconnected "[server] exec ""data\scripts\update.sqf"";if(BIS_EVO_dunit == _name) then {BIS_EVO_dunit = ""none""}";
    onPlayerDisconnected "
    BIS_EVO_dunit = _name;
    _mark = format[""%1mash"",BIS_EVO_dunit];
    deleteMarker _mark;
    _mark = format[""%1farp"",BIS_EVO_dunit];
    deleteMarker _mark;
    [] execVM ""data\scripts\noplayermove.sqf"";
    ";
};

execVM "R3F_ARTY_AND_LOG\init.sqf";

XGreyText = {"<t color='#f0bfbfbf'>" + _this + "</t>"};
XRedText = {"<t color='#f0ff0000'>" + _this + "</t>"};
XBlueText = {"<t color='#f07f7f00'>" + _this + "</t>"};

if (isServer and not (local player)) exitWith {}; 

// Large marker seen over occupied cites
BIS_EVO_MainObjective = createMarkerLocal ["MainObj", getMarkerPos "mobj1"];
BIS_EVO_MainObjective setMarkerColorLocal "ColorBlack";
BIS_EVO_MainObjective setMarkerShapeLocal "ELLIPSE";
BIS_EVO_MainObjective setMarkerSizeLocal [500, 500];

// For jip, client waits for server to run update.sqf
waitUntil {BIS_EVO_allvar_packed != ""};

_temp = compile BIS_EVO_allvar_packed;
_vars = call _temp;
BIS_EVO_end = _vars select 0;
BIS_EVO_MissionProgress = _vars select 1;
BIS_EVO_lives = _vars select 2;

/*
mando_hitch_no_check_for_drop = true;
mando_hitch_types = ["Landvehicle", "ReammoBox", "StaticWeapon"];
[12] execVM "mando_hitch\mando_hitch.sqf";
[["CH_47F_EP1","UH60M_EP1","UH60M_MEV_EP1"]] execVM "mando_hitch\mando_add_hitch.sqf";
*/


//          ----------below this line edit by psycho----------

setfire = true;
//CB_uav_ready = true;
conter_hint = false;
publicVariable "conter_hint";



titleCut ["","black faded", 0];

//code original from doolitle - matched by psycho
if (local player) then
{
    _myIn = 
    {
        private ["_return"];
        _return = false;
        {
            if (_x == _this select 0) exitWith {_return = true};
        }
        forEach (_this select 1);
        _return;
    };    
    _cfg = configFile/"CfgPatches";
    for [{_i = 0}, {_i < count _cfg}, {_i = _i + 1}] do 
    {
        if (isClass (_cfg select _i) and [configName (_cfg select _i), ["ACE_Main"]] call _myIn) then 
        {
            diag_log format ["Initialisation for %1 stoped! ---- Reason: ACE-Mod is not allowed in this Mission. Please disable this Mod for playing %1. --------------------------", missionName];
            _trg = createTrigger ["EmptyDetector", [0,0]];
            _trg setTriggerStatements ["true", "", ""];
            _trg setTriggerType "END6";
        };
    };
    Mod_Check_done = true;
};
waitUntil {not isNil "Mod_check_done"};
if (local player) then {[] spawn {sleep 10; hintSilent "Modcheck Succeeded --- all your Mods are allowed...";}};
//////////////////////////////////////////



...wenn du wiedermal ein script benötigst, melde dich einfach wieder. lol
__________________
Niemand hat die Absicht eine Tüte zu bauen!
​​​​​​​
___<<<A3 Wounding System>>>___
Pfandgiraffe ist offline  
Alt 18.10.2010, 20:56   #12 (permalink)
50 Beiträge
 
Registriert seit: 27.04.2008
Ort: Deutschland
Beiträge: 88
Roehrenradio eine Nachricht über ICQ schicken Roehrenradio eine Nachricht über MSN schicken Roehrenradio eine Nachricht über Skype™ schicken
Standard

Und das ist wirklich grossteils von BIS selbst?
__________________
crCTI URR 1.0
Roehrenradio ist offline  
Alt 18.10.2010, 20:59   #13 (permalink)
500 Beiträge1000 Beiträge
 
Benutzerbild von Pfandgiraffe
 
Registriert seit: 16.09.2008
Ort: Berlin
Alter: 38
Beiträge: 1.737
Pfandgiraffe eine Nachricht über ICQ schicken Pfandgiraffe eine Nachricht über Skype™ schicken
Standard

ka, glaub schon. das is aus arma1 importiert. da wurde immer nur dazu geschrieben
__________________
Niemand hat die Absicht eine Tüte zu bauen!
​​​​​​​
___<<<A3 Wounding System>>>___
Pfandgiraffe ist offline  
Alt 18.10.2010, 21:38   #14 (permalink)
10 Jahre hx3
5000 Beiträge
 
Benutzerbild von Xeno
 
Registriert seit: 03.01.2008
Alter: 84
Beiträge: 6.552
Standard

Zitat von Roehrenradio Beitrag anzeigen

Und das ist wirklich grossteils von BIS selbst?

*deleted*

Xeno
__________________
In arma everything is made of refined explodium, armored with wet paper towels.

Geändert von Xeno (03.01.2014 um 10:15 Uhr).
Xeno ist offline  
Alt 18.10.2010, 22:15   #15 (permalink)
500 Beiträge1000 Beiträge
 
Benutzerbild von Pfandgiraffe
 
Registriert seit: 16.09.2008
Ort: Berlin
Alter: 38
Beiträge: 1.737
Pfandgiraffe eine Nachricht über ICQ schicken Pfandgiraffe eine Nachricht über Skype™ schicken
Standard

als ich die a2 evo das erstemal in die hand nahm, war aufjedenfall alles voller vars die eindeutig auf arma1 hinwiesen. ist die paradrop nicht auch aus a1?
__________________
Niemand hat die Absicht eine Tüte zu bauen!
​​​​​​​
___<<<A3 Wounding System>>>___
Pfandgiraffe ist offline  
Alt 18.10.2010, 22:41   #16 (permalink)
10 Jahre hx3
5000 Beiträge
 
Benutzerbild von Xeno
 
Registriert seit: 03.01.2008
Alter: 84
Beiträge: 6.552
Standard

Zitat von Psychobastard Beitrag anzeigen

als ich die a2 evo das erstemal in die hand nahm, war aufjedenfall alles voller vars die eindeutig auf arma1 hinwiesen. ist die paradrop nicht auch aus a1?

*deleted*

Xeno
__________________
In arma everything is made of refined explodium, armored with wet paper towels.

Geändert von Xeno (03.01.2014 um 10:15 Uhr).
Xeno ist offline  
 


Aktive Benutzer in diesem Thema: 1 (Registrierte Benutzer: 0, Gäste: 1)
 
Themen-Optionen
Ansicht

Forumregeln
Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Ähnliche Themen
Thema Autor Forum Antworten Letzter Beitrag
Problem bei der bedingung anwesenheit Moerderhoschi Editing & Scripting 49 03.09.2010 12:52
Bedingung und Auslöser in *.sqf??? GER_CJ-187 Editing & Scripting 4 23.08.2010 19:55
Name als Bedingung GER_CJ-187 Editing & Scripting 0 05.06.2010 17:45


Kontakt - HX3.de - Archiv - Nach oben

Angetrieben durch vBulletin, Entwicklung von Philipp Dörner & Tobias



SEO by vBSEO 3.2.0 ©2008, Crawlability, Inc.

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119