Archiv verlassen und diese Seite im Standarddesign anzeigen : Kisten
Braindead
11.03.2013, 22:32
Hallo,
Unter welcher Kategorie findet man Kisten mit Uniformen und mit Aufsätzen für Waffen???
Danke im Vorraus Lars:D
Braindead
11.03.2013, 22:42
und noch die 2. frage^^ wie füge ich "Missionen" aus dem Editor in den Multiplayer ein?
Hallo,
Unter welcher Kategorie findet man Kisten mit Uniformen und mit Aufsätzen für Waffen???
Danke im Vorraus Lars:D
Dafür gibts keine spezielle Kiste soweit ich weiß.
Folgendes in die Init einer Mun-Kiste schreiben:
this additemcargo ["Zasleh2",2];
this additemcargo ["muzzle_snds_H", 2];
this additemcargo ["muzzle_snds_L", 2];
this additemcargo ["muzzle_snds_B", 2];
this additemcargo ["muzzle_snds_H_MG", 2];
this additemcargo ["optic_Arco", 2];
this additemcargo ["optic_Hamr", 2];
this additemcargo ["optic_Aco", 2];
this additemcargo ["optic_ACO_grn",2];
this additemcargo ["optic_Holosight", 2];
this additemcargo ["acc_flashlight", 2];
this additemcargo ["acc_pointer_IR", 2];
und noch die 2. frage^^ wie füge ich "Missionen" aus dem Editor in den Multiplayer ein?
Mission als Mulitplayermission abspeichern, dann in der Serverliste auswählen.
Kannst es auch mal hiermit versuchen, da kannst du selber festlegen mit welchen Classnames oder Gegenstandskategorien das Script die Kiste befüllen soll.
/*
Author: Tajin
File: fillbytype.sqf
Version: 0.2
Desc: Fills a box/vehicle with Items of the desired SuperClass
Syntax: [this,[ #parameters# ] execVM "fillbytype.sqf";
Replace #parameters# with any of the following:
Classname only: (this fills in the default number [10] of any type of Pistol)
"Pistol"
Classname and amount: (this fills in 5 silenced Rook40 Pistols)
["hgun_Rook40_snds_F",5]
Classname, amount and Configfile: (this fills in 5 of every type of Backpack)
["Bag_Base",5,"CfgVehicles"]
Multiple selections are also possible:
["Pistol",5],["Bag_Base",5,"CfgVehicles"]
# The script also adds 10 magazines of every available Magazinetype per Weapon #
*/
private ["_cfg","_box","_desired","_inherit","_list","_i","_sel","_arr","_dd","_d","_desire","_dcount","_class","_type","_scope","_object","_mags","_x","_kindof","_icon","_dconfig"];
if(!isServer) exitWith {};
_box = _this select 0;
_desired = [];
FNC_kindOf = {
_inherit = inheritsFrom _this;
_list = [configName _this];
while { (configName _inherit) != "" } do {
_list set[count _list,configName _inherit];
_inherit = inheritsFrom( _inherit );
};
_list
};
switch(typeName (_this select 1)) do {
case "ARRAY": {
_desired = _this select 1;
for "_i" from 0 to (count _desired)-1 do {
_sel = _desired select _i;
if ( (typeName _sel) == "STRING" ) then {
_arr = [_sel,10];
_desired set[_i,_arr];
};
};
break;
};
case "STRING": {
_desired = [[_this select 1,10]];
break;
};
};
clearWeaponCargoGlobal _box;
clearMagazineCargoGlobal _box;
clearItemCargoGlobal _box;
clearBackpackCargoGlobal _box;
diag_log format["Starting: %1", _desired];
for "_d" from 0 to (count _desired)-1 do {
_dd = _desired select _d;
_desire = _dd select 0;
_dcount = _dd select 1;
if (count _dd > 2) then {
_dconfig = _dd select 2;
} else {
_dconfig = "CfgWeapons";
};
_cfg = configFile >> _dconfig;
for "_i" from 0 to (count _cfg)-1 do {
_class = _cfg select _i;
if (isClass _class) then {
_type = getNumber(_class >> "type");
_scope = getNumber(_class >> "scope");
_icon = getText(_class >> "picture");
if(_scope == 2 && _type != 65536 && _icon != "\A3\Weapons_F\Data\clear_empty.paa") then {
_kindof = _class call FNC_kindOf;
if ( _desire in _kindof ) then {
_object = configName _class;
switch (true) do {
case ("Bag_Base" in _kindof): {
_box addBackpackCargo [_object, _dcount];
};
case ("ItemCore" in _kindof): {
_box addItemCargoGlobal [_object, _dcount];
};
default {
_box addWeaponCargoGlobal [_object, _dcount];
};
};
diag_log format["%1 added (%2)", _object, _icon];
_mags = getArray(_class >> "magazines");
{
_box addMagazineCargoGlobal [_x,_dcount * 10];
diag_log format["Magazines %1 added", _x];
} forEach _mags;
};
};
};
};
};
diag_log "finished";
Für Uniformen (5 von jeder Sorte) wäre das z.b:
[this,[ ["Uniform_Base",5] ] execVM "fillbytype.sqf";
( Classnames und deren Hierarchie findest du hier: http://browser.six-projects.net/cfg_weapons/tree?utf8=%E2%9C%93&version=67&commit=Save )
Braindead
12.03.2013, 09:57
Danke :daumen:
Braindead
12.03.2013, 10:13
Danke :daumen: aber wenn ich das eingeben steht da: type Array expected nothing
Danke :daumen: aber wenn ich das eingeben steht da: type Array expected nothing
Dann probiers mal so:
nul = [this,[ ["Uniform_Base",5] ] execVM "fillbytype.sqf";
Braindead
12.03.2013, 10:41
ma was neues: fillbytype.sqf not found
Naja klar, du musst die Scriptdatei mit dem Inhalt oben natürlich auch erstmal erstellen und in deinem Missionsordner ablegen. Sonst klappt das nicht. :D
JoeJoe87577
12.03.2013, 11:47
Dieses Script hier füllt die gewünschte Kiste mit allem auf was im Spiel ist.
[ALPHA] ARMA 3 Crate Filler - Scripts - Armaholic (http://www.armaholic.com/page.php?id=18773)
Und auch noch mit allem was reinkommt :D
vBulletin® v3.7.3, Copyright ©2000-2024, Jelsoft Enterprises Ltd.