/*
	Autor:	AssoLoki
	Beschreibung:			Liefert die für den "animate"- Befehl benötigten Namen von Benutzer- Aktionen eines Objekts (z.B. Fluggeräte, Gebäude, Tore).
							
	Anwendung:				Cursor auf das gewüsnchte Objekt ausrichten und Script über Funkauslöser auslösen.
	
	Rückgabe:				Array mit den gefundenen Benutzer- Aktionen des übergebenen Objektes, bestehend aus Aktions- Name und
							dem entsprechenden "animate"- Code.
							Wird per "hintC" Ingame ausgegeben, in die Zwischenablage (Clipboard) kopiert und ebenfalls in die rpt- Datei
							geschrieben (nützlich wenn man mehrer Objekte hintereinander abfragen will).
							
	Hinweise:				Der Inhalt der Zwischenablage kann mit "Ctrl + V" in einen beliebigen Texteditor (z.B. Notepad) eingefügt werden.
							Beim übertragen des Codes in einen Auslöser, eine Objekt-Initzeile oder ein Script muss das "_this" for dem
							"animate"- Befehl durch das Objekt ersetzt werden, auf das die Animation angewendet werden soll.
*/
private ["_objectType", "_config", "_UAktions", "_i", "_uaKlasse", "_uaStatment", "_eintrag"];
_objekt= cursortarget;
if ((TypeName _objekt) != "OBJECT") exitWith {hintC "Script 'getAnimateName' - Fehler:\nEs wurde kein Objekt an das Script übergeben!";};
_objectType= typeOf _objekt;
_config= configFile >> "CfgVehicles" >> _objectType >> "UserActions";
if ((count _config) < 1) exitWith {hintC format ["Script 'getAnimateName' - Info:\nübergebenes Objekt (Type: %1) hat keine Benutzer- Aktionen", _objectType];};
_UAktions= [(format ["Objekt- Type: %1",_objectType])];
for [{_i = 0}, {_i < (count _config)}, {_i= _i + 1}] do
	{
	_uaKlasse= _config select _i;
	if (isclass _uaKlasse) then
		{
		_uaStatment= getText (_config >> (configName _uaKlasse) >> "statement");
		_eintrag= format ["Aktion- Titel: %1, Code: %2", (configName _uaKlasse), _uaStatment];
		_UAktions= _UAktions + [[_eintrag]];
		};
	};
hintC format ["%1", _UAktions];
copytoclipboard format ["%1", _UAktions];
diag_log format ["Script getAnimateName- Result: %1", _UAktions];
