Armed-Assault.de Twitter


Editing The world is a Script - write it!

Antwort
 
Themen-Optionen Ansicht
Alt 13.07.2008, 10:07   #1 (permalink)
SQF Zauberer 10 Jahre hx3
500 Beiträge1000 Beiträge
 
Benutzerbild von Vienna
 
Registriert seit: 12.07.2004
Ort: Wien
Beiträge: 1.917
Standard Ändern der Fahrzeugbewaffnung

Ein Beispiel für Flugzeuge mit zwei Skripten und im Anhang die Mission dazu.

Beim Einsteigen ins Fahrzeug sind im Aktionsmenü einmalig 3 Auswahlmöglichkeiten zur Umrüstung der Fahrzeugbewaffnung vorhanden.


AktionenWaffenliste.sqf
Code:
// Ändern der Bewaffnung von Fahrzeugen über das Aktionsmenü, wenn der Spieler das Fahrzeug besteigt.
//
// Skriptaufruf in die Initialisierungszeile des Fahrzeuges wie folgt eintragen:
//  temp = this execVM "AktionenWaffenliste.sqf"
//
// Verwendet Skript "NeuBewaffnen.sqf"

private ["_a1","_a2","_w1","_w2","_w3","_w4","_w5","_w6"];

//Waffenliste für Luftkampfeinheiten.
_w1 = ["57mmLauncher","96Rnd_57mm",1];
_w2 = ["HellfireLauncher","8Rnd_Hellfire",1];
_w3 = ["M197","750Rnd_M197_AH1",1];
_w4 = ["MaverickLauncher","5Rnd_Maverick_A10",1];
_w5 = ["S8Launcher","40Rnd_S8T",1];
_w6 = ["GAU8","1350Rnd_30mmAP_A10",1];

VehicleBewaffnungEnde = false; // globale Variable zum Beenden des Skripts

waitUntil {vehicle player == _this}; // warten bis Spieler ins Fahrzeug einsteigt

// Aktionen hinzufügen
_a1 = _this addAction ["Bewaffnen wie AH1W und  A10", "NeuBewaffnen.sqf", [_w1,_w2,_w3,_w4,_w5,_w6],100,true,true,""];
_a2 = _this addAction ["Bewaffnen wie Standard AH1W", "NeuBewaffnen.sqf", [_w1,_w2,_w3],100,true,true,""];
_a3 = _this addAction ["Bewaffnen wie Standard  A10", "NeuBewaffnen.sqf", [_w4,_w5,_w6],100,true,true,""];

waitUntil {VehicleBewaffnungEnde}; // warten bis Bewaffnung gewählt wurde

// Aktionen entfernen
_this removeAction _a1;
_this removeAction _a2;
_this removeAction _a3;
NeuBewaffnen.sqf
Code:
// Neubewaffnung eines Fahrzeuges in dem sich der Spieler befindet.
// 
// Parameter: Array mit beliebig vielen dreidimensionalen Unterarrays.
//   Beispiel für ein Unterarray: [ ["Waffennamebezeichnung","Magazinbezeichnung",Magazinanzahl],... ]

private ["_unit","_i","_w","_m","_a","_j","_l"];

_l = _this select 3; //Array mit der Bewaffnungsliste laden

_unit = vehicle player;

//vorhandene Waffen und Magazine entfernen
{_unit RemoveWeapon _x;} foreach (weapons _unit); 
{_unit removeMagazine _x;} forEach (magazines _unit); 

for [{_i=0},{_i<count _l},{_i=_i+1}] do
   {
      _w = (_l select _i) select 0; //Waffenbezeichnung als String
      _m = (_l select _i) select 1; //Magazinbezeichnung als String
      _a = (_l select _i) select 2; //Anzahl derMagazie als Zahl
      for [{_j=1},{_j<=_a},{_j=_j+1}] do {_unit addMagazine _m};
      _unit addWeapon _w;
      _unit SelectWeapon _w
   };

//entfernt die Aktionsmenüpunkte des aufrufenden Skripts	
VehicleBewaffnungEnde = true;

//Bewaffnung anzeigen
_w = weapons vehicle _unit;
_m = magazines vehicle _unit;
_l = format["Waffen:\n"]; {_l = format["%1\n%2",_l,_x]} forEach _w;
_l = format["%1\n\n\nMagazine:\n",_l]; {_l = format["%1\n%2",_l,_x]} forEach _m;
hint _l
Angehängte Dateien
Dateityp: zip Fahrzeugbewaffnung_aendern.zip (2,5 KB, 68x aufgerufen)
Vienna ist offline   Mit Zitat antworten
Alt 13.07.2008, 10:14   #2 (permalink)
500 Beiträge
 
Benutzerbild von Mr-Murray
 
Registriert seit: 10.06.2004
Ort: München - Germany
Beiträge: 876
Mr-Murray eine Nachricht über ICQ schicken Mr-Murray eine Nachricht über Skype™ schicken
Standard

Der Vienna geht ja ab wie ein Zäpfchen Schön, dass du wieder da und aktiv bist!!!
Man kann sich ja vor lauter Comments und Solutions kaum noch retten

Bitte weiter so!!!



Grüße

Mr-Murray
__________________
MR-MURRAY presents

ArmA Editing Guide Deluxe Edition - English Version Download
ArmA Editing Guide Deluxe Edition - German Version Download

Visit me at Facebook! Mapfact Murray
Mr-Murray ist offline   Mit Zitat antworten
Alt 13.07.2008, 13:50   #3 (permalink)
SQF Zauberer 10 Jahre hx3
500 Beiträge1000 Beiträge
 
Benutzerbild von Vienna
 
Registriert seit: 12.07.2004
Ort: Wien
Beiträge: 1.917
Standard

Die Motivation ist stark vom Interesse der Mitspieler und davon abhängig, ob die Bugs des Spieles Bemühungen nicht wider zunichte machen.

Aber durch die Patches dürft das Spiel jetzt einen Zustand erreicht haben, der recht brauchbar ist.


Wegen der großen Nachfrage wurde eine weitere Beispiel-Variante erstellt, bei der die Waffen einzeln hinzugefügt werden können.

Die Auswahl ist abgeschlossen, wenn alle möglichen Waffen geladen wurden, oder das Fahrzeug sich in Bewegung setzt.
Angehängte Dateien
Dateityp: zip Fahrzeugbewaffnungen_Einzelwahl.zip (2,5 KB, 78x aufgerufen)
Vienna ist offline   Mit Zitat antworten
Antwort


Aktive Benutzer in diesem Thema: 1 (Registrierte Benutzer: 0, Gäste: 1)
 
Themen-Optionen
Ansicht

Forumregeln
Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Ähnliche Themen
Thema Autor Forum Antworten Letzter Beitrag
waffenname ändern IntoTheLight Editing 3 30.04.2008 12:58
Texturen ändern FireFighter14 Mod und Addon Ecke 10 15.10.2005 20:33
Firefox Benutzerprofil ändern? Gelöschter Benutzer Hilfe 1 11.06.2005 06:51
serial nummer ändern ? dab Community 3 06.02.2005 22:46


Kontakt - HX3.de - Archiv - Nach oben

Angetrieben durch vBulletin, Entwicklung von Philipp Dörner & Tobias



SEO by vBSEO 3.2.0 ©2008, Crawlability, Inc.

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116