Armed-Assault.de Twitter


Editing The world is a Script - write it!

Antwort
 
Themen-Optionen Ansicht
Alt 14.02.2008, 20:44   #61 (permalink)
User gesperrt
Newbie
 
Registriert seit: 05.02.2008
Beiträge: 7
Standard

Hallo, ich habe da auch so eine sche** Fehler

Und zwar, wenn ich bei meiner Einheit eingebe: flyinHeight 100, Das heißt
dass sie in 100m höhe fliegen soll, erscheint so ne dämliche Textnachricht:

Typ: Jede Erwartet nichts.

Also ich werde daraus nicht schlau.
IST DAS EIN BUG?

ES WÄRE BESSER, WENN MICH JEMAND EINES BESSEREN BEHLEHREN KÖNNTE
HYDRA ist offline   Mit Zitat antworten
Alt 14.02.2008, 21:16   #62 (permalink)
50 Beiträge100 Beiträge250 Beiträge
 
Benutzerbild von Big Fan
 
Registriert seit: 04.01.2008
Ort: Internet
Alter: 36
Beiträge: 253
Standard

probiers mal mit this flyInHeight 100 oder unitname flyInHeight 100 ansonsten würde ich sagen "ArmA spinnt" hatte ich auch schon, arma neu gestartet und dann gings wieder
__________________
Manche halten OFP und ArmA/2 für verbuggt, ich halte es für eine Herausforderung...

Aktueller preview trailer:
https://vid.me/lFy1
Big Fan ist offline   Mit Zitat antworten
Alt 14.02.2008, 21:21   #63 (permalink)
User gesperrt
Newbie
 
Registriert seit: 05.02.2008
Beiträge: 7
Standard

Danke für deine Hilfe, probier ich gleich aus!! DANKE!!!
HYDRA ist offline   Mit Zitat antworten
Alt 08.07.2008, 00:52   #64 (permalink)
50 Beiträge100 Beiträge
 
Benutzerbild von Andi <C.L.A.N.>
 
Registriert seit: 23.05.2008
Ort: SFB
Alter: 35
Beiträge: 170
Standard

Heeyy .. so habe auch ma ne frage :


if (player isKindOf "US_Soldier_WDL_Med") then {_actionId8 = player addAction ["Build MASH", "actions\mtent.sqf",0,1, false, true,"test2"]};

if (player isKindof "SoldierWMiner") then {_actionId8 = player addAction ["Build FARP", "actions\etent.sqf",0,1, false, true,"test2"]};

in dem Abschnit : if (player isKindof "SoldierWMiner") würde ich gerne 4 Saldaten mit deren Namen vereinbaren für das - dass daraufolgende dann gilt !!!!!

Kann mir jemand büdde helfen ????????

Geändert von Andi <C.L.A.N.> (08.07.2008 um 03:35 Uhr).
Andi <C.L.A.N.> ist offline   Mit Zitat antworten
Alt 08.07.2008, 12:21   #65 (permalink)
50 Beiträge100 Beiträge250 Beiträge
 
Benutzerbild von pspsps91
 
Registriert seit: 22.12.2005
Beiträge: 323
Standard

Code:
if (player isKindof "SoldierWMiner" OR player isKindof "SoldierWB")
Das kannst du dann ewig so weitermachen.
__________________
SP Mission, coming soon...
pspsps91 ist offline   Mit Zitat antworten
Alt 08.07.2008, 12:46   #66 (permalink)
500 Beiträge
 
Benutzerbild von Mr-Murray
 
Registriert seit: 10.06.2004
Ort: München - Germany
Beiträge: 876
Mr-Murray eine Nachricht über ICQ schicken Mr-Murray eine Nachricht über Skype™ schicken
Standard

... bis dir die Klassennamen ausgehen
__________________
MR-MURRAY presents

ArmA Editing Guide Deluxe Edition - English Version Download
ArmA Editing Guide Deluxe Edition - German Version Download

Visit me at Facebook! Mapfact Murray
Mr-Murray ist offline   Mit Zitat antworten
Alt 08.07.2008, 13:04   #67 (permalink)
50 Beiträge100 Beiträge
 
Benutzerbild von Andi <C.L.A.N.>
 
Registriert seit: 23.05.2008
Ort: SFB
Alter: 35
Beiträge: 170
Standard

ok dankeschön für die schnelle hilfe ... aba ich meinte nicht die klassennamen sondern den Player-namen ...

also player 1 hat den namen "eng1" ; player 2 heißt "eng2" usw.

...und statt die Klassenbezeichnung möchte ich nur die vier Player vereinbaren ??? geht das denn ???
Andi <C.L.A.N.> ist offline   Mit Zitat antworten
Alt 08.07.2008, 22:45   #68 (permalink)
50 Beiträge100 Beiträge250 Beiträge
 
Benutzerbild von pspsps91
 
Registriert seit: 22.12.2005
Beiträge: 323
Standard

jo, ist wieder das gleiche Prinzip:
Code:
if (eng1 isKindof "SoldierWMiner" OR eng2 isKindOf"SoldierWMiner")
Wenn dann die Action allerdings für den Spieler, für dens zutrifft gelten soll wirds schon schwieriger. Man könnte es mit einer foreach-Schleife lösen:
Code:
{
	if (_x isKindOf "SoldierWMinder") then {
		_x addAction ["Build MASH", "actions\mtent.sqf",0,1, false, true,"test2"];
	};
} forEach [eng1,eng2];
__________________
SP Mission, coming soon...
pspsps91 ist offline   Mit Zitat antworten
Alt 09.07.2008, 00:45   #69 (permalink)
50 Beiträge100 Beiträge
 
Benutzerbild von Andi <C.L.A.N.>
 
Registriert seit: 23.05.2008
Ort: SFB
Alter: 35
Beiträge: 170
Standard

@ pspsps91 ganz großes Dankeschön .... funzt super .... will die Woodland soldaten in meine EVO basteln .... habe ja nur 2 klassenbezeichnungen .... leider is mir aufgefallen dass die keine Verletzungen an den texturen aufzeigen, wenn sie angeschossen werden (kein Blut).... was isn da los ???? 1.14 Bug - Fehler ???? offtopic - sry ... oda spinnt mein ArmA !!!
Andi <C.L.A.N.> ist offline   Mit Zitat antworten
Alt 10.07.2008, 02:33   #70 (permalink)
50 Beiträge100 Beiträge
 
Benutzerbild von Andi <C.L.A.N.>
 
Registriert seit: 23.05.2008
Ort: SFB
Alter: 35
Beiträge: 170
Standard

hallo ... habe mal ne frage zur EVOLUTION V2 ... in der QG EVO V2 springen doch die Fallis über der jeweiligen stadt ab - in der normalen "sara" Evo jedoch nicht - obwohl das script "makepara.sqf" doch vorhanden ist !!! wird es nicht ausgelöst - würde das gerne korrigieren !!! ?????????????????
Andi <C.L.A.N.> ist offline   Mit Zitat antworten
Alt 12.07.2008, 03:42   #71 (permalink)
50 Beiträge100 Beiträge
 
Benutzerbild von Andi <C.L.A.N.>
 
Registriert seit: 23.05.2008
Ort: SFB
Alter: 35
Beiträge: 170
Standard

hallo - sagt mal gibt es ein script mit dem ich 2 schwere waffen tragen kann ... z.B. MG und RPG launcher ???
Andi <C.L.A.N.> ist offline   Mit Zitat antworten
Alt 12.07.2008, 10:25   #72 (permalink)
50 Beiträge100 Beiträge
 
Benutzerbild von Imutep
 
Registriert seit: 04.10.2005
Ort: München
Beiträge: 118
Standard

ColonelSandersLite hat mal sowas in der Art als Script geschrieben. Is aber für primäre Waffen. Schau selbst ob du es brauchen kannst.

Klick mich oder klick du mich
__________________
Imutep ist offline   Mit Zitat antworten
Alt 12.07.2008, 13:37   #73 (permalink)
50 Beiträge100 Beiträge
 
Benutzerbild von Andi <C.L.A.N.>
 
Registriert seit: 23.05.2008
Ort: SFB
Alter: 35
Beiträge: 170
Standard

yeah danke ... das script funzt - is aber kompliziert was die handhabung angeht ... in der domination 3 von Xeno gibt es auch so ein weaponsswitch script ... aber ich kriege es nicht herausgelöst so das ich es selber nutzen kann !!!!
Andi <C.L.A.N.> ist offline   Mit Zitat antworten
Alt 12.07.2008, 14:20   #74 (permalink)
5000 Beiträge
 
Benutzerbild von Xeno
 
Registriert seit: 03.01.2008
Alter: 77
Beiträge: 6.547
Standard

Zitat von Andi <C.L.A.N.> Beitrag anzeigen

yeah danke ... das script funzt - is aber kompliziert was die handhabung angeht ... in der domination 3 von Xeno gibt es auch so ein weaponsswitch script ... aber ich kriege es nicht herausgelöst so das ich es selber nutzen kann !!!!

Versuchs mal so

Erstelle einen Auslöser, Bedingung local player
Bei Aktivierung: handle = [] execVM "x_setupbackpack.sqf";

x_setupbackpack.sqf:
Code:
// by Xeno
private ["_p","_pos","_trigger","_s"];
if (!local player) exitWith {};

_p = player;
_pos = position _p;

player_backpack = [];

pbp_id = -1000;

prim_weap_player = primaryWeapon _p;
_s = format ["%1 to Backpack", prim_weap_player];
if (prim_weap_player != "") then {
    pbp_id = _p addAction [_s, "x_backpack.sqf",[],-1,false];
};

// No Weapon fix for backpack
_trigger = createTrigger["EmptyDetector" ,_pos];
_trigger setTriggerArea [0, 0, 0, false];
_trigger setTriggerActivation ["NONE", "PRESENT", true];
_trigger setTriggerStatements["primaryWeapon player != prim_weap_player","prim_weap_player = primaryWeapon player;if (pbp_id != -1 && count player_backpack == 0) then {player removeAction pbp_id;pbp_id = -1;};if (pbp_id == -1 && count player_backpack == 0 && prim_weap_player != """") then {pbp_id = player addAction [format [""%1 to Backpack"", prim_weap_player], ""x_backpack.sqf"",[],-1,false];};",""];

while {true} do {
    waitUntil {!alive player};
    _p = player;
    _weapons = weapons _p;
    _magazines = magazines _p;
    if (pbp_id != -1000) then {
        _p removeAction pbp_id;
    };
    waitUntil {alive player};
    _p = player;
    removeAllWeapons _p;
    {_p addMagazine _x;} forEach _magazines;
    {_p addWeapon _x;} forEach _weapons;
    _primw = primaryWeapon _p;
    if (_primw != "") then {
        _p selectWeapon _primw;
        _muzzles = getArray(configFile>>"cfgWeapons" >> _primw >> "muzzles");
        _p selectWeapon (_muzzles select 0);
    };
    if (count player_backpack == 0) then {
        _s = format ["%1 to Backpack", primaryWeapon _p];
        pbp_id = _p addAction [_s, "x_backpack.sqf",[],-1,false];
    } else {
        _s = format ["Weapon %1", (player_backpack select 0)];
        pbp_id = _p addAction [_s, "x_backpack.sqf",[],-1,false];
    };
};

if (true) exitWith {};
x_backpack.sqf:
Code:
// by Xeno
private ["_p"];
_p = player;
_p removeAction pbp_id;

if (count player_backpack == 0) then {
    _primary = primaryWeapon _p;
    if (_primary != "") then {
        _mag_types = getArray(configFile>> "cfgWeapons" >> _primary >> "magazines");
        _magazines = magazines _p;
        _mags_backpack = [];
        {
            if (_x in _mag_types) then {_mags_backpack = _mags_backpack + [_x]};
        } forEach _magazines;
        _muzzles = getArray(configFile>> "cfgWeapons" >> _primary >> "muzzles");
        if (count _muzzles == 2) then {
            _mag_types = getArray(configFile>> "cfgWeapons" >> _primary >> (_muzzles select 1) >> "magazines");
            {
                if (_x in _mag_types) then {_mags_backpack = _mags_backpack + [_x]};
            } forEach _magazines;
        };
        player_backpack = [_primary, _mags_backpack];
        _weapons = weapons _p;
        _pistol = "";
        {
            scopeName "pistolsearch";
            _base = inheritsFrom (configFile >> "cfgWeapons" >> _x);
            for "_xs" from 1 to 3 do {
                if (configName _base == "Pistol") then {
                    _pistol = _x;
                    breakOut "pistolsearch";
                };
                _base = inheritsFrom (configFile >> "cfgWeapons" >> (configName _base));
            };
        } forEach _weapons;
        if (_pistol != "") then {
            _p removeWeapon _pistol;
        };
        {
            _p removeMagazine _x;
        } forEach _mags_backpack;
        _p removeWeapon _primary;
        _anim = animationState _p;
        WaitUntil {animationState player != _anim};
        _s = format ["Weapon %1", _primary];
        if (_pistol != "") then {
            _p addWeapon _pistol;
            _p selectWeapon _pistol;
        };
        pbp_id = _p addAction [_s, "x_backpack.sqf",[],-1,false];
    } else { // has no primary
    };
} else { // switch weapon
    _primary = primaryWeapon _p;
    if (_primary == "") then {
        {
            _p addMagazine _x;
        } forEach (player_backpack select 1);
        _p addWeapon (player_backpack select 0);
        _muzzles = getArray(configFile>>"cfgWeapons" >> (player_backpack select 0) >> "muzzles");
        _p selectWeapon (player_backpack select 0);
        _p selectWeapon (_muzzles select 0);
        _s = format ["%1 to Backpack", (player_backpack select 0)];
        player_backpack = [];
        _p removeAction pbp_id;
        pbp_id = _p addAction [_s, "x_backpack.sqf",[],-1,false];
    } else {
        _mag_types = getArray(configFile>> "cfgWeapons" >> _primary >> "magazines");
        _magazines = magazines _p;
        _mags_backpack = [];
        {
            if (_x in _mag_types) then {_mags_backpack = _mags_backpack + [_x]};
        } forEach _magazines;
        _muzzles = getArray(configFile>> "cfgWeapons" >> _primary >> "muzzles");
        if (count _muzzles == 2) then {
            _mag_types = getArray(configFile>> "cfgWeapons" >> _primary >> (_muzzles select 1) >> "magazines");
            {
                if (_x in _mag_types) then {_mags_backpack = _mags_backpack + [_x]};
            } forEach _magazines;
        };
        {
            _p removeMagazine _x;
        } forEach _mags_backpack;
        _weapons = weapons _p;
        _pistol = "";
        {
            scopeName "pistolsearch2";
            _base = inheritsFrom (configFile >> "cfgWeapons" >> _x);
            for "_xs" from 1 to 3 do {
                if (configName _base == "Pistol") then {
                    _pistol = _x;
                    breakOut "pistolsearch2";
                };
                _base = inheritsFrom (configFile >> "cfgWeapons" >> (configName _base));
            };
        } forEach _weapons;
        if (_pistol != "") then {
            _p removeWeapon _pistol;
        };
        _p removeWeapon _primary;
        sleep 1;
        _anim = animationState _p;
        WaitUntil {animationState player != _anim};
        {
            _p addMagazine _x;
        } forEach (player_backpack select 1);
        if (_pistol != "") then {
            _p addWeapon _pistol;
        };
        _p addWeapon (player_backpack select 0);
        _muzzles = getArray(configFile>> "cfgWeapons" >> (player_backpack select 0) >> "muzzles");
        _p selectWeapon (player_backpack select 0);
        _p selectWeapon (_muzzles select 0);
        player_backpack = [_primary, _mags_backpack];
        _s = format ["Weapon %1", _primary];
        pbp_id = _p addAction [_s, "x_backpack.sqf",[],-1,false];
    };
};

if (true) exitWith {};
Beim Respawn erhält der Spieler in dieser Variante auch seine Waffe zurück, die er vor dem Tode hatte.

Xeno
__________________
In arma everything is made of refined explodium, armored with wet paper towels.
Xeno ist offline   Mit Zitat antworten
Alt 12.07.2008, 16:14   #75 (permalink)
SQF Zauberer 10 Jahre hx3
500 Beiträge1000 Beiträge
 
Benutzerbild von Vienna
 
Registriert seit: 12.07.2004
Ort: Wien
Beiträge: 1.917
Standard

Xeno, die letzte Zeile deiner Skripts lautet : if (true) exitWith {};

Hat das in ArmA besondere Auswirkungen?
Vienna ist offline   Mit Zitat antworten
Alt 12.07.2008, 17:50   #76 (permalink)
50 Beiträge100 Beiträge
 
Benutzerbild von Andi <C.L.A.N.>
 
Registriert seit: 23.05.2008
Ort: SFB
Alter: 35
Beiträge: 170
Standard

@ Xeno .... yeehaw funzt wie Atze .... ganz großes Dankescheen !!!!!!!
Andi <C.L.A.N.> ist offline   Mit Zitat antworten
Alt 12.07.2008, 18:58   #77 (permalink)
50 Beiträge100 Beiträge
 
Benutzerbild von Andi <C.L.A.N.>
 
Registriert seit: 23.05.2008
Ort: SFB
Alter: 35
Beiträge: 170
Standard

ich nochmal - brauche mal eine übersetzung in script sprache büdde :


wenn der player kein "M240" oder "M249" mit sich führt dann schließe (das script) und schreibe (hintc) : You can build a MG_Nest without M240 or M249



dankescheen schonma !!!!!!
Andi <C.L.A.N.> ist offline   Mit Zitat antworten
Alt 12.07.2008, 19:53   #78 (permalink)
50 Beiträge100 Beiträge
 
Benutzerbild von Andi <C.L.A.N.>
 
Registriert seit: 23.05.2008
Ort: SFB
Alter: 35
Beiträge: 170
Standard

if (not (primaryWeapon player == "M240")) exitWith {hint "You can not build a MG_Nest without M240"};



hehe thx Andi !!!!
Andi <C.L.A.N.> ist offline   Mit Zitat antworten
Alt 13.07.2008, 19:05   #79 (permalink)
50 Beiträge100 Beiträge
 
Benutzerbild von Andi <C.L.A.N.>
 
Registriert seit: 23.05.2008
Ort: SFB
Alter: 35
Beiträge: 170
Standard

und ich wieda ... würde gerne leichte Fahrzeuge unter einem UH60MG/FFAR hängen können und die dann nach irgendwo schaffen ... also ein Hebescript ... habe probiert das winch-script aus der Hohei Evo zu nutzen aba das funzt net ... hat jemand ne idee ???
Andi <C.L.A.N.> ist offline   Mit Zitat antworten
Alt 13.07.2008, 19:09   #80 (permalink)
Imperator fori nocturni - This sucks more than anything that has ever sucked before 10 Jahre hx3
20.000 Beiträge
 
Benutzerbild von burns
 
Registriert seit: 13.04.2003
Ort: Monerica
Alter: 35
Beiträge: 32.225
Standard

Zitat von Andi <C.L.A.N.> Beitrag anzeigen

und ich wieda ... würde gerne leichte Fahrzeuge unter einem UH60MG/FFAR hängen können und die dann nach irgendwo schaffen ... also ein Hebescript ... habe probiert das winch-script aus der Hohei Evo zu nutzen aba das funzt net ... hat jemand ne idee ???

OFPEC Editors Depot
__________________

burns ist offline   Mit Zitat antworten
Antwort


Aktive Benutzer in diesem Thema: 1 (Registrierte Benutzer: 0, Gäste: 1)
 
Themen-Optionen
Ansicht

Forumregeln
Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Ähnliche Themen
Thema Autor Forum Antworten Letzter Beitrag
Bitte um Hilfe bei Script für Waffenrespawn Defender Editing 3 16.12.2006 19:41
hilfe ;) bitte mal rein schauen @ thx zynon Editing 3 29.07.2006 19:16
cannot create... + Startet nicht+ bitte hilfe Tempic Hilfe 11 25.01.2006 19:52
Hilfe beim Umtexturieren DaReal Mod und Addon Ecke 11 13.08.2005 20:05


Kontakt - HX3.de - Archiv - Nach oben

Angetrieben durch vBulletin, Entwicklung von Philipp Dörner & Tobias



SEO by vBSEO 3.2.0 ©2008, Crawlability, Inc.

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116